sys-app/seabios:

	fixed a bug in 1.7.0

1 files changed, 71 insertions, 0 deletions

diff --git a/sys-apps/seabios/seabios-1.7.0-r3.ebuild b/sys-apps/seabios/seabios-1.7.0-r3.ebuild
new file mode 100644
index 0000000..9c0f7a2
--- /dev/null
+++ b/sys-apps/seabios/seabios-1.7.0-r3.ebuild
@@ -0,0 +1,71 @@
+# Copyright 1999-2012 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+# $Header: /var/cvsroot/gentoo-x86/sys-apps/seabios/seabios-1.7.0.ebuild,v 1.1 2012/06/28 15:09:36 cardoe Exp $
+
+EAPI=4
+
+PYTHON_DEPEND="2"
+
+inherit python
+
+#BACKPORTS=1
+
+if [[ ${PV} = *9999* || ! -z "${EGIT_COMMIT}" ]]; then
+	EGIT_REPO_URI="git://git.seabios.org/seabios.git"
+	inherit git-2
+	KEYWORDS=""
+	SRC_URI=""
+else
+	KEYWORDS="~amd64"
+	SRC_URI="http://www.linuxtogo.org/~kevin/SeaBIOS/${PN}-${PV}.tar.gz
+	${BACKPORTS:+http://dev.gentoo.org/~cardoe/distfiles/${PN}-${PV}-bp-${BACKPORTS}.tar.bz2}"
+fi
+
+DESCRIPTION="Open Source implementation of a 16-bit x86 BIOS"
+HOMEPAGE="http://www.seabios.org"
+
+LICENSE="LGPL-3 GPL-3"
+SLOT="0"
+IUSE="debug-serial-port thread-optionroms"
+
+RDEPEND="
+	!app-emulation/qemu
+	!<=app-emulation/qemu-kvm-0.15.0"
+
+pkg_setup() {
+	python_set_active_version 2
+}
+
+src_prepare() {
+	sed 's/$(Q)$(MAKE)/$(Q)+$(MAKE)/' -i "${S}/Makefile"
+	if [[ -z "${EGIT_COMMIT}" ]]; then
+		sed -e "s/VERSION=.*/VERSION=${PV}/" \
+			-i "${S}/Makefile"
+	else
+		sed -e "s/VERSION=.*/VERSION=${PV}_pre${EGIT_COMMIT}/" \
+			-i "${S}/Makefile"
+	fi
+}
+
+src_configure() {
+	if use debug-serial-port || use thread-optionroms; then
+		emake defconfig || die "Creating default config for ${PN} failed"
+		use debug-serial-port && \
+			sed 's/^# CONFIG_DEBUG_SERIAL is not set$/CONFIG_DEBUG_SERIAL=y\nCONFIG_DEBUG_SERIAL_PORT=0x3f8/' \
+				-i .config
+		use thread-optionroms && \
+			sed 's/^# CONFIG_THREAD_OPTIONROMS is not set$/CONFIG_THREAD_OPTIONROMS=y/' \
+				-i .config
+	fi
+}
+
+src_compile() {
+	emake out/bios.bin
+#	emake out/vgabios.bin
+}
+
+src_install() {
+	insinto /usr/share/seabios
+	doins out/bios.bin
+#	doins out/vgabios.bin
+}