Add dev-java/commons-daemon-1.0.15, update README.md

2 files changed, 64 insertions, 0 deletions

diff --git a/dev-java/commons-daemon/Manifest b/dev-java/commons-daemon/Manifest
new file mode 100644
index 00000000..576cbb71
--- /dev/null
+++ b/dev-java/commons-daemon/Manifest
@@ -0,0 +1,2 @@
+DIST commons-daemon-1.0.15-src.tar.gz 291128 SHA256 11ee57d2c6b281589c1497b2f88180553f06d5ac1560ce1841e05f89f0342432 SHA512 f20cc8796978fb09b6ecc8d99bb3c8b271b097d74c1f99b286cde213631e7f50a4104f5db2c354f9624ba8b037502d81e327c581b38253b9b216aa2172016e40 WHIRLPOOL 6b3b5f5d12fc9fd15345e71a7bf41f88605b00f9bc0ab5ab5fca3752f4bae1adf6ae6b2c3781a68b00d0609c51cb5cb2f4e399effa40f08be0c5dacc2e230d65
+EBUILD commons-daemon-1.0.15.ebuild 1408 SHA256 30780367f41bd38b03621e162d31eb3f838e8b87a923ba708e20b0c73c7ddde5 SHA512 de229f5745ef650b25c5ede08e145acb7caa55d5c224a10f2699d31e8fd3984f3daf618c102924aa2d925faf6f7ae3f1957acf867815520724075a3a877542ce WHIRLPOOL fb6f37e188c9226e0b1c34e2a6b8ba2f54f2e15d466f75f91358bf8a739621684e5c0823739b622ca171672e62445e304b4bb01c627a9345a2318131910f9bae
diff --git a/dev-java/commons-daemon/commons-daemon-1.0.15.ebuild b/dev-java/commons-daemon/commons-daemon-1.0.15.ebuild
new file mode 100644
index 00000000..59d8c87a
--- /dev/null
+++ b/dev-java/commons-daemon/commons-daemon-1.0.15.ebuild
@@ -0,0 +1,62 @@
+# Copyright 1999-2017 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=5
+
+WANT_AUTOCONF=2.5
+
+JAVA_PKG_IUSE="doc examples source"
+
+inherit autotools flag-o-matic java-pkg-2 java-ant-2
+
+DESCRIPTION="Tools to allow Java programs to run as UNIX daemons"
+SRC_URI="mirror://apache/commons/daemon/source/${P}-src.tar.gz"
+HOMEPAGE="http://commons.apache.org/daemon/"
+
+LICENSE="Apache-2.0"
+SLOT="0"
+KEYWORDS="amd64 ppc64 x86 ~x86-fbsd ~amd64-linux ~x86-linux ~x86-solaris"
+IUSE="kernel_linux"
+
+CDEPEND="kernel_linux? ( sys-libs/libcap )"
+
+DEPEND="
+	${CDEPEND}
+	>=virtual/jdk-1.6
+	>=dev-java/java-config-2
+	source? ( app-arch/zip )"
+
+RDEPEND="
+	${CDEPEND}
+	>=virtual/jre-1.6"
+
+S="${WORKDIR}/${P}-src"
+
+java_prepare() {
+	cd "${S}/src/native/unix" || die
+	sed -i "s/powerpc/powerpc|powerpc64/g" support/apsupport.m4 || die
+	eautoconf
+}
+
+src_configure() {
+	use kernel_linux && append-cppflags -I$( java-config-2 -g JAVA_HOME )/include/linux
+	java-ant-2_src_configure
+	cd "${S}/src/native/unix" || die
+	default
+}
+
+src_compile() {
+	java-pkg-2_src_compile
+	cd "${S}/src/native/unix" || die
+	default
+}
+
+src_install() {
+	dobin src/native/unix/jsvc
+	java-pkg_newjar dist/*.jar
+
+	dodoc README RELEASE-NOTES.txt *.html src/native/unix/CHANGES.txt
+	use doc && java-pkg_dohtml -r dist/docs/*
+	use examples && java-pkg_doexamples src/samples
+	use source && java-pkg_dosrc src/main/java/*
+}