app-pda/libimobiledevice/libimobiledevice-9999.ebuild


1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78

# Copyright 1999-2011 Gentoo Foundation
# Distributed under the terms of the GNU General Public License v2
# $Header: /var/cvsroot/gentoo-x86/app-pda/libimobiledevice/libimobiledevice-1.1.1.ebuild,v 1.5 2011/11/13 11:37:54 ssuominen Exp $

EAPI=3
PYTHON_DEPEND="python? 2:2.6"

inherit python

if [[ ${PV} == "9999" ]] ; then
	inherit git-2
	EGIT_REPO_URI="http://git.sukimashita.com/${PN}.git"
else
	SRC_URI="http://www.libimobiledevice.org/downloads/${P}.tar.bz2"
fi

DESCRIPTION="Support library to communicate with Apple iPhone/iPod Touch devices"
HOMEPAGE="http://www.libimobiledevice.org/"

LICENSE="GPL-2 LGPL-2.1"
SLOT="0"
KEYWORDS="amd64 ~ppc64 x86"
IUSE="python static-libs"

RDEPEND=">=app-pda/libplist-9999[python?]
	>=app-pda/usbmuxd-9999
	>=dev-libs/glib-2.28.6
	dev-libs/libgcrypt
	>=dev-libs/libtasn1-1.1
	>=net-libs/gnutls-1.6.3
	sys-fs/fuse
	virtual/libusb:1"
DEPEND="${RDEPEND}
	dev-util/pkgconfig
	python? ( >=dev-lang/swig-2.0.0 )"

pkg_setup() {
	if use python; then
		python_set_active_version 2
		python_pkg_setup
	fi
}

src_prepare() {
	#sed -i -e 's:1.3.21:2.0.0:g' configure || die

	rm -f py-compile
	ln -s $(type -P true) py-compile
}

src_configure() {
	# --with-swig is same as --without-swig wrt #361029

	local myconf
	use python || myconf="--without-swig"

	econf \
		--disable-dependency-tracking \
		$(use_enable static-libs static) \
		${myconf}
}

src_install() {
	emake DESTDIR="${D}" install || die

	dodoc AUTHORS NEWS README
	dohtml docs/html/*

	find "${D}" -name '*.la' -exec rm -f {} +
}

pkg_postinst() {
	use python && python_mod_optimize imobiledevice
}

pkg_postrm() {
	use python && python_mod_cleanup imobiledevice
}