x11-libs/libdockapp/libdockapp-0.7.2-r2.ebuild


1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46

# Copyright 1999-2020 Gentoo Authors
# Distributed under the terms of the GNU General Public License v2

EAPI=7
inherit autotools font

DESCRIPTION="Window Maker Dock Applet Library"
HOMEPAGE="https://www.dockapps.net/libdockapp"
SRC_URI="https://dev.gentoo.org/~voyageur/distfiles/${P}.tar.gz"

LICENSE="MIT public-domain"
SLOT="0/3"
KEYWORDS="~alpha ~amd64 ~ppc ~ppc64 ~sparc ~x86"
# Required for font eclass
IUSE="+X"
REQUIRED_USE="X"

RDEPEND="x11-libs/libX11
	x11-libs/libXt
	x11-libs/libXext
	x11-libs/libXpm"
DEPEND="${RDEPEND}
	x11-base/xorg-proto"

FONT_S=${S}/fonts
FONT_SUFFIX="gz"
DOCS="README ChangeLog NEWS AUTHORS"
PATCHES=( "${FILESDIR}"/${P}-fno-common.patch )

src_prepare()
{
	default
	eautoreconf
}

src_configure()
{
	# Font installation handled by font eclass
	econf --without-font --without-examples
}

src_install()
{
	emake DESTDIR="${D}" install
	font_src_install
}