blob: 55ea226bc2ca5a9edc6485a1a254f5facae400ed (
plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
79
80
81
82
83
84
85
86
87
88
89
90
91
92
93
94
95
96
97
98
99
100
101
102
103
104
105
106
107
108
109
110
111
112
113
114
115
116
117
118
119
120
121
122
123
124
125
126
127
128
129
130
131
132
133
134
135
136
137
138
139
140
141
142
143
144
145
146
147
148
149
150
151
152
|
# Copyright 1999-2018 Gentoo Foundation
# Distributed under the terms of the GNU General Public License v2
EAPI=6
inherit autotools desktop xdg
DESCRIPTION="A fast and lightweight web browser running in both graphics and text mode"
HOMEPAGE="http://links.twibright.com/"
SRC_URI="http://${PN}.twibright.com/download/${P}.tar.bz2"
LICENSE="GPL-2"
SLOT="2"
KEYWORDS="~alpha amd64 arm ~arm64 hppa ia64 ~mips ppc ppc64 s390 ~sh sparc x86 ~ppc-aix ~amd64-linux ~x86-linux ~ppc-macos ~x64-macos ~x86-macos ~m68k-mint ~sparc-solaris ~x64-solaris ~x86-solaris"
IUSE="bzip2 fbcon gpm ipv6 jpeg libevent libressl livecd lzma ssl suid svga tiff unicode X zlib"
GRAPHICS_DEPEND="media-libs/libpng:0="
RDEPEND="
bzip2? (
app-arch/bzip2
)
fbcon? (
${GRAPHICS_DEPEND}
)
gpm? (
sys-libs/gpm
)
jpeg? (
virtual/jpeg:0
)
libevent? (
dev-libs/libevent:0=
)
livecd? (
${GRAPHICS_DEPEND}
sys-libs/gpm
virtual/jpeg:0
)
lzma? (
app-arch/xz-utils
)
ssl? (
!libressl? ( dev-libs/openssl:0= )
libressl? ( dev-libs/libressl:0= )
)
svga? (
${GRAPHICS_DEPEND}
media-libs/svgalib
)
tiff? (
media-libs/tiff:0
)
X? (
${GRAPHICS_DEPEND}
x11-libs/libXext
)
zlib? (
sys-libs/zlib
)"
DEPEND="${RDEPEND}
virtual/pkgconfig
fbcon? ( virtual/os-headers )
livecd? ( virtual/os-headers )"
REQUIRED_USE="!livecd? ( fbcon? ( gpm ) )
svga? ( suid )"
DOCS=( AUTHORS BRAILLE_HOWTO ChangeLog KEYS NEWS README SITES )
src_prepare() {
xdg_src_prepare
if use unicode; then
pushd intl > /dev/null || die
./gen-intl || die
./synclang || die
popd > /dev/null || die
fi
# error: conditional "am__fastdepCXX" was never defined (for eautoreconf)
sed -i \
-e '/AC_PROG_CXX/s:dnl ::' \
-e 's:AM_CONFIG_HEADER:AC_CONFIG_HEADERS:' \
configure.in || die #467020
# Upstream configure produced by broken autoconf-2.13. This also fixes
# toolchain detection.
mv configure.in configure.ac || die
eautoreconf #131440 and #103483#c23
}
src_configure() {
local myconf
if use livecd; then
export ac_cv_lib_gpm_Gpm_Open=yes
myconf+=' --with-fb --with-libjpeg'
else
export ac_cv_lib_gpm_Gpm_Open=$(usex gpm)
fi
if use X || use fbcon || use svga || use livecd; then
myconf+=' --enable-graphics'
fi
econf \
--without-directfb \
$(use_with ipv6) \
$(use_with ssl) \
$(use_with zlib) \
$(use_with bzip2) \
$(use_with lzma) \
$(use_with svga svgalib) \
$(use_with X x) \
$(use_with fbcon fb) \
$(use_with libevent) \
$(use_with jpeg libjpeg) \
$(use_with tiff libtiff) \
${myconf}
}
src_install() {
HTML_DOCS="doc/links_cal/*"
default
if use X; then
newicon Links_logo.png links.png
make_desktop_entry 'links -g %u' Links links 'Network;WebBrowser'
local d="${ED}"/usr/share/applications
echo 'MimeType=x-scheme-handler/http;' >> "${d}"/*.desktop || die
if use ssl; then
sed -i -e 's:x-scheme-handler/http;:&x-scheme-handler/https;:' \
"${d}"/*.desktop || die
fi
fi
use suid && fperms 4755 /usr/bin/links
}
pkg_preinst() {
use X && xdg_pkg_preinst
}
pkg_postinst() {
use X && xdg_pkg_postinst
}
pkg_postrm() {
use X && xdg_pkg_postrm
}
|
GitWeb