blob: 30f7b9c29e98fd26254b26c4b5bf2c8cba897ab0 (
plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
79
80
81
82
83
84
85
86
87
88
89
90
91
92
93
94
95
96
97
98
99
100
101
102
103
104
105
106
107
108
109
110
111
112
113
114
115
116
117
118
119
120
121
122
123
124
125
126
127
128
129
130
131
132
133
134
135
136
137
138
|
# Copyright 2011-2020 Gentoo Authors
# Distributed under the terms of the GNU General Public License v2
EAPI="6"
CHROMIUM_LANGS="am ar bg bn ca cs da de el en-GB es es-419 et fa fi fil fr gu he
hi hr hu id it ja kn ko lt lv ml mr ms nb nl pl pt-BR pt-PT ro ru sk sl sr
sv sw ta te th tr uk vi zh-CN zh-TW"
inherit chromium-2 eutils gnome2-utils pax-utils unpacker xdg-utils
DESCRIPTION="The web browser from Google"
HOMEPAGE="https://www.google.com/chrome"
if [[ ${PN} == google-chrome ]]; then
KEYWORDS="-* amd64"
MY_PN=${PN}-stable
else
KEYWORDS="-* ~amd64"
MY_PN=${PN}
fi
MY_P="${MY_PN}_${PV}-1"
SRC_URI="https://dl.google.com/linux/chrome/deb/pool/main/g/${MY_PN}/${MY_P}_amd64.deb"
LICENSE="google-chrome"
SLOT="0"
IUSE="selinux"
RESTRICT="bindist mirror strip"
DEPEND=""
RDEPEND="
app-accessibility/at-spi2-atk:2
app-accessibility/at-spi2-core:2
app-arch/bzip2
app-misc/ca-certificates
dev-libs/atk
dev-libs/expat
dev-libs/glib:2
dev-libs/nspr
>=dev-libs/nss-3.26
dev-libs/wayland
media-libs/alsa-lib
media-libs/fontconfig
media-libs/freetype:2
media-libs/mesa[gbm]
net-print/cups
sys-apps/dbus
sys-libs/libcap
x11-libs/cairo
x11-libs/gdk-pixbuf:2
x11-libs/gtk+:3[X]
x11-libs/libdrm
>=x11-libs/libX11-1.5.0
x11-libs/libXcomposite
x11-libs/libXcursor
x11-libs/libXdamage
x11-libs/libXext
x11-libs/libXfixes
x11-libs/libXi
x11-libs/libXrandr
x11-libs/libXrender
x11-libs/libXScrnSaver
x11-libs/libXtst
x11-libs/libxcb
x11-libs/libxkbcommon
x11-libs/pango
x11-misc/xdg-utils
selinux? ( sec-policy/selinux-chromium )
"
QA_PREBUILT="*"
QA_DESKTOP_FILE="usr/share/applications/google-chrome.*\\.desktop"
S=${WORKDIR}
CHROME_HOME="opt/google/chrome${PN#google-chrome}"
pkg_nofetch() {
eerror "Please wait 24 hours and sync your tree before reporting a bug for google-chrome fetch failures."
}
pkg_pretend() {
# Protect against people using autounmask overzealously
use amd64 || die "google-chrome only works on amd64"
}
pkg_setup() {
chromium_suid_sandbox_check_kernel_config
}
src_unpack() {
:
}
src_install() {
dodir /
cd "${ED}" || die
unpacker
rm -r etc usr/share/menu || die
mv usr/share/doc/${MY_PN} usr/share/doc/${PF} || die
gzip -d usr/share/doc/${PF}/changelog.gz || die
gzip -d usr/share/man/man1/${MY_PN}.1.gz || die
if [[ -L usr/share/man/man1/google-chrome.1.gz ]]; then
rm usr/share/man/man1/google-chrome.1.gz || die
dosym ${MY_PN}.1 usr/share/man/man1/google-chrome.1
fi
pushd "${CHROME_HOME}/locales" > /dev/null || die
chromium_remove_language_paks
popd > /dev/null || die
local suffix=
[[ ${PN} == google-chrome-beta ]] && suffix=_beta
[[ ${PN} == google-chrome-unstable ]] && suffix=_dev
local size
for size in 16 24 32 48 64 128 256 ; do
newicon -s ${size} "${CHROME_HOME}/product_logo_${size}${suffix}.png" ${PN}.png
done
pax-mark m "${CHROME_HOME}/chrome"
}
pkg_preinst() {
gnome2_icon_savelist
}
pkg_postrm() {
gnome2_icon_cache_update
xdg_desktop_database_update
}
pkg_postinst() {
gnome2_icon_cache_update
xdg_desktop_database_update
}
|
GitWeb