blob: e8505ae64d2332c0d77cfba7adf7ecf325fe3ea6 (
plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
|
# Copyright 1999-2020 Gentoo Authors
# Distributed under the terms of the GNU General Public License v2
EAPI=7
inherit toolchain-funcs
if [[ ${PV} == "9999" ]] ; then
EGIT_REPO_URI="git://repo.or.cz/${PN}.git
http://repo.or.cz/r/${PN}.git"
inherit git-r3
else
SRC_URI="http://repo.or.cz/w/smatch.git/snapshot/${PV}.tar.gz -> ${P}.tar.gz
mirror://gentoo/${P}.tar.gz"
KEYWORDS="~amd64 ~arm ~hppa ~ia64 ~ppc ~ppc64 ~s390 ~sparc ~x86"
S=${WORKDIR}/${PN}
fi
DESCRIPTION="static analysis tool for C"
HOMEPAGE="http://smatch.sourceforge.net/"
LICENSE="OSL-1.1"
SLOT="0"
IUSE=""
RDEPEND="dev-db/sqlite"
DEPEND="${RDEPEND}"
S=${WORKDIR}/${P}-7a4fdad
src_prepare() {
default
sed -i \
-e '/^CFLAGS =/{s:=:+=:;s:-O2 -finline-functions:${CPPFLAGS}:}' \
Makefile || die
}
_emake() {
# gtk/llvm/xml is used by sparse which we don't install
emake \
PREFIX="${EPREFIX}/usr" \
V=1 \
AR="$(tc-getAR)" \
CC="$(tc-getCC)" \
LD='$(CC)' \
HAVE_GTK2=no \
HAVE_LLVM=no \
HAVE_LIBXML=no \
"$@"
}
src_compile() {
_emake smatch
}
src_test() {
_emake check
}
src_install() {
# default install target installs a lot of sparse cruft
dobin smatch
insinto /usr/share/smatch/smatch_data
doins smatch_data/*
dodoc FAQ README
}
|
GitWeb
