blob: 8d4e6bb18c091cb514edc18f174db482ab159e7c (
plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
|
# Copyright 1999-2022 Gentoo Authors
# Distributed under the terms of the GNU General Public License v2
EAPI=8
PYTHON_COMPAT=( python3_{8..10} )
inherit cmake flag-o-matic llvm llvm.org python-any-r1
DESCRIPTION="The LLVM linker (link editor)"
HOMEPAGE="https://llvm.org/"
LICENSE="Apache-2.0-with-LLVM-exceptions UoI-NCSA"
SLOT="0"
KEYWORDS="amd64 arm arm64 ~ppc ppc64 ~riscv x86"
IUSE="debug test"
RESTRICT="!test? ( test )"
DEPEND="
~sys-devel/llvm-${PV}
"
RDEPEND="
${DEPEND}
"
BDEPEND="
test? (
>=dev-util/cmake-3.16
$(python_gen_any_dep "~dev-python/lit-${PV}[\${PYTHON_USEDEP}]")
)
"
LLVM_COMPONENTS=( lld cmake libunwind/include/mach-o )
LLVM_TEST_COMPONENTS=( llvm/utils/{lit,unittest} )
llvm.org_set_globals
python_check_deps() {
has_version -b "dev-python/lit[${PYTHON_USEDEP}]"
}
pkg_setup() {
LLVM_MAX_SLOT=${PV%%.*} llvm_pkg_setup
use test && python-any-r1_pkg_setup
}
src_unpack() {
llvm.org_src_unpack
# Directory ${WORKDIR}/llvm does not exist with USE="-test",
# but LLVM_MAIN_SRC_DIR="${WORKDIR}/llvm" is set below,
# and ${LLVM_MAIN_SRC_DIR}/../libunwind/include is used by build system
# (lld/MachO/CMakeLists.txt) and is expected to be resolvable
# to existent directory ${WORKDIR}/libunwind/include.
mkdir -p "${WORKDIR}/llvm" || die
}
src_configure() {
# LLVM_ENABLE_ASSERTIONS=NO does not guarantee this for us, #614844
use debug || local -x CPPFLAGS="${CPPFLAGS} -DNDEBUG"
use elibc_musl && append-ldflags -Wl,-z,stack-size=2097152
local mycmakeargs=(
-DBUILD_SHARED_LIBS=ON
-DLLVM_INCLUDE_TESTS=$(usex test)
-DLLVM_MAIN_SRC_DIR="${WORKDIR}/llvm"
)
use test && mycmakeargs+=(
-DLLVM_BUILD_TESTS=ON
-DLLVM_EXTERNAL_LIT="${EPREFIX}/usr/bin/lit"
-DLLVM_LIT_ARGS="$(get_lit_flags)"
-DPython3_EXECUTABLE="${PYTHON}"
)
cmake_src_configure
}
src_test() {
local -x LIT_PRESERVES_TMP=1
cmake_build check-lld
}
|
GitWeb