blob: 11f5f9cf4e195e881cfc2092442f38f8c8bacaa3 (
plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
|
# Copyright 1999-2021 Gentoo Authors
# Distributed under the terms of the GNU General Public License v2
EAPI=7
inherit autotools
DESCRIPTION="M(easuring)buffer is a replacement for buffer with additional functionality"
HOMEPAGE="https://www.maier-komor.de/mbuffer.html"
SRC_URI="https://www.maier-komor.de/software/mbuffer/${P}.tgz"
LICENSE="GPL-3"
SLOT="0"
KEYWORDS="amd64 arm ~arm64 ppc x86"
IUSE="debug ssl test"
REQUIRED_USE="test? ( ssl )"
RESTRICT="!test? ( test )"
RDEPEND="ssl? (
dev-libs/openssl:0=
)"
DEPEND="${RDEPEND}"
PATCHES=(
"${FILESDIR}/${PN}-20180410-sysconfdir.patch"
"${FILESDIR}/${PN}-20200929-find-OBJDUMP.patch"
)
src_prepare() {
ln -s "${DISTDIR}"/${P}.tgz test.tar #258881
default
mv configure.in configure.ac || die
eautoreconf
}
src_configure() {
local myeconfargs=(
$(use_enable ssl md5)
$(use_enable debug)
)
econf "${myeconfargs[@]}"
}
src_test() {
if has usersandbox ${FEATURES} || has network-sandbox ${FEATURES}; then
ewarn "Some tests may fail with FEATURES=usersandbox or"
ewarn "FEATURES=network-sandbox; Skipping tests because"
ewarn "test suite would hang forever in such environments!"
return 0;
fi
# Enforce MAKEOPTS=-j1 because src_test() spawns multiple listener
# using same port and src_install may have problems (with /etc folder)
local -x MAKEOPTS=-j1
default
}
pkg_postinst() {
if ! has_version "app-arch/mt-st"; then
elog ""
elog "If you want autoloader support you need to install \"app-arch/mt-st\" in addition!"
fi
}
|
GitWeb
