blob: e3a1f7ec6ec86d729143096e6f2a978ce582a108 (
plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
|
# Copyright 1999-2022 Gentoo Authors
# Distributed under the terms of the GNU General Public License v2
EAPI=8
inherit autotools systemd
DESCRIPTION="Powerful replacement for inetd"
HOMEPAGE="https://github.com/xinetd-org/xinetd https://github.com/openSUSE/xinetd"
SRC_URI="https://github.com/openSUSE/xinetd/releases/download/${PV}/${P}.tar.xz"
LICENSE="BSD"
SLOT="0"
KEYWORDS="~alpha amd64 arm arm64 ~hppa ~ia64 ~loong ~m68k ~mips ~ppc ppc64 ~riscv ~s390 ~sparc x86"
IUSE="perl rpc selinux tcpd"
DEPEND="
rpc? ( net-libs/libtirpc:= )
selinux? ( sys-libs/libselinux )
tcpd? ( >=sys-apps/tcp-wrappers-7.6-r2 )
"
RDEPEND="
${DEPEND}
perl? ( dev-lang/perl )
"
BDEPEND="virtual/pkgconfig"
PATCHES=(
"${FILESDIR}"/${PN}-2.3.15.4-0001-configure.ac-use-AC_USE_SYSTEM_EXTENSIONS.patch
"${FILESDIR}"/${PN}-2.3.15.4-0002-redirect-drop-deprecated-sys-signal.h-include.patch
)
src_prepare() {
default
sed -i \
-e 's:/usr/bin/kill:/bin/kill:' \
"contrib/${PN}.service" || die
eautoreconf
}
src_configure() {
econf \
$(use_with tcpd libwrap) \
$(use_with selinux labeled-networking) \
$(use_with rpc) \
--with-loadavg
}
src_install() {
default
use perl || rm -f "${ED}"/usr/sbin/xconv.pl
newinitd "${FILESDIR}"/xinetd.rc6 xinetd
newconfd "${FILESDIR}"/xinetd.confd xinetd
systemd_dounit "contrib/${PN}.service"
newdoc contrib/xinetd.conf xinetd.conf.dist.sample
dodoc README.md CHANGELOG
}
|
GitWeb
