blob: 3394d77c062329415ef256f4f9c25259f29a0433 (
plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
79
80
81
82
83
84
85
86
87
|
# Copyright 1999-2021 Gentoo Authors
# Distributed under the terms of the GNU General Public License v2
EAPI=7
inherit multilib toolchain-funcs
if [[ ${PV} == "9999" ]] ; then
EGIT_REPO_URI="git://git.kernel.org/pub/scm/utils/dtc/dtc.git"
inherit git-r3
else
SRC_URI="https://www.kernel.org/pub/software/utils/${PN}/${P}.tar.xz"
KEYWORDS="~alpha ~amd64 ~arm ~arm64 ~hppa ~ia64 ~m68k ~mips ~ppc ~ppc64 ~riscv ~s390 ~sparc ~x86"
fi
DESCRIPTION="Open Firmware device tree compiler"
HOMEPAGE="https://devicetree.org/ https://git.kernel.org/cgit/utils/dtc/dtc.git/"
LICENSE="GPL-2"
SLOT="0"
IUSE="static-libs yaml"
BDEPEND="
sys-devel/bison
sys-devel/flex
virtual/pkgconfig
"
RDEPEND="yaml? ( dev-libs/libyaml )"
DEPEND="${RDEPEND}"
DOCS="
Documentation/dt-object-internal.txt
Documentation/dts-format.txt
Documentation/manual.txt
"
PATCHES=(
"${FILESDIR}"/${PN}-1.4.4-posix-shell.patch
"${FILESDIR}"/${PN}-1.5.0-fdt_check_full-visibility.patch
"${FILESDIR}"/${PN}-1.5.0-gcc-10.patch
)
_emake() {
# valgrind is used only in 'make checkm'
emake \
NO_PYTHON=1 \
NO_VALGRIND=1 \
NO_YAML=$(usex !yaml 1 0) \
\
AR="$(tc-getAR)" \
CC="$(tc-getCC)" \
PKG_CONFIG="$(tc-getPKG_CONFIG)" \
\
V=1 \
\
PREFIX="${EPREFIX}/usr" \
\
LIBDIR="\$(PREFIX)/$(get_libdir)" \
\
"$@"
}
src_prepare() {
default
sed -i \
-e '/^CFLAGS =/s:=:+=:' \
-e '/^CPPFLAGS =/s:=:+=:' \
-e 's:-Werror::' \
-e 's:-g -Os::' \
Makefile || die
tc-export AR CC PKG_CONFIG
}
src_compile() {
_emake
}
src_test() {
_emake check
}
src_install() {
_emake DESTDIR="${D}" install
use static-libs || find "${ED}" -name '*.a' -delete
}
|
GitWeb