blob: 7b70747a4e9b26fb28b587b804290e50bc1eb06b (
plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
|
# Copyright 1999-2020 Gentoo Authors
# Distributed under the terms of the GNU General Public License v2
EAPI=7
PYTHON_COMPAT=( python3_{7,8} )
inherit python-r1
DESCRIPTION="TensorFlow's Visualization Toolkit"
HOMEPAGE="https://www.tensorflow.org/"
SRC_URI="https://files.pythonhosted.org/packages/py3/${PN::1}/${PN}/${P}-py3-none-any.whl -> ${P}.zip"
LICENSE="Apache-2.0"
SLOT="0"
KEYWORDS="~amd64"
IUSE=""
REQUIRED_USE=${PYTHON_REQUIRED_USE}
RDEPEND="
${PYTHON_DEPS}
dev-python/bleach[${PYTHON_USEDEP}]
>=dev-python/google-auth-1.6.3[${PYTHON_USEDEP}]
>=dev-python/google-auth-oauthlib-0.4.1[${PYTHON_USEDEP}]
dev-python/grpcio[${PYTHON_USEDEP}]
dev-python/html5lib[${PYTHON_USEDEP}]
dev-python/markdown[${PYTHON_USEDEP}]
dev-python/numpy[${PYTHON_USEDEP}]
dev-python/protobuf-python[${PYTHON_USEDEP}]
dev-python/six[${PYTHON_USEDEP}]
>=dev-python/setuptools-41[${PYTHON_USEDEP}]
dev-python/werkzeug[${PYTHON_USEDEP}]
dev-python/wheel[${PYTHON_USEDEP}]
>=dev-python/scipy-1.4.1[${PYTHON_USEDEP}]"
BDEPEND="app-arch/unzip
${PYTHON_DEPS}"
PDEPEND="sci-libs/tensorflow[python,${PYTHON_USEDEP}]"
S="${WORKDIR}"
src_prepare() {
eapply_user
rm -rf "${S}/${PN}/_vendor/bleach" || die
rm -rf "${S}/${PN}/_vendor/html5lib" || die
sed -i -e '/_vendor.bleach/d' -e '/_vendor.html5lib/d' "${S}/${P}.dist-info/RECORD" || die "failed to unvendor"
find "${S}/${PN}" -name '*.py' -exec sed -i \
-e 's/^from tensorboard\._vendor import html5lib/import html5lib/' \
-e 's/^from tensorboard\._vendor import bleach/import bleach/' \
-e 's/^from tensorboard\._vendor\.html5lib/from html5lib/' \
-e 's/^from tensorboard\._vendor\.bleach/from bleach/' \
{} + || die "failed to unvendor"
sed -i -e '/tensorboard-plugin-/d' "${S}/${P}.dist-info/METADATA" || die "failed to remove plugin deps"
}
src_install() {
do_install() {
python_domodule "${PN}"
python_domodule "${P}.dist-info"
}
python_foreach_impl do_install
}
|
GitWeb
