blob: 509fa30f426c44afca7e60c44acf8b07f2ff251d (
plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
79
80
81
82
83
84
85
86
87
88
89
90
91
92
93
94
95
96
97
98
99
100
101
102
103
104
105
106
107
108
109
110
111
112
113
114
115
116
117
118
119
120
121
122
123
124
125
126
127
128
129
130
131
|
# Copyright 1999-2020 Gentoo Authors
# Distributed under the terms of the GNU General Public License v2
EAPI=7
PYTHON_COMPAT=( python3_{6,7,8} )
FORTRAN_NEEDED=fortran
FORTRAN_STANDARD=90
inherit desktop fortran-2 python-single-r1 scons-utils toolchain-funcs
DESCRIPTION="Object-oriented tool suite for chemical kinetics, thermodynamics, and transport"
HOMEPAGE="https://www.cantera.org"
SRC_URI="https://github.com/Cantera/${PN}/archive/v${PV}.tar.gz -> ${P}.tar.gz"
LICENSE="BSD"
SLOT="0"
KEYWORDS="amd64 ~x86"
IUSE="+cti fortran pch +python test"
RESTRICT="!test? ( test )"
REQUIRED_USE="
python? ( cti )
${PYTHON_REQUIRED_USE}
"
RDEPEND="
${PYTHON_DEPS}
python? (
$(python_gen_cond_dep '
dev-python/numpy[${PYTHON_MULTI_USEDEP}]
')
)
<sci-libs/sundials-5.3.0:0=
"
DEPEND="
${RDEPEND}
dev-cpp/eigen:3
dev-libs/boost
dev-libs/libfmt
python? (
$(python_gen_cond_dep '
dev-python/cython[${PYTHON_MULTI_USEDEP}]
')
)
test? (
>=dev-cpp/gtest-1.8.0
)
"
PATCHES=(
"${FILESDIR}/${PN}_${PV}_env.patch"
"${FILESDIR}/${PN}_${PV}_env_python_install_prefix.patch"
"${FILESDIR}/${PN}_${PV}_sundials4.patch"
)
pkg_setup() {
fortran-2_pkg_setup
python-single-r1_pkg_setup
}
## Full list of configuration options of Cantera is presented here:
## http://cantera.org/docs/sphinx/html/compiling/config-options.html
src_configure() {
scons_vars=(
CC="$(tc-getCC)"
CXX="$(tc-getCXX)"
cc_flags="${CXXFLAGS}"
cxx_flags="-std=c++11"
debug="no"
FORTRAN="$(tc-getFC)"
FORTRANFLAGS="${FFLAGS}"
optimize_flags="-Wno-inline"
renamed_shared_libraries="no"
use_pch=$(usex pch)
## In some cases other order can break the detection of right location of Boost: ##
system_fmt="y"
system_sundials="y"
system_eigen="y"
env_vars="all"
extra_inc_dirs="/usr/include/eigen3"
)
use test || scons_vars+=( googletest="none" )
scons_targets=(
f90_interface=$(usex fortran y n)
python2_package="none"
)
if use cti ; then
local scons_python=$(usex python full minimal)
scons_targets+=( python3_package="${scons_python}" python3_cmd="${EPYTHON}" )
else
scons_targets+=( python3_package="none" )
fi
}
src_compile() {
escons build "${scons_vars[@]}" "${scons_targets[@]}" prefix="/usr"
}
src_test() {
escons test
}
src_install() {
escons install stage_dir="${D}" libdirname="$(get_libdir)" python3_prefix="$(python_get_sitedir)"
if ! use cti ; then
rm -r "${D}/usr/share/man" || die "Can't remove man files."
else
# Run the byte-compile of modules
python_optimize "${D}/$(python_get_sitedir)/${PN}"
fi
}
pkg_postinst() {
if use cti && ! use python ; then
elog "Cantera was build without 'python' use-flag therefore the CTI tool 'ck2cti'"
elog "will convert Chemkin files to Cantera format without verification of kinetic mechanism."
fi
local post_msg=$(usex fortran "and Fortran " "")
elog "C++ ${post_msg}samples are installed to '/usr/share/${PN}/samples/' directory."
if use python ; then
elog "Python examples are installed to '$(python_get_sitedir)/${PN}/examples/' directories."
fi
}
|
GitWeb