blob: efba5c33f5ba9192095963cd3821cce56657f76e (
plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
79
80
81
82
83
84
85
86
87
88
89
90
91
92
93
94
95
96
97
|
# Copyright 2010-2018 Gentoo Authors
# Distributed under the terms of the GNU General Public License v2
EAPI=6
inherit autotools bash-completion-r1
BITCOINCORE_COMMITHASH="49e34e288005a5b144a642e197b628396f5a0765"
KNOTS_PV="${PV}.knots20180918"
KNOTS_P="bitcoin-${KNOTS_PV}"
DESCRIPTION="Command-line JSON-RPC client specifically for interfacing with bitcoind"
HOMEPAGE="https://bitcoincore.org/ https://bitcoinknots.org/"
SRC_URI="
https://github.com/bitcoin/bitcoin/archive/${BITCOINCORE_COMMITHASH}.tar.gz -> bitcoin-v${PV}.tar.gz
https://bitcoinknots.org/files/0.16.x/${KNOTS_PV}/${KNOTS_P}.patches.txz -> ${KNOTS_P}.patches.tar.xz
"
LICENSE="MIT"
SLOT="0"
KEYWORDS="~amd64 ~amd64-linux ~arm ~arm64 ~mips ~ppc ~x86 ~x86-linux"
IUSE="knots libressl"
DEPEND="
>=dev-libs/boost-1.52.0:=[threads(+)]
dev-libs/libevent:=
dev-libs/univalue:=
!libressl? ( dev-libs/openssl:0=[-bindist] )
libressl? ( dev-libs/libressl:0= )
"
RDEPEND="${DEPEND}"
DOCS=( doc/bips.md doc/release-notes.md )
S="${WORKDIR}/bitcoin-${BITCOINCORE_COMMITHASH}"
pkg_pretend() {
if use knots; then
elog "You are building ${PN} from Bitcoin Knots."
elog "For more information, see:"
elog "https://bitcoinknots.org/files/0.16.x/${KNOTS_PV}/${KNOTS_P}.desc.html"
else
elog "You are building ${PN} from Bitcoin Core."
elog "For more information, see:"
elog "https://bitcoincore.org/en/2018/09/18/release-${PV}/"
fi
}
src_prepare() {
local knots_patchdir="${WORKDIR}/${KNOTS_P}.patches/"
eapply "${knots_patchdir}/${KNOTS_P}.syslibs.patch"
if use knots; then
eapply "${knots_patchdir}/${KNOTS_P}.f.patch"
eapply "${knots_patchdir}/${KNOTS_P}.branding.patch"
eapply "${knots_patchdir}/${KNOTS_P}.ts.patch"
fi
eapply_user
echo '#!/bin/true' >share/genbuild.sh || die
mkdir -p src/obj || die
echo "#define BUILD_SUFFIX gentoo${PVR#${PV}}" >src/obj/build.h || die
eautoreconf
rm -r src/leveldb src/secp256k1 || die
}
src_configure() {
local my_econf=(
--disable-asm
--without-qtdbus
--with-libevent
--without-qrencode
--without-miniupnpc
--disable-tests
--disable-wallet
--disable-zmq
--enable-util-cli
--disable-util-tx
--disable-bench
--without-libs
--without-daemon
--without-gui
--disable-ccache
--disable-static
--with-system-univalue
)
econf "${my_econf[@]}"
}
src_install() {
default
newbashcomp contrib/bitcoin-cli.bash-completion ${PN}
}
|
GitWeb