blob: 43d4ec1636e1681ea35764fa684fbc9f862bd5ca (
plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
79
80
81
82
83
84
85
86
87
|
# Copyright 1999-2023 Gentoo Authors
# Distributed under the terms of the GNU General Public License v2
EAPI=8
PYTHON_COMPAT=( python3_{9..11} )
PYTHON_REQ_USE="sqlite,threads(+)"
DISTUTILS_SINGLE_IMPL=1
DISTUTILS_USE_PEP517=setuptools
inherit distutils-r1 optfeature virtualx xdg
DESCRIPTION="An open source gaming platform for GNU/Linux"
HOMEPAGE="https://lutris.net/"
if [[ ${PV} == *9999* ]] ; then
EGIT_REPO_URI="https://github.com/lutris/lutris.git"
inherit git-r3
else
if [[ ${PV} == *_beta* ]] ; then
SRC_URI="https://github.com/lutris/lutris/archive/refs/tags/v${PV/_/-}.tar.gz -> ${P}.tar.gz"
S="${WORKDIR}"/${P/_/-}
else
SRC_URI="https://lutris.net/releases/${P/-/_}.tar.xz"
S="${WORKDIR}/${PN}"
KEYWORDS="~amd64 ~x86"
fi
fi
LICENSE="GPL-3+ CC0-1.0"
SLOT="0"
RDEPEND="
app-arch/cabextract
app-arch/p7zip
app-arch/unzip
$(python_gen_cond_dep '
dev-python/certifi[${PYTHON_USEDEP}]
dev-python/dbus-python[${PYTHON_USEDEP}]
dev-python/distro[${PYTHON_USEDEP}]
dev-python/lxml[${PYTHON_USEDEP}]
dev-python/pillow[${PYTHON_USEDEP}]
dev-python/pygobject:3[${PYTHON_USEDEP}]
dev-python/pypresence[${PYTHON_USEDEP}]
dev-python/python-evdev[${PYTHON_USEDEP}]
dev-python/pyyaml[${PYTHON_USEDEP}]
dev-python/requests[${PYTHON_USEDEP}]
dev-python/protobuf-python[${PYTHON_USEDEP}]
dev-python/moddb[${PYTHON_USEDEP}]
')
media-sound/fluid-soundfont
|| (
net-libs/webkit-gtk:4[introspection]
net-libs/webkit-gtk:4.1[introspection]
)
x11-apps/mesa-progs
x11-apps/xgamma
x11-apps/xrandr
x11-libs/gtk+:3[introspection]
x11-libs/gdk-pixbuf[jpeg]
"
distutils_enable_tests pytest
DOCS=( AUTHORS README.rst docs/installers.rst docs/steam.rst )
python_test() {
virtx epytest
}
python_install_all() {
distutils-r1_python_install_all
python_fix_shebang "${ED}/usr/share/lutris/bin/lutris-wrapper" #740048
}
pkg_postinst() {
xdg_pkg_postinst
optfeature "running MS Windows games through wine+DXVK/proton or other Vulkan games (plus ICD for your hardware)" media-libs/vulkan-loader
# Quote README.rst
elog ""
elog "Lutris installations are fully automated through scripts, which can"
elog "be written in either JSON or YAML. The scripting syntax is described"
elog "in ${EROOT}/usr/share/doc/${PF}/installers.rst.bz2, and is also"
elog "available online at lutris.net."
}
|
GitWeb