dev-util/elfkickers/elfkickers-3.1a.ebuild


1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37

# Copyright 1999-2021 Gentoo Authors
# Distributed under the terms of the GNU General Public License v2

EAPI=7

inherit toolchain-funcs

MY_PN=${PN/elf/ELF}-${PV}
S=${WORKDIR}/${MY_PN}

DESCRIPTION="collection of programs to manipulate ELF files: sstrip, rebind, elfls, elftoc"
HOMEPAGE="http://www.muppetlabs.com/~breadbox/software/elfkickers.html"
SRC_URI="http://www.muppetlabs.com/~breadbox/pub/software/${MY_PN}.tar.gz"

LICENSE="GPL-2"
SLOT="0"
KEYWORDS="amd64 arm ~hppa ~mips sparc x86"
IUSE="doc"

DEPEND="app-misc/pax-utils"
RDEPEND=""

PATCHES=(
	"${FILESDIR}"/${PN}-3.1-respect-CFLAGS-LDFLAGS.patch
	"${FILESDIR}"/${PN}-3.1-create-destdir-path.patch
	"${FILESDIR}"/add-freebsd-elf-defs.patch
	"${FILESDIR}"/${PN}-3.1-AR.patch
)

src_prepare() {
	default

	tc-export AR CC

	sed -i -e "s:^prefix = /usr/local:prefix = ${D}:" Makefile \
		|| die "sed failed"
}