blob: 82b1c595870213ec12db2e55a2e711b5c5557ef8 (
plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
79
|
# Copyright 1999-2019 Gentoo Authors
# Distributed under the terms of the GNU General Public License v2
EAPI=6
# gedit-3.8 is python3 only, this also per:
# https://bugzilla.redhat.com/show_bug.cgi?id=979450
PYTHON_COMPAT=( python{3_5,3_6} )
inherit gnome.org gnome2-utils meson python-single-r1 xdg
DESCRIPTION="An API documentation browser for GNOME"
HOMEPAGE="https://wiki.gnome.org/Apps/Devhelp"
LICENSE="GPL-3+"
SLOT="0/3-6" # subslot = 3-(libdevhelp-3 soname version)
KEYWORDS="~alpha amd64 ~arm ~ia64 ~ppc ~ppc64 ~sparc x86"
IUSE="gedit gtk-doc +introspection"
REQUIRED_USE="gedit? ( ${PYTHON_REQUIRED_USE} )"
COMMON_DEPEND="
>=dev-libs/glib-2.56:2
>=x11-libs/gtk+-3.22:3[introspection?]
>=net-libs/webkit-gtk-2.20:4[introspection?]
>=gui-libs/amtk-5.0:5
gnome-base/gsettings-desktop-schemas
introspection? ( >=dev-libs/gobject-introspection-1.54:= )
"
RDEPEND="${COMMON_DEPEND}
gedit? (
${PYTHON_DEPS}
app-editors/gedit[introspection,python,${PYTHON_USEDEP}]
dev-python/pygobject:3[${PYTHON_USEDEP}] )
"
# libxml2 required for glib-compile-resources
DEPEND="${COMMON_DEPEND}
${PYTHON_DEPS}
dev-libs/libxml2:2
dev-util/glib-utils
dev-util/itstool
gtk-doc? (
>=dev-util/gtk-doc-1.25
app-text/docbook-xml-dtd:4.3 )
>=sys-devel/gettext-0.19.8
virtual/pkgconfig
"
PATCHES=(
"${FILESDIR}"/${PV}-optional-introspection.patch
"${FILESDIR}"/${PV}-optional-gedit.patch
)
pkg_setup() {
use gedit && python-single-r1_pkg_setup
}
src_configure() {
local emesonargs=(
-Dflatpak_build=false
$(meson_use gedit gedit_plugin)
$(meson_use gtk-doc gtk_doc)
$(meson_use introspection)
)
meson_src_configure
}
src_install() {
meson_src_install
use gedit && python_optimize "${ED%/}"/usr/$(get_libdir)/gedit/plugins
}
pkg_postinst() {
xdg_pkg_postinst
gnome2_schemas_update
}
pkg_postrm() {
xdg_pkg_postrm
gnome2_schemas_update
}
|
GitWeb