blob: 852b7a270164383c33cc94ee64d4b68a1ac31502 (
plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
|
# Copyright 1999-2023 Gentoo Authors
# Distributed under the terms of the GNU General Public License v2
EAPI=8
PYTHON_COMPAT=( python3_{9..11} )
inherit meson python-single-r1
DESCRIPTION="Compiler for Blueprint, a markup language for GTK user interfaces"
HOMEPAGE="https://jwestman.pages.gitlab.gnome.org/blueprint-compiler/
https://gitlab.gnome.org/jwestman/blueprint-compiler/"
if [[ ${PV} == *9999 ]] ; then
inherit git-r3
EGIT_REPO_URI="https://gitlab.gnome.org/jwestman/${PN}.git"
else
SRC_URI="https://gitlab.gnome.org/jwestman/${PN}/-/archive/v${PV}/${PN}-v${PV}.tar.bz2"
S="${WORKDIR}"/${PN}-v${PV}
KEYWORDS="amd64 ~x86"
fi
LICENSE="LGPL-3+"
SLOT="0"
IUSE="doc test"
REQUIRED_USE="${PYTHON_REQUIRED_USE}"
RESTRICT="!test? ( test )"
RDEPEND="
${PYTHON_DEPS}
$(python_gen_cond_dep '
dev-python/pygobject:3[${PYTHON_USEDEP}]
')
"
BDEPEND="
${RDEPEND}
doc? (
$(python_gen_cond_dep '
dev-python/furo[${PYTHON_USEDEP}]
dev-python/sphinx[${PYTHON_USEDEP}]
')
)
test? (
gui-libs/gtk:4[introspection]
)
"
DOCS=( CONTRIBUTING.md MAINTENANCE.md NEWS.md README.md )
src_configure() {
local -a emesonargs=(
$(meson_use doc docs)
)
meson_src_configure
}
src_compile() {
meson_src_compile
use doc && build_sphinx docs
}
src_install() {
meson_src_install
python_optimize
}
|
GitWeb
