blob: c845b48cd4a5358d874674861e9674192ae16ab9 (
plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
|
# Copyright 1999-2022 Gentoo Authors
# Distributed under the terms of the GNU General Public License v2
EAPI=8
inherit cmake
DESCRIPTION="Blocking, shuffling and lossless compression library"
HOMEPAGE="
https://www.blosc.org/
https://github.com/Blosc/c-blosc/
"
SRC_URI="
https://github.com/Blosc/c-blosc/archive/v${PV}.tar.gz
-> ${P}.gh.tar.gz
"
LICENSE="BSD"
SLOT="0/1"
KEYWORDS="~alpha amd64 arm arm64 ~hppa ~ia64 ppc ppc64 ~riscv ~s390 ~sparc x86 ~amd64-linux ~x86-linux"
IUSE="+lz4 +snappy test zlib zstd"
RESTRICT="!test? ( test )"
DEPEND="
lz4? ( >=app-arch/lz4-1.7.5:= )
snappy? ( app-arch/snappy:= )
zlib? ( sys-libs/zlib:= )
zstd? ( app-arch/zstd:= )
"
RDEPEND="
${DEPEND}
"
src_configure() {
# remove bundled libs (just in case)
rm -rf internal-complibs || die
local mycmakeargs=(
-DBUILD_STATIC=OFF
-DBUILD_TESTS=$(usex test)
-DBUILD_BENCHMARKS=OFF
-DBUILD_FUZZERS=OFF
-DDEACTIVATE_LZ4=$(usex !lz4)
-DDEACTIVATE_SNAPPY=$(usex !snappy)
-DDEACTIVATE_ZLIB=$(usex !zlib)
-DDEACTIVATE_ZSTD=$(usex !zstd)
-DPREFER_EXTERNAL_LZ4=ON
# snappy is always external
-DPREFER_EXTERNAL_ZLIB=ON
-DPREFER_EXTERNAL_ZSTD=ON
)
cmake_src_configure
}
|
GitWeb
