blob: 3f1599a36f761e036d643d616c9b01857acd246b (
plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
|
# Copyright 2018-2020 Gentoo Authors
# Distributed under the terms of the GNU General Public License v2
EAPI=7
PYTHON_COMPAT=( python3_{6,7,8,9} )
DISTUTILS_USE_SETUPTOOLS=rdepend
inherit bash-completion-r1 distutils-r1
MY_PV=${PV/_/-}
DESCRIPTION="Multi-container orchestration for Docker"
HOMEPAGE="https://github.com/docker/compose"
SRC_URI="https://github.com/docker/compose/archive/${MY_PV}.tar.gz -> ${P}.tar.gz"
LICENSE="Apache-2.0"
SLOT="0"
KEYWORDS="amd64 arm64"
IUSE="test"
RESTRICT="!test? ( test )"
RDEPEND="dev-python/setuptools[${PYTHON_USEDEP}]
>=dev-python/cached-property-1.2.0[${PYTHON_USEDEP}]
>=dev-python/distro-1.5.0[${PYTHON_USEDEP}]
>=dev-python/docker-py-4.3.1[${PYTHON_USEDEP}]
>=dev-python/dockerpty-0.4.1[${PYTHON_USEDEP}]
>=dev-python/docopt-0.6.1[${PYTHON_USEDEP}]
>=dev-python/python-dotenv-0.13.0[${PYTHON_USEDEP}]
>=dev-python/jsonschema-2.5.1[${PYTHON_USEDEP}]
dev-python/paramiko[${PYTHON_USEDEP}]
>=dev-python/PySocks-1.6.0[${PYTHON_USEDEP}]
>=dev-python/pyyaml-3.10[${PYTHON_USEDEP}]
>=dev-python/requests-2.20.0[${PYTHON_USEDEP}]
>=dev-python/six-1.3.0[${PYTHON_USEDEP}]
>=dev-python/texttable-0.9.0[${PYTHON_USEDEP}]
>=dev-python/websocket-client-0.32.0[${PYTHON_USEDEP}]"
DEPEND="${RDEPEND}
test? (
>=dev-python/pytest-5[${PYTHON_USEDEP}]
>=dev-python/ddt-1.2.2[${PYTHON_USEDEP}]
)"
S="${WORKDIR}/compose-${MY_PV}"
PATCHES=(
# Bug #679968 -- https://bugs.gentoo.org/679968
# Bug #681002 -- https://bugs.gentoo.org/681002
"${FILESDIR}"/${PN}-1.27.0_rc3-setup-py.patch
)
DOCS=( CHANGELOG.md README.md )
src_prepare() {
# Address QA issue "docker-compose.exe: missing alias (symlink) for completed command."
sed 's,^\(complete.*\) docker-compose\.exe\(.*\),\1\2,' -i contrib/completion/bash/docker-compose || die
default
}
python_test() {
distutils_install_for_testing
${PYTHON} -m pytest tests/unit/ || die "tests failed under ${EPYTHON}"
}
python_install_all() {
newbashcomp contrib/completion/bash/docker-compose ${PN}
insinto /usr/share/zsh/site-functions
doins contrib/completion/zsh/*
distutils-r1_python_install_all
}
|
GitWeb
