app-benchmarks/bonnie++/bonnie++-1.97.2.ebuild


1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39

# Copyright 1999-2016 Gentoo Foundation
# Distributed under the terms of the GNU General Public License v2
# $Id$

EAPI="6"

DESCRIPTION="Hard drive bottleneck testing benchmark suite"
HOMEPAGE="http://www.coker.com.au/bonnie++/"
SRC_URI="http://www.coker.com.au/bonnie++/experimental/${P}.tgz"

LICENSE="GPL-2"
SLOT="0"
KEYWORDS="~alpha amd64 ~arm ~hppa ~ia64 ~mips ~ppc ~ppc64 sparc x86"
IUSE="debug"

S="${WORKDIR}/${P}"

PATCHES=(
	"${FILESDIR}/${PN}-1.96-compile-flags.patch" #426788
	"${FILESDIR}"/${PN}-1.97-zcav-array-indexing-fix.patch #309319
)

DOCS=( README.txt README-2.00 debian/changelog credits.txt )
HTML_DOCS=( readme.html )

src_configure() {
	econf \
		$(usex debug "--enable-debug" "") \
		--disable-stripping
}

src_install() {
	dobin bonnie++ zcav bon_csv2html bon_csv2txt
	sed -i -e \
		"s:/usr/share/doc/bonnie++:${EPREFIX}/usr/share/doc/${PF}/html:g" \
		bonnie++.8 || die #431684
	doman bon_csv2html.1 bon_csv2txt.1 bonnie++.8 zcav.8
	einstalldocs
}