1 files changed, 0 insertions, 65 deletions
diff --git a/sys-kernel/vanilla-kernel/vanilla-kernel-5.5.4.ebuild b/sys-kernel/vanilla-kernel/vanilla-kernel-5.5.4.ebuild
deleted file mode 100644
index 50511d1437cd..000000000000
--- a/sys-kernel/vanilla-kernel/vanilla-kernel-5.5.4.ebuild
+++ /dev/null
@@ -1,65 +0,0 @@
-# Copyright 2020 Gentoo Authors
-# Distributed under the terms of the GNU General Public License v2
-
-EAPI=7
-
-inherit kernel-build
-
-MY_P=linux-${PV}
-# https://git.archlinux.org/svntogit/packages.git/log/trunk/config?h=packages/linux
-AMD64_CONFIG_VER=5.5.1-arch1
-AMD64_CONFIG_HASH=2e42789fe089b87dfe6763e7d48781b6a0c33b95
-# https://git.archlinux32.org/packages/log/core/linux/config.i686
-I686_CONFIG_VER=5.5.2-arch1
-I686_CONFIG_HASH=06ff2f85b50e8d38c79597e1dae4aee8b501f057
-
-DESCRIPTION="Linux kernel built from vanilla upstream sources"
-HOMEPAGE="https://www.kernel.org/"
-SRC_URI+=" https://cdn.kernel.org/pub/linux/kernel/v$(ver_cut 1).x/${MY_P}.tar.xz
-	amd64? (
-		https://git.archlinux.org/svntogit/packages.git/plain/trunk/config?h=packages/linux&id=${AMD64_CONFIG_HASH}
-			-> linux-${AMD64_CONFIG_VER}.amd64.config
-	)
-	x86? (
-		https://git.archlinux32.org/packages/plain/core/linux/config.i686?id=${I686_CONFIG_HASH}
-			-> linux-${I686_CONFIG_VER}.i686.config
-	)"
-S=${WORKDIR}/${MY_P}
-
-LICENSE="GPL-2"
-KEYWORDS="~amd64 ~x86"
-
-RDEPEND="
-	!sys-kernel/vanilla-kernel-bin:${SLOT}"
-
-src_prepare() {
-	default
-
-	# prepare the default config
-	case ${ARCH} in
-		amd64)
-			cp "${DISTDIR}"/linux-${AMD64_CONFIG_VER}.amd64.config .config || die
-			;;
-		x86)
-			cp "${DISTDIR}"/linux-${I686_CONFIG_VER}.i686.config .config || die
-			;;
-		*)
-			die "Unsupported arch ${ARCH}"
-			;;
-	esac
-
-	local config_tweaks=(
-		# shove arch under the carpet!
-		-e 's:^CONFIG_DEFAULT_HOSTNAME=:&"gentoo":'
-		# we do support x32
-		-e '/CONFIG_X86_X32/s:.*:CONFIG_X86_X32=y:'
-		# disable signatures
-		-e '/CONFIG_MODULE_SIG/d'
-		-e '/CONFIG_SECURITY_LOCKDOWN/d'
-		# disable compression to allow stripping
-		-e '/CONFIG_MODULE_COMPRESS/d'
-		# disable gcc plugins to unbreak distcc
-		-e '/CONFIG_GCC_PLUGIN_STRUCTLEAK/d'
-	)
-	sed -i "${config_tweaks[@]}" .config || die
-}