1 files changed, 44 insertions, 0 deletions
diff --git a/kde-frameworks/kauth/kauth-5.64.0.ebuild b/kde-frameworks/kauth/kauth-5.64.0.ebuild
new file mode 100644
index 000000000000..716efe94fc52
--- /dev/null
+++ b/kde-frameworks/kauth/kauth-5.64.0.ebuild
@@ -0,0 +1,44 @@
+# Copyright 1999-2019 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=7
+
+PVCUT=$(ver_cut 1-2)
+QTMIN=5.12.3
+VIRTUALX_REQUIRED="test"
+inherit ecm kde.org
+
+DESCRIPTION="Framework to let applications perform actions as a privileged user"
+LICENSE="LGPL-2.1+"
+KEYWORDS="~amd64 ~arm ~arm64 ~x86"
+IUSE="nls +policykit"
+
+BDEPEND="
+	nls? ( >=dev-qt/linguist-tools-${QTMIN}:5 )
+"
+DEPEND="
+	>=kde-frameworks/kcoreaddons-${PVCUT}:5
+	>=dev-qt/qtdbus-${QTMIN}:5
+	>=dev-qt/qtgui-${QTMIN}:5
+	>=dev-qt/qtwidgets-${QTMIN}:5
+	policykit? ( sys-auth/polkit-qt[qt5(+)] )
+"
+RDEPEND="${DEPEND}"
+PDEPEND="policykit? ( kde-plasma/polkit-kde-agent )"
+
+src_configure() {
+	local mycmakeargs=(
+		$(cmake-utils_use_find_package policykit PolkitQt5-1)
+	)
+
+	ecm_src_configure
+}
+
+src_test() {
+	# KAuthHelperTest test fails, bug 654842
+	local myctestargs=(
+		-E "(KAuthHelperTest)"
+	)
+
+	ecm_src_test
+}