1 files changed, 42 insertions, 0 deletions
diff --git a/dev-python/pyquery/pyquery-1.2.11.ebuild b/dev-python/pyquery/pyquery-1.2.11.ebuild
new file mode 100644
index 000000000000..08cb9c610c32
--- /dev/null
+++ b/dev-python/pyquery/pyquery-1.2.11.ebuild
@@ -0,0 +1,42 @@
+# Copyright 1999-2015 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+# $Id$
+
+EAPI=5
+
+PYTHON_COMPAT=( python{2_7,3_3,3_4} )
+
+inherit distutils-r1 eutils
+
+DESCRIPTION="A jQuery-like library for python"
+HOMEPAGE="https://github.com/gawel/pyquery"
+SRC_URI="mirror://pypi/${PN:0:1}/${PN}/${P}.tar.gz"
+
+LICENSE="BSD"
+SLOT="0"
+KEYWORDS="~alpha ~amd64 ~arm ~hppa ~ia64 ~ppc ~ppc64 ~s390 ~sh ~sparc ~x86"
+IUSE="test"
+
+RDEPEND="
+	>=dev-python/lxml-2.1[${PYTHON_USEDEP}]
+	>dev-python/cssselect-0.7.9[${PYTHON_USEDEP}]
+	>=dev-python/webob-1.1.9[${PYTHON_USEDEP}]"
+DEPEND="
+	dev-python/setuptools[${PYTHON_USEDEP}]
+	app-arch/unzip
+	test? ( ${RDEPEND}
+		dev-python/beautifulsoup:python-2[$(python_gen_usedep 'python2*')]
+		dev-python/beautifulsoup:python-3[$(python_gen_usedep 'python3*')]
+		dev-python/requests[${PYTHON_USEDEP}]
+		dev-python/nose[${PYTHON_USEDEP}]
+		dev-python/webtest[${PYTHON_USEDEP}]
+		$(python_gen_cond_dep 'dev-python/restkit[${PYTHON_USEDEP}]' 'python2_7') )"
+
+python_test() {
+	# The suite, it appears, requires this hard setting of PYTHONPATH!
+	PYTHONPATH=. nosetests || die "Tests fail with ${EPYTHON}"
+}
+
+pkg_postinst() {
+	optfeature "Support for BeautifulSoup3 as a parser backend" dev-python/beautifulsoup
+}