1 files changed, 58 insertions, 0 deletions
diff --git a/dev-python/mako/mako-1.2.1.ebuild b/dev-python/mako/mako-1.2.1.ebuild
new file mode 100644
index 000000000000..113cd08e2976
--- /dev/null
+++ b/dev-python/mako/mako-1.2.1.ebuild
@@ -0,0 +1,58 @@
+# Copyright 1999-2022 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+DISTUTILS_USE_PEP517=setuptools
+PYTHON_COMPAT=( pypy3 python3_{8..11} )
+
+inherit distutils-r1
+
+MY_P=${P^}
+DESCRIPTION="A Python templating language"
+HOMEPAGE="
+	https://www.makotemplates.org/
+	https://github.com/sqlalchemy/mako/
+	https://pypi.org/project/Mako/
+"
+SRC_URI="mirror://pypi/${MY_P:0:1}/${PN^}/${MY_P}.tar.gz"
+S="${WORKDIR}/${MY_P}"
+
+LICENSE="MIT"
+SLOT="0"
+KEYWORDS="~alpha ~amd64 ~arm ~arm64 ~hppa ~ia64 ~loong ~m68k ~mips ~ppc ~ppc64 ~riscv ~s390 ~sparc ~x86 ~amd64-linux ~x86-linux ~x64-macos"
+IUSE="doc"
+
+RDEPEND="
+	>=dev-python/markupsafe-0.9.2[${PYTHON_USEDEP}]
+"
+BDEPEND="
+	test? (
+		dev-python/Babel[${PYTHON_USEDEP}]
+	)
+"
+
+distutils_enable_tests pytest
+
+python_test() {
+	local EPYTEST_DESELECT=(
+		# change in pygments
+		test/test_exceptions.py::ExceptionsTest::test_format_exceptions_pygments
+	)
+	[[ ${EPYTHON} == pypy3 ]] && EPYTEST_DESELECT+=(
+		test/test_exceptions.py::ExceptionsTest::test_alternating_file_names
+	)
+	local EPYTEST_IGNORE=(
+		# lingua is not packaged in Gentoo and the skip is currently broken
+		# https://github.com/sqlalchemy/mako/pull/357
+		test/ext/test_linguaplugin.py
+	)
+	epytest
+}
+
+python_install_all() {
+	rm -r doc/build || die
+
+	use doc && local HTML_DOCS=( doc/. )
+	distutils-r1_python_install_all
+}