1 files changed, 48 insertions, 0 deletions
diff --git a/dev-libs/libflatarray/libflatarray-0.3.0-r1.ebuild b/dev-libs/libflatarray/libflatarray-0.3.0-r1.ebuild
new file mode 100644
index 000000000000..5ce31c11e1d3
--- /dev/null
+++ b/dev-libs/libflatarray/libflatarray-0.3.0-r1.ebuild
@@ -0,0 +1,48 @@
+# Copyright 1999-2020 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=7
+
+inherit cmake cuda
+
+DESCRIPTION="Struct of arrays library with object oriented interface for C++"
+HOMEPAGE="
+	http://www.libgeodecomp.org/libflatarray.html
+	https://github.com/STEllAR-GROUP/libflatarray"
+SRC_URI="http://www.libgeodecomp.org/archive/${P}.tar.bz2"
+
+LICENSE="Boost-1.0"
+SLOT="0"
+KEYWORDS="~amd64 ~ppc ~x86"
+IUSE="cuda examples test"
+RESTRICT="!test? ( test )"
+
+DEPEND="
+	cuda? ( dev-util/nvidia-cuda-toolkit )"
+
+src_prepare() {
+	cmake_src_prepare
+	use cuda && cuda_src_prepare
+}
+
+src_configure() {
+	local mycmakeargs=(
+		-DWITH_CUDA=$(usex cuda)
+	)
+	cmake_src_configure
+}
+
+src_install() {
+	cmake_src_install
+
+	if use examples; then
+		docompress -x /usr/share/doc/${PF}
+		dodoc -r examples/
+		dodoc -r "${WORKDIR}"/${P}_build/examples/
+		find "${ED}"/usr/share/doc/${PF} -iname "*cmake*" -exec rm -rf {} + || die
+	fi
+}
+
+src_test() {
+	cmake_build check
+}