1 files changed, 48 insertions, 0 deletions
diff --git a/dev-libs/argtable/argtable-2.13-r1.ebuild b/dev-libs/argtable/argtable-2.13-r1.ebuild
new file mode 100644
index 000000000000..2c4752d6da85
--- /dev/null
+++ b/dev-libs/argtable/argtable-2.13-r1.ebuild
@@ -0,0 +1,48 @@
+# Copyright 1999-2017 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=6
+inherit versionator
+
+DESCRIPTION="An ANSI C library for parsing GNU-style command-line options with minimal fuss"
+HOMEPAGE="http://argtable.sourceforge.net/"
+
+MY_PV="$(replace_version_separator 1 '-')"
+MY_P=${PN}${MY_PV}
+
+SRC_URI="mirror://sourceforge/${PN}/${MY_P}.tar.gz"
+
+LICENSE="LGPL-2"
+SLOT="0"
+KEYWORDS="~amd64 ~x86"
+IUSE="doc debug examples static-libs"
+
+S="${WORKDIR}/${MY_P}"
+
+src_configure() {
+	econf \
+		$(use_enable debug) \
+		$(use_enable static-libs static)
+}
+
+src_install() {
+	emake DESTDIR="${D}" install
+	rm -rf "${D}"/usr/share/doc/${PF}/
+
+	dodoc AUTHORS ChangeLog NEWS README
+
+	if use doc ; then
+		cd "${S}/doc"
+		dodoc *.pdf *.ps
+		docinto html
+		dodoc *.html *.gif
+	fi
+
+	if use examples ; then
+		cd "${S}/example"
+		docinto examples
+		dodoc Makefile *.[ch] README.txt
+	fi
+
+	find "${ED}" -name "*.la" -delete || die "failed to delete .la files"
+}