1 files changed, 67 insertions, 0 deletions
diff --git a/dev-libs/appstream-glib/appstream-glib-0.8.0.ebuild b/dev-libs/appstream-glib/appstream-glib-0.8.0.ebuild
new file mode 100644
index 000000000000..28cc5cc07b30
--- /dev/null
+++ b/dev-libs/appstream-glib/appstream-glib-0.8.0.ebuild
@@ -0,0 +1,67 @@
+# Copyright 1999-2022 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+inherit xdg meson
+
+DESCRIPTION="Provides GObjects and helper methods to read and write AppStream metadata"
+HOMEPAGE="https://people.freedesktop.org/~hughsient/appstream-glib/ https://github.com/hughsie/appstream-glib"
+SRC_URI="https://people.freedesktop.org/~hughsient/${PN}/releases/${P}.tar.xz"
+
+LICENSE="LGPL-2.1+"
+SLOT="0/8" # soname version
+KEYWORDS="~alpha ~amd64 ~arm ~arm64 ~hppa ~ia64 ~ppc ~ppc64 ~riscv ~s390 ~sparc ~x86 ~amd64-linux ~x86-linux ~ppc-macos ~x64-macos ~sparc-solaris ~sparc64-solaris ~x64-solaris ~x86-solaris"
+IUSE="gtk-doc fonts +introspection stemmer"
+
+RDEPEND="
+	>=dev-libs/glib-2.58.0:2
+	sys-apps/util-linux
+	app-arch/libarchive:=
+	>=net-misc/curl-7.56.0
+	>=dev-libs/json-glib-1.1.2
+	>=x11-libs/gdk-pixbuf-2.31.5:2[introspection?]
+
+	fonts? (
+		x11-libs/gtk+:3
+		>=media-libs/freetype-2.4:2
+	)
+	>=media-libs/fontconfig-2.11:1.0
+	dev-libs/libyaml
+	stemmer? ( dev-libs/snowball-stemmer:= )
+	x11-libs/pango
+	introspection? ( >=dev-libs/gobject-introspection-1.54:= )
+"
+DEPEND="${RDEPEND}"
+# libxml2 required for glib-compile-resources
+BDEPEND="
+	dev-util/gperf
+
+	dev-libs/libxml2:2
+	app-text/docbook-xml-dtd:4.2
+	dev-libs/libxslt
+	gtk-doc? (
+		>=dev-util/gtk-doc-1.9
+		app-text/docbook-xml-dtd:4.3
+	)
+	>=sys-devel/gettext-0.19.8
+"
+
+PATCHES=(
+	"${FILESDIR}"/${P}-fix-as-self-test.patch
+)
+
+src_configure() {
+	local emesonargs=(
+		-Ddep11=true
+		-Dbuilder=true
+		-Drpm=false
+		-Dalpm=false
+		$(meson_use fonts)
+		$(meson_use stemmer)
+		-Dman=true
+		$(meson_use gtk-doc)
+		$(meson_use introspection)
+	)
+	meson_src_configure
+}