7 files changed, 315 insertions, 6 deletions
diff --git a/app-doc/gnucash-docs/Manifest b/app-doc/gnucash-docs/Manifest
index 715bac84cf8f..cd26c7d157e6 100644
--- a/app-doc/gnucash-docs/Manifest
+++ b/app-doc/gnucash-docs/Manifest
@@ -1,3 +1,4 @@
 DIST gnucash-docs-3.0.tar.gz 92420576 BLAKE2B 95d8c310b3616b44a814c7c5d6e8b1b586eef12831ea967818bef302e0dde3f0ab8e1b1d4fd0d504173625d87d54738a392ad3d53b8bfa079fd5ba87ac3a2d91 SHA512 908694725de6d9595cb73d4b334f157287a864ff7ba1057bdff7c0fb55660c5828a6b5c1e868eea7fbd0fca4b3b594fb3989092f270446dbd56c07479c6036cf
 DIST gnucash-docs-3.1.tar.gz 92421041 BLAKE2B b169d26cb9fb07a265fb5b8fc492fa8b0ed240be094278416d54542dd4ca074b3d4a182421b75d09c1f6c435891c5637aed646f0d11bdd57a9b71cbc999676dd SHA512 4af1f0b895cc928c109ae4f883efd1b483a5b318e02fcd6ca4ff7631ed4e13bc0f89f28b2f8ea895f9e37f596eb7b84e84732dfac6b2d4fe98b7405603149339
 DIST gnucash-docs-3.2.tar.gz 92387447 BLAKE2B dac502975f885b777c1e91a7ea574789947e1dddfd3239c05973ce57fec41a6d78e605ef37aaf721db4aa4d2bc8f2dda7ed76cc4dc97dd49e30618414e262f15 SHA512 a58a583a457377f529223ced083fb64460b3b0c75a423db08c7f9542711be98fd59bd776bf77309ff91d1c46f22a5ae882d8c0a8ec3fc834d7a8028a95028aad
+DIST gnucash-docs-3.3.tar.gz 92417386 BLAKE2B 200f9b8d3006589eac5f0d66300d658f69f5c55078371c5b416e34784835350de9bd40fc5d85e59116022874294f74e259a034d6ebcaf315b1ea9942b8350c7b SHA512 5887171cbe95f545eb6e647aee2d04a26ab9102643acd8d3e5754000613a7fb08e4470777f7dfbfd0d1ed7609de7a6241cd82f5c7d62f632b2e3751b005bc01e
diff --git a/app-doc/gnucash-docs/gnucash-docs-3.3.ebuild b/app-doc/gnucash-docs/gnucash-docs-3.3.ebuild
new file mode 100644
index 000000000000..186406585218
--- /dev/null
+++ b/app-doc/gnucash-docs/gnucash-docs-3.3.ebuild
@@ -0,0 +1,85 @@
+# Copyright 1999-2018 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=6
+
+PLOCALES="C de it ja pt ru"
+PLOCALE_BACKUP="C"
+
+inherit autotools gnome2 l10n
+
+DESCRIPTION="Documentation package for GnuCash"
+HOMEPAGE="http://www.gnucash.org/"
+SRC_URI="https://github.com/Gnucash/${PN}/archive/${PV}.tar.gz -> ${P}.tar.gz"
+
+SLOT="0"
+LICENSE="GPL-2 FDL-1.1"
+KEYWORDS="~amd64 ~ppc ~ppc64 ~x86"
+
+for my_locale in ${PLOCALES}; do
+	IUSE+=" l10n_${my_locale}"
+done
+
+DEPEND="
+	app-text/docbook-xml-dtd
+	app-text/docbook-xsl-stylesheets
+	app-text/rarian
+	dev-libs/libxml2
+	dev-libs/libxslt
+"
+
+my_l10n_get_locales() {
+	local l locales
+	for l in ${PLOCALES[@]}; do
+		use "l10n_${l}" && locales+=( $l )
+	done
+	if [[ ${#locales[@]} -gt 0 ]]; then
+		echo ${locales[@]}
+	else
+		echo $PLOCALE_BACKUP
+	fi
+}
+
+src_prepare() {
+	default
+	eautoreconf
+}
+
+src_compile() {
+	:
+}
+
+src_install() {
+	local doc_type my_lang
+
+	for doc_type in help guide; do
+		for my_lang in $(my_l10n_get_locales); do
+			case $my_lang in
+				# Both help and guides translated
+				C|de|it|pt) ;;
+				ru|ja) # Only guides translated
+					if [[ ${doc_type} = "help" ]] ; then
+						elog "Help documentation hasn't been translated for $my_lang"
+						elog "Will do English instead."
+						my_lang=C
+					fi
+					;;
+				*)
+					die "Invalid locale: $my_lang"
+					;;
+			esac
+
+			cd "${S}/${doc_type}/${my_lang}" || die
+			emake DESTDIR="${D}" install
+		done
+	done
+
+	cd "${S}" || die
+	einstalldocs
+}
+
+pkg_postinst() {
+	gnome2_pkg_postinst
+	optfeature "You need dev-java/fop to generate pdf files." dev-java/fop
+	optfeature "You need gnome-extra/yelp to view the docs." gnome-extra/yelp
+}
diff --git a/app-office/gnucash/Manifest b/app-office/gnucash/Manifest
index 0b9b77c4e41a..0cd972338cb2 100644
--- a/app-office/gnucash/Manifest
+++ b/app-office/gnucash/Manifest
@@ -1,3 +1,4 @@
 DIST gnucash-2.7.4.tar.bz2 13364512 BLAKE2B 0a552efe5a4f024517c054516eb25b51abb2f934e6fc904afd4b0fb48283f9ebb89583b83b0efefba66d014df16c8997c413d05278d4290c44e4fa2278564b61 SHA512 d096ec2a3907dcd09c936f0a49ef6fb5028a17d2e0ade9e68eae7303530480ce19e08c1864efd862d363fda9ef6343260396b794b3c4ac74544baa2628a310eb
 DIST gnucash-3.2.tar.bz2 13383942 BLAKE2B ce4beb9eab290bbc85c4b3bf68b205a8ebb274056bf10ef1721bce48ec18e4df4b488ce885dc767b4f1e951dabcdc2ba702cb5fe239f249ec50c8d2d1d12a434 SHA512 ef74cbf396096a71316e14500a5b4e57670f9e9c0c5d46f3afe051ccbae2e46a5f14edd8dd805dfb61276b934db286d48ae044160699df82689e2718ed2f7573
+DIST gnucash-3.3.tar.bz2 13440713 BLAKE2B a308af90d8a8e50eb732d29c7eadac1fb75b63006da5bbaa9044039c43c1c17976c6b6fdb1706a08a527b75b1300df3a8ed469151370097b0308a173a170e41b SHA512 4bf0369ca9b3c91c98a0d916f0befc7e5675a246559a6a72dba6592b64f56f3cbd1885b0711e44e8d9cca290be742812763691ae2f639ea31ec534e52e17b3f9
 DIST gtest-1.8.0.tar.gz 1281617 BLAKE2B ac052b4d0eb0d8ded03a8c7dff05177818627b8a51f2dbc2c162b2ee2a5d1323539e7d0d02236d9ebb799995e018f0171c2fdaeb4de3bb339548265e50de79e6 SHA512 1dbece324473e53a83a60601b02c92c089f5d314761351974e097b2cf4d24af4296f9eb8653b6b03b1e363d9c5f793897acae1f0c7ac40149216035c4d395d9d
diff --git a/app-office/gnucash/gnucash-3.3.ebuild b/app-office/gnucash/gnucash-3.3.ebuild
new file mode 100644
index 000000000000..52fda92ce402
--- /dev/null
+++ b/app-office/gnucash/gnucash-3.3.ebuild
@@ -0,0 +1,169 @@
+# Copyright 1999-2018 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=6
+
+# google{test,mock} version
+GV="1.8.0"
+PYTHON_COMPAT=( python3_{4,5,6} )
+
+inherit cmake-utils gnome2-utils python-single-r1 xdg-utils
+
+DESCRIPTION="A personal finance manager"
+HOMEPAGE="http://www.gnucash.org/"
+SRC_URI="https://github.com/Gnucash/${PN}/releases/download/${PV}/${P}.tar.bz2
+		 https://github.com/google/googletest/archive/release-${GV}.tar.gz -> gtest-${GV}.tar.gz"
+
+SLOT="0"
+LICENSE="GPL-2"
+KEYWORDS="~amd64 ~ppc ~ppc64 ~x86"
+
+IUSE="aqbanking chipcard debug doc examples gnome-keyring mysql nls ofx postgres
+	  python quotes -register2 sqlite +gui"
+REQUIRED_USE="
+	chipcard? ( aqbanking )
+	python? ( ${PYTHON_REQUIRED_USE} )"
+
+# libdbi version requirement for sqlite taken from bug #455134
+#
+# dev-libs/boost must always be built with nls enabled.
+RDEPEND="
+	>=dev-libs/glib-2.40.0:2
+	>=dev-libs/libxml2-2.7.0:2
+	>=sys-libs/zlib-1.1.4
+	>=dev-scheme/guile-2.0.0:12=[regex]
+	dev-libs/boost:=[icu,nls]
+	dev-libs/icu:=
+	dev-libs/libxslt
+	aqbanking? (
+		>=net-libs/aqbanking-5[gtk,ofx?]
+		sys-libs/gwenhywfar[gtk]
+		chipcard? ( sys-libs/libchipcard )
+	)
+	gnome-keyring? ( >=app-crypt/libsecret-0.18 )
+	gui? (
+	  gnome-base/dconf
+	  net-libs/webkit-gtk:4=
+	  >=x11-libs/gtk+-3.14.0:3
+	)
+	mysql? (
+		dev-db/libdbi
+		dev-db/libdbi-drivers[mysql]
+	)
+	ofx? ( >=dev-libs/libofx-0.9.1 )
+	postgres? (
+		dev-db/libdbi
+		dev-db/libdbi-drivers[postgres]
+	)
+	python? ( ${PYTHON_DEPS} )
+	quotes? (
+		>=dev-perl/Finance-Quote-1.11
+		dev-perl/Date-Manip
+		dev-perl/HTML-TableExtract
+	)
+	sqlite? (
+		>=dev-db/libdbi-0.9.0
+		>=dev-db/libdbi-drivers-0.9.0[sqlite]
+	)
+"
+
+DEPEND="${RDEPEND}
+	~dev-cpp/gtest-${GV}
+	>=sys-devel/gettext-0.19.6
+	dev-lang/perl
+	dev-perl/XML-Parser
+	sys-devel/libtool
+	virtual/pkgconfig
+"
+
+PDEPEND="doc? (
+	~app-doc/gnucash-docs-${PV}
+	gnome-extra/yelp
+)"
+
+PATCHES=( "${FILESDIR}"/${PN}-3.2-no-gui.patch )
+
+pkg_setup() {
+	use python && python-single-r1_pkg_setup
+	xdg_environment_reset
+}
+
+src_configure() {
+	local sql_on_off="OFF"
+	if use mysql || use postgres || use sqlite ; then
+		sql_on_off="ON"
+	fi
+
+	local mycmakeargs=(
+		-DGMOCK_ROOT="${WORKDIR}"/googletest-release-${GV}/googlemock
+		-DGTEST_ROOT="${WORKDIR}"/googletest-release-${GV}/googletest
+
+		-DDISABLE_NLS=$(usex !nls)
+		-DENABLE_REGISTER2=$(usex register2)
+		-DWITH_AQBANKING=$(usex aqbanking)
+		-DWITH_OFX=$(usex ofx)
+		-DWITH_PYTHON=$(usex python)
+		-DWITH_SQL=${sql_on_off}
+		-DWITH_GNUCASH=$(usex gui)
+	)
+
+	cmake-utils_src_configure
+}
+
+src_test() {
+	if use python ; then
+		cp common/test-core/unittest_support.py \
+		   "${BUILD_DIR}"/common/test-core/ || die
+	fi
+
+	cd "${BUILD_DIR}" || die
+	XDG_DATA_HOME="${T}/$(whoami)" emake check
+}
+
+src_install() {
+	cmake-utils_src_install
+
+	rm "${ED%/}"/usr/share/doc/${PF}/README.dependencies || die
+
+	if use gui ; then
+	  rm "${ED%/}"/usr/share/glib-2.0/schemas/gschemas.compiled || die
+	fi
+
+	if use examples ; then
+		mv "${ED%/}"/usr/share/doc/gnucash \
+		   "${ED%/}"/usr/share/doc/${PF}/examples || die
+		pushd "${ED%/}"/usr/share/doc/${PF}/examples/ > /dev/null || die
+		rm AUTHORS DOCUMENTERS LICENSE NEWS projects.html ChangeLog* \
+		   *win32-bin.txt || die
+		popd > /dev/null || die
+		docompress -x /usr/share/doc/${PF}/examples/
+	else
+		rm -r "${ED%/}"/usr/share/doc/gnucash || die
+	fi
+
+	use aqbanking && dodoc doc/README.HBCI
+	use ofx && dodoc doc/README.OFX
+}
+
+pkg_postinst() {
+	if use gui ; then
+		gnome2_icon_cache_update
+		gnome2_schemas_update
+	fi
+	xdg_desktop_database_update
+	xdg_mimeinfo_database_update
+
+	ewarn "Backup all financial files or databases before using GnuCash >=2.7.0!"
+	ewarn
+	ewarn "GnuCash 2.7.0 introduced large changes in its file format and database"
+	ewarn "schema that WILL prevent you from reverting back to GnuCash 2.6."
+}
+
+pkg_postrm() {
+	if use gui ; then
+		gnome2_icon_cache_update
+		gnome2_schemas_update
+	fi
+	xdg_desktop_database_update
+	xdg_mimeinfo_database_update
+}
diff --git a/dev-libs/re2/Manifest b/dev-libs/re2/Manifest
index 6b073898bfcb..1c0e730eee03 100644
--- a/dev-libs/re2/Manifest
+++ b/dev-libs/re2/Manifest
@@ -2,3 +2,4 @@ DIST re2-2016-05-01.tar.gz 399509 BLAKE2B ec7676da99493bb2be56bd661f8f3bd57b123b
 DIST re2-2016-11-01.tar.gz 379816 BLAKE2B 251c45684fa4f3f85e0138c6f788f7a35fbc2ad8766f6a9bc0daf7305ac2140a1102602cf8843242f7a311ec09bf4fe516b605e39e8c857aa2f475783085c231 SHA512 1be7d2551737cb9dc1031dac9335f82dfb58f3612bdb745bf6c5121334bf8689bb0564b751c23e4c002478cc46cc237ce4da294090adb983b0c1db25a9fac0a7
 DIST re2-2017-03-01.tar.gz 382241 BLAKE2B 0a034267f435386b1bfc1680c98aabf4d18dac40cbce3c5a5705cb6a383d54f81b90e22fdd0f16220434eca2eb1c6a5d28ae7e903cdca2397bbc6c10c11ac703 SHA512 566a3ff6598fc9b26dcabe175efa48becd38459185d6bb86b3abb1856a3e7b0f9b5e302594b1ac4817dcb5968920df43d23279a6cff2a74b6b0c174dc9379f88
 DIST re2-2018-04-01.tar.gz 389724 BLAKE2B 629d5cf82a465dfd2d50a3761f0b6504dba6309e5a2605a6f1fde20cae7e7cbb7bef6703abc12161891cb14e7308db3d18b25e575d3ffd8bbdd5cfba6f067983 SHA512 862d9bcb574ea986b1497d6c079104a0cf27b418a6ec8c24047f0d43ede2c8f7f0bdc6a3ccddaeb746f0d821e3e7fd701f438d7fed101db969785c4b344e0462
+DIST re2-2018-10-01.tar.gz 391254 BLAKE2B 297b9abef94fb3ad95e35bb7ff642a5d47b5bc20b1bc3544c76f8a91ec5b9812a1fad1cd5c6a7d4b7c24baaf15302602e8d1b483bdfc6d1246bf268620a9440e SHA512 91e400856137d16c6319e310dab99b4baa74c0bcf634c97464fccdf4092ffc8e1d5ee2a6714b8114719e2dd92e962d5e970ce1b360a3644a8b395d8fb47431be
diff --git a/dev-libs/re2/re2-0.2018.10.01.ebuild b/dev-libs/re2/re2-0.2018.10.01.ebuild
new file mode 100644
index 000000000000..641a25172807
--- /dev/null
+++ b/dev-libs/re2/re2-0.2018.10.01.ebuild
@@ -0,0 +1,52 @@
+# Copyright 1999-2018 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=7
+
+inherit multilib-minimal toolchain-funcs
+
+# Different date format used upstream.
+RE2_VER=${PV#0.}
+RE2_VER=${RE2_VER//./-}
+
+DESCRIPTION="An efficient, principled regular expression library"
+HOMEPAGE="https://github.com/google/re2"
+SRC_URI="https://github.com/google/re2/archive/${RE2_VER}.tar.gz -> re2-${RE2_VER}.tar.gz"
+
+LICENSE="BSD"
+# NOTE: Always run libre2 through abi-compliance-checker!
+# https://abi-laboratory.pro/tracker/timeline/re2/
+SONAME="gentoo-2017-03-01"
+SLOT="0/${SONAME}"
+KEYWORDS="~amd64 ~arm ~arm64 ~x86"
+IUSE="icu"
+
+RDEPEND="icu? ( dev-libs/icu:0=[${MULTILIB_USEDEP}] )"
+DEPEND="${RDEPEND}"
+BDEPEND="icu? ( virtual/pkgconfig )"
+
+S="${WORKDIR}/re2-${RE2_VER}"
+
+DOCS=( AUTHORS CONTRIBUTORS README doc/syntax.txt )
+HTML_DOCS=( doc/syntax.html )
+
+src_prepare() {
+	default
+	grep -qv '^SONAME=0$' Makefile || die "Check SONAME in Makefile"
+	if use icu; then
+		sed -i -e 's:^# \(\(CC\|LD\)ICU=.*\):\1:' Makefile || die
+	fi
+	multilib_copy_sources
+}
+
+src_configure() {
+	tc-export AR CXX NM
+}
+
+multilib_src_compile() {
+	emake SONAME="${SONAME}"
+}
+
+multilib_src_install() {
+	emake SONAME="${SONAME}" DESTDIR="${D}" prefix="${EPREFIX}/usr" libdir="\$(exec_prefix)/$(get_libdir)" install
+}
diff --git a/eclass/xdg-utils.eclass b/eclass/xdg-utils.eclass
index 2c2d2324c2b7..fe1eef213ea4 100644
--- a/eclass/xdg-utils.eclass
+++ b/eclass/xdg-utils.eclass
@@ -6,7 +6,7 @@
 # gnome@gentoo.org
 # @AUTHOR:
 # Original author: Gilles Dartiguelongue <eva@gentoo.org>
-# @SUPPORTED_EAPIS: 0 1 2 3 4 5 6
+# @SUPPORTED_EAPIS: 0 1 2 3 4 5 6 7
 # @BLURB: Auxiliary functions commonly used by XDG compliant packages.
 # @DESCRIPTION:
 # This eclass provides a set of auxiliary functions needed by most XDG
@@ -16,7 +16,7 @@
 #  * XDG mime information database management
 
 case "${EAPI:-0}" in
-	0|1|2|3|4|5|6) ;;
+	0|1|2|3|4|5|6|7) ;;
 	*) die "EAPI=${EAPI} is not supported" ;;
 esac
 
@@ -67,7 +67,7 @@ xdg_environment_reset() {
 # Updates the .desktop files database.
 # Generates a list of mimetypes linked to applications that can handle them
 xdg_desktop_database_update() {
-	local updater="${EROOT}${DESKTOP_DATABASE_UPDATE_BIN}"
+	local updater="${EROOT%/}${DESKTOP_DATABASE_UPDATE_BIN}"
 
 	if [[ ${EBUILD_PHASE} != post* ]] ; then
 		die "xdg_desktop_database_update must be used in pkg_post* phases."
@@ -79,7 +79,7 @@ xdg_desktop_database_update() {
 	fi
 
 	ebegin "Updating .desktop files database"
-	"${updater}" -q "${EROOT}${DESKTOP_DATABASE_DIR}"
+	"${updater}" -q "${EROOT%/}${DESKTOP_DATABASE_DIR}"
 	eend $?
 }
 
@@ -88,7 +88,7 @@ xdg_desktop_database_update() {
 # Update the mime database.
 # Creates a general list of mime types from several sources
 xdg_mimeinfo_database_update() {
-	local updater="${EROOT}${MIMEINFO_DATABASE_UPDATE_BIN}"
+	local updater="${EROOT%/}${MIMEINFO_DATABASE_UPDATE_BIN}"
 
 	if [[ ${EBUILD_PHASE} != post* ]] ; then
 		die "xdg_mimeinfo_database_update must be used in pkg_post* phases."
@@ -100,6 +100,6 @@ xdg_mimeinfo_database_update() {
 	fi
 
 	ebegin "Updating shared mime info database"
-	"${updater}" "${EROOT}${MIMEINFO_DATABASE_DIR}"
+	"${updater}" "${EROOT%/}${MIMEINFO_DATABASE_DIR}"
 	eend $?
 }