xfce-base/xfce4-settings: Bump to 4.19.2

Signed-off-by: Michał Górny <mgorny@gentoo.org>

2 files changed, 97 insertions, 0 deletions

diff --git a/xfce-base/xfce4-settings/Manifest b/xfce-base/xfce4-settings/Manifest
index a83e1a36f06c..ac9289050205 100644
--- a/xfce-base/xfce4-settings/Manifest
+++ b/xfce-base/xfce4-settings/Manifest
@@ -1,2 +1,3 @@
 DIST xfce4-settings-4.18.4.tar.bz2 1557097 BLAKE2B 0269ed1778becc547ba187c096d7c9938cc00f56fb1c9312c9d0eb9b5344d4785f88abadecf391724699de2cb28b35ffed057f06e85f3e098a902a4047969a9c SHA512 2f9e2de4a3a0cc59b4701b44899464532fbae8805270485d2821b65b9d78be54bb636c4cd4205de97e18c13b20912fcd1f4ca0b3baa561bf1a783829f53a06a0
 DIST xfce4-settings-4.19.1.tar.bz2 2406390 BLAKE2B 3b528d7ea0a44e8a59b0e9612d116a17592db1b57932873b86f218c30721781c25cf5a0bbc3deefde6ef3370947f20033fac282b8a8fd9883ccb33a91f438750 SHA512 9d08c3dda27fcb3832b74cf32bedb4a051d46437f31b07a838f58bd324fca63ad6159558deca0b29de5d22b467c08a690d5eafef5e0581a3bc8782ba1771a937
+DIST xfce4-settings-4.19.2.tar.bz2 2433368 BLAKE2B 00175d94837c0abec841feed5d1ea834160afccae8718f4af11323d65d5d751d288dd2651b06ceee6ec02fa2ec222e5b94322a38fa59fd29a18e64a1eb84c88c SHA512 dc225dc3d4296db1dbfdd93685a29b453faab2c3259e2dd1f162d631b3853c4f2b582facab60814d1babe934c2eac752ef954dff2b285e9340dd5247f131555a
diff --git a/xfce-base/xfce4-settings/xfce4-settings-4.19.2.ebuild b/xfce-base/xfce4-settings/xfce4-settings-4.19.2.ebuild
new file mode 100644
index 000000000000..a0230d2c2ba5
--- /dev/null
+++ b/xfce-base/xfce4-settings/xfce4-settings-4.19.2.ebuild
@@ -0,0 +1,96 @@
+# Copyright 1999-2024 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+PYTHON_COMPAT=( python3_{10..11} )
+
+inherit autotools python-single-r1 xdg-utils
+
+DESCRIPTION="Configuration system for the Xfce desktop environment"
+HOMEPAGE="
+	https://docs.xfce.org/xfce/xfce4-settings/start
+	https://gitlab.xfce.org/xfce/xfce4-settings/
+"
+SRC_URI="https://archive.xfce.org/src/xfce/${PN}/${PV%.*}/${P}.tar.bz2"
+
+LICENSE="GPL-2+"
+SLOT="0"
+KEYWORDS="~amd64 ~arm ~arm64 ~hppa ~ia64 ~loong ~ppc ~ppc64 ~riscv ~sparc ~x86 ~amd64-linux ~x86-linux"
+IUSE="X colord input_devices_libinput libcanberra libnotify upower wayland +xklavier"
+REQUIRED_USE="
+	${PYTHON_REQUIRED_USE}
+	|| ( X wayland )
+"
+
+RDEPEND="
+	${PYTHON_DEPS}
+	>=dev-libs/glib-2.66.0
+	>=x11-libs/gtk+-3.24.0:3[X?,wayland?]
+	>=xfce-base/garcon-0.1.10:=
+	>=xfce-base/exo-0.11.0:=
+	>=xfce-base/libxfce4ui-4.19.5:=
+	>=xfce-base/libxfce4util-4.17.2:=
+	>=xfce-base/xfconf-4.13.0:=
+	colord? ( >=x11-misc/colord-1.0.2:= )
+	libcanberra? ( >=media-libs/libcanberra-0.25[sound] )
+	upower? ( >=sys-power/upower-0.9.8 )
+
+	X? (
+		>=media-libs/fontconfig-2.6.0
+		>=x11-libs/libX11-1.6.7
+		>=x11-libs/libXcursor-1.1.0
+		>=x11-libs/libXi-1.2.0
+		>=x11-libs/libXrandr-1.5.0
+		input_devices_libinput? ( >=x11-drivers/xf86-input-libinput-0.6.0 )
+		libnotify? ( >=x11-libs/libnotify-0.1.3 )
+		xklavier? ( >=x11-libs/libxklavier-5.0 )
+	)
+	wayland? (
+		>=dev-libs/wayland-1.15
+		>=gui-libs/gtk-layer-shell-0.7.0
+	)
+"
+DEPEND="
+	${RDEPEND}
+	X? ( x11-base/xorg-proto )
+"
+# libxml2 for xmllint
+BDEPEND="
+	dev-libs/libxml2
+	dev-util/gdbus-codegen
+	>=sys-devel/gettext-0.19.8
+	virtual/pkgconfig
+"
+
+src_prepare() {
+	default
+	eautomake
+}
+
+src_configure() {
+	local myconf=(
+		$(use_enable upower upower-glib)
+		$(use_enable input_devices_libinput xorg-libinput)
+		$(use_enable libnotify)
+		$(use_enable colord)
+		$(use_enable xklavier libxklavier)
+		$(use_enable libcanberra sound-settings)
+		$(use_enable X x11)
+		$(use_enable wayland)
+	)
+	econf "${myconf[@]}"
+}
+
+src_install() {
+	default
+	find "${D}" -name '*.la' -delete || die
+}
+
+pkg_postinst() {
+	xdg_icon_cache_update
+}
+
+pkg_postrm() {
+	xdg_icon_cache_update
+}