proj/gentoo: Initial commit

This commit represents a new era for Gentoo:
Storing the gentoo-x86 tree in Git, as converted from CVS.

This commit is the start of the NEW history.
Any historical data is intended to be grafted onto this point.

Creation process:
1. Take final CVS checkout snapshot
2. Remove ALL ChangeLog* files
3. Transform all Manifests to thin
4. Remove empty Manifests
5. Convert all stale $Header$/$Id$ CVS keywords to non-expanded Git $Id$
5.1. Do not touch files with -kb/-ko keyword flags.

Signed-off-by: Robin H. Johnson <robbat2@gentoo.org>
X-Thanks: Alec Warner <antarus@gentoo.org> - did the GSoC 2006 migration tests
X-Thanks: Robin H. Johnson <robbat2@gentoo.org> - infra guy, herding this project
X-Thanks: Nguyen Thai Ngoc Duy <pclouds@gentoo.org> - Former Gentoo developer, wrote Git features for the migration
X-Thanks: Brian Harring <ferringb@gentoo.org> - wrote much python to improve cvs2svn
X-Thanks: Rich Freeman <rich0@gentoo.org> - validation scripts
X-Thanks: Patrick Lauer <patrick@gentoo.org> - Gentoo dev, running new 2014 work in migration
X-Thanks: Michał Górny <mgorny@gentoo.org> - scripts, QA, nagging
X-Thanks: All of other Gentoo developers - many ideas and lots of paint on the bikeshed

1 files changed, 92 insertions, 0 deletions

diff --git a/x11-wm/enlightenment/enlightenment-0.17.9999.ebuild b/x11-wm/enlightenment/enlightenment-0.17.9999.ebuild
new file mode 100644
index 000000000000..d1ada7b5919e
--- /dev/null
+++ b/x11-wm/enlightenment/enlightenment-0.17.9999.ebuild
@@ -0,0 +1,92 @@
+# Copyright 1999-2015 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+# $Id$
+
+EAPI="5"
+
+MY_P=${P/_/-}
+
+if [[ ${PV} == *9999 ]] ; then
+	EGIT_SUB_PROJECT="core"
+	EGIT_URI_APPEND="${PN}"
+else
+	SRC_URI="http://download.enlightenment.org/rel/apps/${PN}/${MY_P}.tar.xz"
+	EKEY_STATE="snap"
+fi
+
+inherit enlightenment
+
+DESCRIPTION="Enlightenment DR17 window manager"
+
+LICENSE="BSD-2"
+KEYWORDS="~amd64 ~arm ~x86"
+SLOT="0.17/${PV%%_*}"
+
+# The @ is just an anchor to expand from
+__EVRY_MODS=""
+__CONF_MODS="
+	+@applications +@comp +@dialogs +@display
+	+@interaction +@intl +@menus
+	+@paths +@performance +@randr +@shelves +@theme +@wallpaper2
+	+@window-manipulation +@window-remembers"
+__NORM_MODS="
+	@access +@appmenu +@backlight +@bluez4 +@battery +@clock
+	+@connman +@contact +@cpufreq +@everything +@fileman
+	+@fileman-opinfo +@gadman +@ibar +@ibox +@illume2 +@mixer +@msgbus
+	+@music-control +@notification +@pager +@quickaccess +@shot
+	+@start +@syscon +@systray +@tasks +@teamwork +@temperature +@tiling
+	+@winlist +@wizard @wl-desktop-shell @wl-screenshot +@xkbswitch"
+IUSE_E_MODULES="
+	${__CONF_MODS//@/enlightenment_modules_conf-}
+	${__NORM_MODS//@/enlightenment_modules_}"
+
+IUSE="pam spell static-libs systemd +udev ukit wayland ${IUSE_E_MODULES}"
+
+RDEPEND="
+	pam? ( sys-libs/pam )
+	systemd? ( sys-apps/systemd )
+	wayland? (
+		dev-libs/efl[wayland]
+		>=dev-libs/wayland-1.2.0
+		>=x11-libs/pixman-0.31.1
+		>=x11-libs/libxkbcommon-0.3.1
+	)
+	>=dev-libs/efl-${PV}[X]
+	>=media-libs/elementary-${PV}
+	x11-libs/xcb-util-keysyms"
+DEPEND="${RDEPEND}"
+
+S=${WORKDIR}/${MY_P}
+
+src_prepare() {
+	epatch "${FILESDIR}"/quickstart.diff
+	enlightenment_src_prepare
+}
+
+src_configure() {
+	E_ECONF=(
+		--disable-install-sysactions
+		$(use_enable doc)
+		--disable-device-hal
+		$(use_enable nls)
+		$(use_enable pam)
+		$(use_enable systemd)
+		--enable-device-udev
+		$(use_enable udev mount-eeze)
+		$(use_enable ukit mount-udisks)
+		$(use_enable wayland wayland-clients)
+	)
+	local u c
+	for u in ${IUSE_E_MODULES} ; do
+		u=${u#+}
+		c=${u#enlightenment_modules_}
+		E_ECONF+=( $(use_enable ${u} ${c}) )
+	done
+	enlightenment_src_configure
+}
+
+src_install() {
+	enlightenment_src_install
+	insinto /etc/enlightenment
+	newins "${FILESDIR}"/gentoo-sysactions.conf sysactions.conf
+}