x11-libs/libva-intel-driver: add a use flag to enable hybrid hardware acceleration

This feature is supported by Intel Haswell and newer architectures.

Signed-off-by: Kai-Chun Ning <kaichun.ning@gmail.com>
Signed-off-by: Conrad Kostecki <conikost@gentoo.org>

2 files changed, 63 insertions, 0 deletions

diff --git a/x11-libs/libva-intel-driver/libva-intel-driver-2.4.1-r2.ebuild b/x11-libs/libva-intel-driver/libva-intel-driver-2.4.1-r2.ebuild
new file mode 100644
index 000000000000..2adee1dcc69b
--- /dev/null
+++ b/x11-libs/libva-intel-driver/libva-intel-driver-2.4.1-r2.ebuild
@@ -0,0 +1,60 @@
+# Copyright 1999-2020 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=7
+
+MY_PN="intel-vaapi-driver"
+if [[ ${PV} = *9999* ]] ; then # Live ebuild
+	inherit git-r3
+	EGIT_REPO_URI="https://github.com/intel/intel-vaapi-driver"
+fi
+
+inherit autotools multilib-minimal
+
+DESCRIPTION="HW video decode support for Intel integrated graphics"
+HOMEPAGE="https://github.com/intel/intel-vaapi-driver"
+if [[ ${PV} != *9999* ]] ; then
+	SRC_URI="https://github.com/intel/${MY_PN}/releases/download/${PV}/${MY_PN}-${PV}.tar.bz2"
+	S="${WORKDIR}/${MY_PN}-${PV}"
+	KEYWORDS="~amd64 ~x86 ~amd64-linux ~x86-linux"
+fi
+
+LICENSE="MIT"
+SLOT="0"
+IUSE="hybrid wayland X"
+RESTRICT="test" # No tests
+
+RDEPEND="
+	>=x11-libs/libdrm-2.4.52[video_cards_intel,${MULTILIB_USEDEP}]
+	>=x11-libs/libva-2.4.0:=[X?,wayland?,drm,${MULTILIB_USEDEP}]
+
+	hybrid? (
+		>=x11-libs/intel-hybrid-codec-driver-2.0.0[X?,wayland?]
+	)
+
+	wayland? (
+		>=dev-libs/wayland-1.11[${MULTILIB_USEDEP}]
+		>=media-libs/mesa-9.1.6[egl(+),${MULTILIB_USEDEP}]
+	)
+"
+DEPEND="${RDEPEND}"
+BDEPEND="virtual/pkgconfig"
+
+src_prepare() {
+	eapply_user
+	sed -e 's/intel-gen4asm/\0diSaBlEd/g' -i configure.ac || die
+	eautoreconf
+}
+
+multilib_src_configure() {
+	local myconf=(
+		$(use_enable hybrid hybrid-codec)
+		$(use_enable wayland)
+		$(use_enable X x11)
+	)
+	ECONF_SOURCE="${S}" econf "${myconf[@]}"
+}
+
+multilib_src_install_all() {
+	find "${D}" -name "*.la" -delete || die
+}
diff --git a/x11-libs/libva-intel-driver/metadata.xml b/x11-libs/libva-intel-driver/metadata.xml
index da593f3141e2..fed131d8322d 100644
--- a/x11-libs/libva-intel-driver/metadata.xml
+++ b/x11-libs/libva-intel-driver/metadata.xml
@@ -5,6 +5,9 @@
     <email>aballier@gentoo.org</email>
     <name>Alexis Ballier</name>
   </maintainer>
+  <use>
+    <flag name="hybrid">Enable support for hybrid vaapi hardware acceleration on Intel Haswell and newer architectures</flag>
+  </use>
   <upstream>
     <remote-id type="github">intel/intel-vaapi-driver</remote-id>
   </upstream>