www-apps/nikola: adjust deps

Package-Manager: Portage-3.0.3, Repoman-3.0.0
RepoMan-Options: --force
Signed-off-by: Thomas Deutschmann <whissi@gentoo.org>

2 files changed, 64 insertions, 0 deletions

diff --git a/www-apps/nikola/metadata.xml b/www-apps/nikola/metadata.xml
index 929eafbf40bf..2c91832336bd 100644
--- a/www-apps/nikola/metadata.xml
+++ b/www-apps/nikola/metadata.xml
@@ -26,6 +26,9 @@
       Add support for <pkg>dev-python/jinja</pkg> as alternative templating
       engine to Mako
     </flag>
+    <flag name="server">
+      Enable support for built-in web server using <pkg>dev-python/aiohttp</pkg>
+    </flag>
     <flag name="watchdog">
       Use <pkg>dev-python/watchdog</pkg> to monitor file system events
     </flag>
diff --git a/www-apps/nikola/nikola-8.1.1-r1.ebuild b/www-apps/nikola/nikola-8.1.1-r1.ebuild
new file mode 100644
index 000000000000..8abf4ceff6cf
--- /dev/null
+++ b/www-apps/nikola/nikola-8.1.1-r1.ebuild
@@ -0,0 +1,61 @@
+# Copyright 1999-2020 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=7
+PYTHON_COMPAT=( python3_{6,7,8} )
+DISTUTILS_USE_SETUPTOOLS=rdepend
+
+inherit distutils-r1
+
+MY_PN="Nikola"
+MY_P="${MY_PN}-${PV}"
+
+DESCRIPTION="A static website and blog generator"
+HOMEPAGE="https://getnikola.com/"
+SRC_URI="mirror://pypi/${MY_PN:0:1}/${MY_PN}/${MY_P}.tar.gz"
+
+LICENSE="MIT Apache-2.0 CC0-1.0 public-domain"
+SLOT="0"
+KEYWORDS="~amd64"
+IUSE="assets charts hyphenation ipython jinja server watchdog webmedia"
+REQUIRED_USE="server? ( watchdog )"
+RESTRICT="test" # needs coveralls
+
+DEPEND=">=dev-python/docutils-0.13[${PYTHON_USEDEP}]" # needs rst2man to build manpage
+RDEPEND="${DEPEND}
+	>=dev-python/Babel-2.6.0[${PYTHON_USEDEP}]
+	>=dev-python/blinker-1.3[${PYTHON_USEDEP}]
+	>=dev-python/doit-0.32[${PYTHON_USEDEP}]
+	>=dev-python/lxml-3.3.5[${PYTHON_USEDEP}]
+	>=dev-python/mako-1.0[${PYTHON_USEDEP}]
+	>=dev-python/markdown-3.0.0[${PYTHON_USEDEP}]
+	>=dev-python/natsort-3.5.2[${PYTHON_USEDEP}]
+	>=dev-python/piexif-1.0.3[${PYTHON_USEDEP}]
+	>=dev-python/pygments-1.6[${PYTHON_USEDEP}]
+	>=dev-python/PyRSS2Gen-1.1[${PYTHON_USEDEP}]
+	>=dev-python/python-dateutil-2.6.0[${PYTHON_USEDEP}]
+	>=dev-python/requests-2.2.0[${PYTHON_USEDEP}]
+	>=dev-python/unidecode-0.04.16[${PYTHON_USEDEP}]
+	>=dev-python/yapsy-1.11.223[${PYTHON_USEDEP}]
+	dev-python/pillow[jpeg,${PYTHON_USEDEP}]
+	dev-python/cloudpickle[${PYTHON_USEDEP}]
+	assets? ( >=dev-python/webassets-0.10.1[${PYTHON_USEDEP}] )
+	charts? ( >=dev-python/pygal-2.0.1[${PYTHON_USEDEP}] )
+	hyphenation? ( >=dev-python/pyphen-0.9.1[${PYTHON_USEDEP}] )
+	ipython? ( >=dev-python/ipython-2.0.0[notebook,${PYTHON_USEDEP}] )
+	jinja? ( >=dev-python/jinja-2.7.2[${PYTHON_USEDEP}] )
+	server? ( dev-python/aiohttp[${PYTHON_USEDEP}] )
+	watchdog? ( >=dev-python/watchdog-0.8.3[${PYTHON_USEDEP}] )
+	webmedia? ( >=dev-python/micawber-0.3.0[${PYTHON_USEDEP}] )"
+
+S="${WORKDIR}/${MY_P}"
+
+src_install() {
+	distutils-r1_src_install
+
+	# hackish way to remove docs that ended up in the wrong place
+	rm -rv "${ED}/usr/share/doc/${PN}" || die
+
+	dodoc AUTHORS.txt CHANGES.txt README.rst docs/*.rst
+	gunzip "${ED}/usr/share/man/man1/${PN}.1.gz" || die
+}