www-apache/mod_gnutls: enable lfs flags on 0.12.0

Closes: https://bugs.gentoo.org/856349
Signed-off-by: Joonas Niilola <juippis@gentoo.org>

1 files changed, 94 insertions, 0 deletions

diff --git a/www-apache/mod_gnutls/mod_gnutls-0.12.0-r1.ebuild b/www-apache/mod_gnutls/mod_gnutls-0.12.0-r1.ebuild
new file mode 100644
index 000000000000..f52b033c580c
--- /dev/null
+++ b/www-apache/mod_gnutls/mod_gnutls-0.12.0-r1.ebuild
@@ -0,0 +1,94 @@
+# Copyright 1999-2022 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=7
+
+PYTHON_COMPAT=( python3_{8..10} )
+
+inherit autotools flag-o-matic apache-module python-any-r1
+
+DESCRIPTION="mod_gnutls uses GnuTLS for SSL/TLS encryption in Apache2 (compare to mod_ssl)"
+HOMEPAGE="https://mod.gnutls.org/"
+SRC_URI="https://mod.gnutls.org/downloads/${P}.tar.bz2"
+
+LICENSE="Apache-2.0"
+SLOT="0"
+KEYWORDS="amd64 x86"
+IUSE="test"
+
+TEST_REQUIRED_APACHE_MODULES="apache2_modules_proxy,apache2_modules_proxy_http"
+
+COMMON_DEPEND=">=net-libs/gnutls-3.3.0:=[pkcs11]"
+
+DEPEND="${COMMON_DEPEND}
+	$(python_gen_any_dep '
+		dev-python/pyyaml[${PYTHON_USEDEP}]
+	')
+	test? (
+		app-crypt/monkeysphere
+		>=net-libs/gnutls-3.3.0:=[tools]
+		net-misc/curl
+		|| (
+			www-servers/apache[apache2_mpms_worker,${TEST_REQUIRED_APACHE_MODULES}]
+			www-servers/apache[apache2_mpms_prefork,${TEST_REQUIRED_APACHE_MODULES}]
+			www-servers/apache[apache2_mpms_event,${TEST_REQUIRED_APACHE_MODULES}]
+		)
+	)"
+
+RDEPEND="${COMMON_DEPEND}"
+BDEPEND="
+	virtual/pkgconfig
+"
+
+RESTRICT="!test? ( test )"
+
+APACHE2_MOD_CONF="47_${PN}"
+APACHE2_MOD_DEFINE="GNUTLS"
+
+DOCFILES="CHANGELOG NOTICE README"
+
+need_apache2_4
+
+python_check_deps() {
+	has_version "dev-python/pyyaml[${PYTHON_USEDEP}]"
+}
+
+pkg_setup() {
+	# Calling depend.apache_pkg_setup fails because we do not have
+	# "apache2" in IUSE but the function expects this in order to call
+	# _init_apache2_late which sets the APACHE_MODULESDIR variable.
+	_init_apache2
+	_init_apache2_late
+
+	python-any-r1_pkg_setup
+}
+
+src_prepare() {
+	default
+	eautoreconf
+}
+
+src_configure() {
+	# Add LFS flags, enable x86 support. #856349
+	append-lfs-flags
+
+	local myeconfargs=(
+		--with-apxs="${APXS}"
+		--disable-strict
+		--disable-doxygen-dot
+		--disable-doxygen-doc
+		--disable-doxygen-html
+		--disable-doxygen-pdf
+		--disable-valgrind-test
+		ac_cv_path_UNSHARE=no
+	)
+	econf "${myeconfargs[@]}"
+}
+
+src_compile() {
+	emake
+}
+
+src_install() {
+	apache-module_src_install
+}