sys-kernel/ck-sources: v.bump (4.9.45 & 4.12.9)

Package-Manager: Portage-2.3.6, Repoman-2.3.1

1 files changed, 60 insertions, 0 deletions

diff --git a/sys-kernel/ck-sources/ck-sources-4.12.9.ebuild b/sys-kernel/ck-sources/ck-sources-4.12.9.ebuild
new file mode 100644
index 000000000000..a146ed2441b0
--- /dev/null
+++ b/sys-kernel/ck-sources/ck-sources-4.12.9.ebuild
@@ -0,0 +1,60 @@
+# Copyright 1999-2017 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI="6"
+ETYPE="sources"
+KEYWORDS="~amd64 ~x86"
+
+HOMEPAGE="https://dev.gentoo.org/~mpagano/genpatches/
+	http://users.tpg.com.au/ckolivas/kernel/"
+
+K_WANT_GENPATCHES="base extras experimental"
+K_EXP_GENPATCHES_PULL="1"
+K_EXP_GENPATCHES_NOUSE="1"
+K_GENPATCHES_VER="10"
+K_SECURITY_UNSUPPORTED="1"
+K_DEBLOB_AVAILABLE="1"
+
+PYTHON_COMPAT=( python2_7 )
+inherit python-any-r1 kernel-2
+detect_version
+detect_arch
+
+DEPEND="deblob? ( ${PYTHON_DEPS} )"
+
+K_BRANCH_ID="${KV_MAJOR}.${KV_MINOR}"
+
+DESCRIPTION="Con Kolivas' high performance patchset and Gentoo's genpatches for Linux ${K_BRANCH_ID}"
+
+CK_VERSION="2"
+
+CK_FILE="patch-${K_BRANCH_ID}-ck${CK_VERSION}.xz"
+
+CK_BASE_URL="http://ck.kolivas.org/patches/4.0"
+CK_LVER_URL="${CK_BASE_URL}/${K_BRANCH_ID}/${K_BRANCH_ID}-ck${CK_VERSION}"
+CK_URI="${CK_LVER_URL}/${CK_FILE}"
+
+SRC_URI="${KERNEL_URI} ${GENPATCHES_URI} ${ARCH_URI} ${CK_URI}"
+
+UNIPATCH_LIST="${DISTDIR}/${CK_FILE}"
+UNIPATCH_STRICTORDER="yes"
+
+# ck-patches already includes BFQ (similar version as genpatches "experimental" USE flag)
+# what's not included is: "additional cpu optimizations" (5010) from genpatches experimental
+
+K_EXP_GENPATCHES_LIST="5010_*.patch*"
+
+pkg_setup() {
+	use deblob && python-any-r1_pkg_setup
+	kernel-2_pkg_setup
+}
+
+src_prepare() {
+
+#-- Comment out CK's EXTRAVERSION in Makefile ---------------------------------
+
+	# linux-info eclass cannot handle recursively expanded variables in Makefile #490328
+	sed -i -e 's/\(^EXTRAVERSION :=.*$\)/# \1/' "${S}/Makefile" || die
+
+	kernel-2_src_prepare
+}