sys-apps/fwupd: Bump to version 1.1.0

This also fixes build with USE="pkcs7".

Closes: https://bugs.gentoo.org/659698
Package-Manager: Portage-2.3.42, Repoman-2.3.9

3 files changed, 104 insertions, 0 deletions

diff --git a/sys-apps/fwupd/Manifest b/sys-apps/fwupd/Manifest
index 7b9b5c1ad8d2..8523f48cf5cb 100644
--- a/sys-apps/fwupd/Manifest
+++ b/sys-apps/fwupd/Manifest
@@ -1,2 +1,3 @@
 DIST fwupd-1.0.6.tar.gz 1569675 BLAKE2B 1e6b4acc52696cc08086647ce69d4901e78201817423a53f1a6af5f9c5b7be658a5f343c88aa358788aa9d51859b29d8ea7269ec855841652a37a88ba577e01e SHA512 8daaf5d5cb91260c443448a874f92d948bf878dc44c586dbd4a75323dd834ba3b106fe570e30c7a0aefe4c4a7008b6db1ec2948a948b3fb94906ef1fe3f2e35a
 DIST fwupd-1.0.8.tar.gz 1584132 BLAKE2B 7744d14a02bd9847c0c1efe8ff8365abccf9d5213150687815d3e1236844ec71dbf161e5f5d7be32103c3613640680b5b2a017f1a60a30df93fc55bf5d765f74 SHA512 11bdc1dd77697b690e849bde59e54cf289cde32f410f9f7e8911a874f0a265b091ac2e335f784f54b64f835f2750a63a74092cc5eaf7a6c70eaa6d06995d131e
+DIST fwupd-1.1.0.tar.gz 1636214 BLAKE2B 492c33eb54852dd7d73f511dd6e5aa222b35e1898105bbfb291e1095c3968101597185cff2a1889e9da5728fdd0c8d4638e7e2102b12cf7659a1b6612ca0e9b7 SHA512 058d4564cf922b5056f6197261d77b97db7238a1658d69d9b29bec70a44542a5a131071935747e0cc963661a61b242ca98375ed8da920f819d37a706aec0c2ae
diff --git a/sys-apps/fwupd/fwupd-1.1.0.ebuild b/sys-apps/fwupd/fwupd-1.1.0.ebuild
new file mode 100644
index 000000000000..4bf84845fd06
--- /dev/null
+++ b/sys-apps/fwupd/fwupd-1.1.0.ebuild
@@ -0,0 +1,102 @@
+# Copyright 1999-2018 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=6
+
+# Package requires newer meson than eclass provides
+MESON_AUTO_DEPEND="no"
+PYTHON_COMPAT=( python3_4 python3_5 python3_6 )
+
+inherit meson python-single-r1 vala xdg-utils
+
+DESCRIPTION="Aims to make updating firmware on Linux automatic, safe and reliable"
+HOMEPAGE="https://fwupd.org"
+SRC_URI="https://github.com/hughsie/${PN}/archive/${PV}.tar.gz -> ${P}.tar.gz"
+
+LICENSE="GPL-2+"
+
+SLOT="0"
+KEYWORDS="~amd64 ~x86"
+IUSE="colorhug dell doc gpg +man pkcs7 redfish systemd test uefi"
+REQUIRED_USE="
+	${PYTHON_REQUIRED_USE}
+	dell? ( uefi )
+"
+
+RDEPEND="
+	${PYTHON_DEPS}
+	app-arch/libarchive:=
+	dev-db/sqlite
+	>=dev-libs/appstream-glib-0.7.4:=[introspection]
+	>=dev-libs/glib-2.45.8:2
+	dev-libs/libgpg-error
+	dev-libs/libgudev:=
+	>=dev-libs/libgusb-0.2.9[introspection]
+	dev-python/pillow[${PYTHON_USEDEP}]
+	dev-python/pycairo[${PYTHON_USEDEP}]
+	dev-python/pygobject:3[cairo,${PYTHON_USEDEP}]
+	>=net-libs/libsoup-2.51.92:2.4[introspection]
+	>=sys-auth/polkit-0.103
+	virtual/libelf:0=
+	colorhug? ( >=x11-misc/colord-1.2.12:0= )
+	dell? (
+		sys-libs/efivar
+		>=sys-libs/libsmbios-2.4.0
+	)
+	gpg? (
+		app-crypt/gpgme
+		dev-libs/libgpg-error
+	)
+	pkcs7? ( >=net-libs/gnutls-3.4.4.1:= )
+	redfish? (
+		dev-libs/json-glib
+		sys-libs/efivar
+	)
+	systemd? ( >=sys-apps/systemd-211 )
+	!systemd? ( >=sys-auth/consolekit-1.0.0 )
+	uefi? (
+		media-libs/fontconfig
+		media-libs/freetype
+		>=sys-libs/efivar-33
+		x11-libs/cairo
+	)
+"
+DEPEND="
+	${RDEPEND}
+	app-arch/gcab
+	app-arch/libarchive
+	>=dev-util/meson-0.41.0
+	>=dev-util/ninja-1.7.2
+	virtual/pkgconfig
+	$(vala_depend)
+	doc? ( dev-util/gtk-doc )
+	man? ( app-text/docbook-sgml-utils )
+	test? ( net-libs/gnutls[tools] )
+"
+
+src_prepare() {
+	default
+	sed -e "s/'--create'/'--absolute-name', '--create'/" \
+		-i data/tests/builder/meson.build || die
+	vala_src_prepare
+}
+
+src_configure() {
+	xdg_environment_reset
+	local emesonargs=(
+		-Dconsolekit="$(usex systemd false true)"
+		-Dgpg="$(usex gpg true false)"
+		-Dgtkdoc="$(usex doc true false)"
+		-Dman="$(usex man true false)"
+		-Dpkcs7="$(usex pkcs7 true false)"
+		-Dplugin_dell="$(usex dell true false)"
+		-Dplugin_redfish="$(usex redfish true false)"
+		-Dplugin_synaptics="$(usex dell true false)"
+		# requires libtbtfwu which is not packaged (yet?)
+		-Dplugin_thunderbolt=false
+		-Dplugin_uefi="$(usex uefi true false)"
+		-Dsystemd="$(usex systemd true false)"
+		-Dtests="$(usex test true false)"
+	)
+	meson_src_configure
+}
diff --git a/sys-apps/fwupd/metadata.xml b/sys-apps/fwupd/metadata.xml
index db5cd052b861..b15f190a058b 100644
--- a/sys-apps/fwupd/metadata.xml
+++ b/sys-apps/fwupd/metadata.xml
@@ -12,6 +12,7 @@
     <flag name="gpg">Enable GPG support.</flag>
     <flag name="man">Build and install man pages</flag>
     <flag name="pkcs7">Enable PKCS7 verification support via <pkg>net-libs/gnutls</pkg>.</flag>
+    <flag name="redfish">Install redfish plugin</flag>
     <flag name="uefi">Enable UEFI support</flag>
     <flag name="uefi_labels">Enable UEFI labels support</flag>
   </use>