sys-apps/pkgcore: Sync metadata.xsd from xml-schema

Acked-by: Arthur Zamarin <arthurzam@gentoo.org>
Signed-off-by: Ulrich Müller <ulm@gentoo.org>

2 files changed, 65 insertions, 0 deletions

diff --git a/sys-apps/pkgcore/files/pkgcore-0.12.23-metadata-xsd.patch b/sys-apps/pkgcore/files/pkgcore-0.12.23-metadata-xsd.patch
new file mode 100644
index 000000000000..abffe300b669
--- /dev/null
+++ b/sys-apps/pkgcore/files/pkgcore-0.12.23-metadata-xsd.patch
@@ -0,0 +1,16 @@
+commit f244de224400d9634742c52c655ac705cce9658a
+Author: Thomas Bracht Laumann Jespersen <t@laumann.xyz>
+Date:   Thu Sep 14 12:32:44 2023 +0000
+
+    data/xml-schema/metadata.xsd: add codeberg remote-id
+
+--- a/data/share/pkgcore/xml-schema/metadata.xsd
++++ b/data/share/pkgcore/xml-schema/metadata.xsd
+@@ -271,6 +271,7 @@
+ 	<xs:simpleType name='upstreamRemoteIdTypeAttrType'>
+ 		<xs:restriction base='xs:token'>
+ 			<xs:enumeration value='bitbucket'/>
++			<xs:enumeration value='codeberg'/>
+ 			<xs:enumeration value='cpan'/>
+ 			<xs:enumeration value='cpan-module'/>
+ 			<xs:enumeration value='cpe'/>
diff --git a/sys-apps/pkgcore/pkgcore-0.12.23-r1.ebuild b/sys-apps/pkgcore/pkgcore-0.12.23-r1.ebuild
new file mode 100644
index 000000000000..dd0437c0c1fd
--- /dev/null
+++ b/sys-apps/pkgcore/pkgcore-0.12.23-r1.ebuild
@@ -0,0 +1,49 @@
+# Copyright 1999-2023 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+DISTUTILS_USE_PEP517=standalone
+PYTHON_COMPAT=( python3_{10..12} )
+inherit distutils-r1
+
+if [[ ${PV} == *9999 ]] ; then
+	EGIT_REPO_URI="https://anongit.gentoo.org/git/proj/pkgcore/pkgcore.git
+		https://github.com/pkgcore/pkgcore.git"
+	inherit git-r3
+else
+	KEYWORDS="~alpha ~amd64 ~arm ~arm64 ~hppa ~ia64 ~loong ~m68k ~mips ~ppc ~ppc64 ~riscv ~s390 ~sparc ~x86 ~x64-macos"
+	inherit pypi
+fi
+
+DESCRIPTION="a framework for package management"
+HOMEPAGE="https://github.com/pkgcore/pkgcore"
+
+LICENSE="BSD MIT"
+SLOT="0"
+
+RDEPEND="
+	>=app-shells/bash-5.0[readline]
+	dev-python/lxml[${PYTHON_USEDEP}]
+"
+if [[ ${PV} == *9999 ]]; then
+	RDEPEND+=" ~dev-python/snakeoil-9999[${PYTHON_USEDEP}]"
+else
+	RDEPEND+=" >=dev-python/snakeoil-0.10.4[${PYTHON_USEDEP}]"
+fi
+BDEPEND="
+	>=dev-python/flit-core-3.8[${PYTHON_USEDEP}]
+	test? (
+		dev-vcs/git
+	)
+"
+
+PATCHES=( "${FILESDIR}/${P}-metadata-xsd.patch" )
+
+distutils_enable_tests pytest
+
+python_install_all() {
+	local DOCS=( NEWS.rst )
+	[[ ${PV} == *9999 ]] || doman build/sphinx/man/*
+	distutils-r1_python_install_all
+}