sci-libs/scikits_learn-0.22.2_p1: Version bump

Copyright: Sony Interactive Entertainment Inc.
Package-Manager: Portage-2.3.96, Repoman-2.3.22
Signed-off-by: Patrick McLean <chutzpah@gentoo.org>

2 files changed, 81 insertions, 0 deletions

diff --git a/sci-libs/scikits_learn/Manifest b/sci-libs/scikits_learn/Manifest
index bb13bbcc95f8..87d114ec5e6e 100644
--- a/sci-libs/scikits_learn/Manifest
+++ b/sci-libs/scikits_learn/Manifest
@@ -1,3 +1,4 @@
 DIST scikit-learn-0.19.0.tar.gz 9341628 BLAKE2B c9e0c12558e81efb6f5cfddead028980b0019d2f6d0fdce5662c9138ec3a5b2a3d30b022a5713578bc7effd09894006e8f7f60a3e038ca66297502d9d4212686 SHA512 1b88bc043b08de9b5bb1f3814b8101c73ced010cf94bd725fb69e1ef95b4a9597a34de4a19f84fbbf63e54d47e95b3ff498d611234fcdfcaa5e4e3cf696289d2
 DIST scikit-learn-0.20.2.tar.gz 10275187 BLAKE2B 6865fd101f99930e014f4a2a89616e1ee917df27a5a1b0a931d47503d7df509fe6490799e876a5d68b1cb76a35c6f85e4acbb31a28adfc528720fe9a69e108a7 SHA512 5e0bdea3c40e38880683c6a49cdf2f4c0d40c1f5436c1d8209d613440d5d9d13b9a608e73943a890ef3effaddd930b5c171c45d29700afb8629285ba4aad414f
 DIST scikit-learn-0.20.4.tar.gz 11684276 BLAKE2B 791fd5c7e3ebfdb9bf01524be46b19341b5750fdc5352de9e50cc395a34cf91551825352f18f235b658b55b38829981884fca9f0535a1c505adeb18ac5d87ceb SHA512 a94c254440641a987df1eaec63302639b8e6f56705ec426c350070658141dd574b502eb1e4b94ae9c766c1becfd911f08bb97d5c87d39b0546d8444ed281b06a
+DIST scikits_learn-0.22.2_p1.tar.gz 7034850 BLAKE2B 41c362ef6594e837a9fc798837e666fbb51e33954fdf700292650204fd9d1ab4fc4d1695890d02a24ad68f4dcc2d3cde8f0827eca70c6fb9a6f0e5c0d9c04fd5 SHA512 20bcda5c65f76bce9b71c5b5fb1b499f7f3a7a3f6fa5fade80a38dc658cb434e16e9d5a4906a9657157a5cc90a6d51080575d6e510207baa9f8b06c4fa761d5b
diff --git a/sci-libs/scikits_learn/scikits_learn-0.22.2_p1.ebuild b/sci-libs/scikits_learn/scikits_learn-0.22.2_p1.ebuild
new file mode 100644
index 000000000000..1bf6679a1b9b
--- /dev/null
+++ b/sci-libs/scikits_learn/scikits_learn-0.22.2_p1.ebuild
@@ -0,0 +1,80 @@
+# Copyright 2020 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=7
+
+PYTHON_COMPAT=( python3_{6,7,8} )
+inherit distutils-r1
+
+MY_PV="${PV//_p/.post}"
+MY_PN="${PN//s_/-}"
+
+DESCRIPTION="Machine learning library for Python"
+HOMEPAGE="https://scikit-learn.org/stable/
+	https://github.com/scikit-learn/scikit-learn"
+SRC_URI="https://github.com/${MY_PN}/${MY_PN}/archive/${MY_PV}.tar.gz -> ${P}.tar.gz"
+#ffhttps://github.com/scikit-learn/scikit-learn/archive/0.22.2.post1.tar.gz
+S="${WORKDIR}/${MY_PN}-${MY_PV}"
+
+LICENSE="BSD"
+SLOT="0"
+KEYWORDS="~amd64 ~x86"
+IUSE="test"
+RESTRICT="!test? ( test )"
+
+RDEPEND="
+	dev-python/wheel[${PYTHON_USEDEP}]
+	dev-python/cython[${PYTHON_USEDEP}]
+	dev-python/numpy[${PYTHON_USEDEP}]
+	sci-libs/scipy[${PYTHON_USEDEP}]
+	sci-libs/scikits[${PYTHON_USEDEP}]
+	virtual/blas:=
+	virtual/cblas:=
+"
+DEPEND="
+	virtual/blas:=
+	virtual/cblas:=
+"
+BDEPEND="
+	test? (
+		${RDEPEND}
+		dev-python/joblib[${PYTHON_USEDEP}]
+	)
+"
+
+distutils_enable_tests pytest
+
+python_prepare_all() {
+	# scikits-learn now uses the horrible numpy.distutils automagic
+	export SCIPY_FCONFIG="config_fc --noopt --noarch"
+
+	# remove bundled cblas
+	rm -rf sklearn/src || die "failed to remove bundled cblas"
+
+	distutils-r1_python_prepare_all
+}
+
+python_compile() {
+	distutils-r1_python_compile ${SCIPY_FCONFIG}
+}
+
+python_test() {
+	distutils_install_for_testing ${SCIPY_FCONFIG}
+	pushd "${TEST_DIR}/lib" >/dev/null || die
+	pytest -vv || die "testing failed with ${EPYTHON}"
+	popd >/dev/null || die
+}
+
+python_install() {
+	distutils-r1_python_install ${SCIPY_FCONFIG}
+}
+
+python_install_all() {
+	find "${S}" -name \*LICENSE.txt -delete
+	distutils-r1_python_install_all
+	if use examples; then
+		dodoc -r examples
+		docompress -x /usr/share/doc/${PF}/examples
+	fi
+
+}