sci-libs/dealii: drop 9.4.0-r1

Signed-off-by: Matthias Maier <tamiko@gentoo.org>

2 files changed, 0 insertions, 183 deletions

diff --git a/sci-libs/dealii/Manifest b/sci-libs/dealii/Manifest
index d5a5844c5276..3ac62d91cec5 100644
--- a/sci-libs/dealii/Manifest
+++ b/sci-libs/dealii/Manifest
@@ -1,7 +1,3 @@
-DIST dealii-9.4.0-offline_documentation.tar.gz 390747598 BLAKE2B 6e8ed938b31a9e6bbbdd5baacce056edc31d489ecd3e9528283650f431d004ca122c968567fe342744d52bab8f8be53ab1b20d56636e2dc48f8cf551791a08bd SHA512 703eb50150ae5bd77f0d84271babd50483c3a9b069abb5b7e8827d00efaa5d189a43ac54f0ef8b2f746b12a10dc611669f5fddd655241a66af4915ec1d458185
-DIST dealii-9.4.0-offline_documentation.tar.gz.asc 246 BLAKE2B cb828efcdb38b88af9abc3be95c90c126144ee1edd076e2c47c7a90dad1df3ac29ce104de7be551fb93671b0b3ffe44b737fcba3841ccb0921e1f0795360fec4 SHA512 59f8997f9a19580861f0c7afd06b9737519c0dbf6990c4569f5c8dbd05e7e41dce19d1b9a639504696be2f99f6e8c555086dcd85c43976ccd5c7ebf007864dc0
-DIST dealii-9.4.0.tar.gz 30297914 BLAKE2B 6beb4c7b83f5316e703d4b77340900c376e622b1dc59c9058a8927174a8c6991994957588b6adf88238e72eec93f8941bfbfb2d0bb01070560468d051d9829f8 SHA512 3be740fbabff65a18870496f483ac4ed6d35c8a53b5128dd09b2dfabe82d60e4a75f02fd508b44f6c93805999aab98f551154f10ca2ad5fabede65c2d6dce320
-DIST dealii-9.4.0.tar.gz.asc 246 BLAKE2B 972d3fa18c83ff9b3aff996efaa0e6d1db848f64a46afb80b083c4f228d42ab1a2d7c5f6172a1ad3ae8542ca9c2a351c2badf98b9104dd5448a0f3d0cbd73e2a SHA512 b0754c891356bcf30d2d32b4ecc780d2ba814b720426d604c0596ebdbdb1a8ae00357b04596c03f75e809593067b022b9e7c08584f88e35f05248472dde44f3b
 DIST dealii-9.4.1-offline_documentation.tar.gz 392007419 BLAKE2B 81404b02ba7dc97a0314f52fa9d775183981864288f4ab4ca81b550a1763d90cb5b04b32c056008ad60a7829b929c78edd80cbeeeb861e4ef638780c13d80aa7 SHA512 9bbaf6e9a478ac643e87f2f07918c8a5216e17b0ddaeba4beb2acde9ea54833e2f0e7d11f61b2cac8b986e442dbb181317b53e1a40a807e7c098167bfd073266
 DIST dealii-9.4.1-offline_documentation.tar.gz.asc 246 BLAKE2B 9ace22c9b174e642cd3fba94c165d816c62814f892f5f6f272efa0301613dc55251152825e726fc6cf7e89bbfb7fa3552ec58ad426a7d58a74ecb89b9072f742 SHA512 50b43dd34a0687395f516f4910581df71054fa8be3c98006566ea649d0af866d38c9793da548ba6bdb7a9fec452dfb6d928d336aace943522d7c3f854209b81b
 DIST dealii-9.4.1.tar.gz 30298204 BLAKE2B 499f542c7a7f071d04048127199c7bebf5668b6e8d13fc2701dd18e28165442e58112ee9e4926e16a592bffdd5d7b7c240eea55808e5f9c021961f7e44b7da79 SHA512 39089aff462d3ff4244ce75f74a4cd908f8f72a81dcc3fb02ca91b3cad2442ceb78677e72cd928b36a04d352c4baa146a25fa5e14c886ca9e2bad0be0069f7b8
diff --git a/sci-libs/dealii/dealii-9.4.0-r1.ebuild b/sci-libs/dealii/dealii-9.4.0-r1.ebuild
deleted file mode 100644
index e85fd0205e74..000000000000
--- a/sci-libs/dealii/dealii-9.4.0-r1.ebuild
+++ /dev/null
@@ -1,179 +0,0 @@
-# Copyright 1999-2024 Gentoo Authors
-# Distributed under the terms of the GNU General Public License v2
-
-EAPI=8
-
-# deal.II uses its own FindLAPACK.cmake file that calls into the system
-# FindLAPACK.cmake module and does additional internal setup. Do not remove
-# any of these modules:
-CMAKE_REMOVE_MODULES_LIST=""
-
-inherit cmake flag-o-matic verify-sig
-
-DESCRIPTION="Solving partial differential equations with the finite element method"
-HOMEPAGE="https://www.dealii.org/"
-
-if [[ ${PV} = *9999* ]]; then
-	inherit git-r3
-	EGIT_REPO_URI="https://github.com/dealii/dealii.git"
-	SRC_URI=""
-else
-	SRC_URI="https://github.com/${PN}/${PN}/releases/download/v${PV}/${P}.tar.gz
-		verify-sig? ( https://github.com/${PN}/${PN}/releases/download/v${PV}/${P}.tar.gz.asc )
-		doc? (
-			https://github.com/${PN}/${PN}/releases/download/v${PV}/${P}-offline_documentation.tar.gz
-			verify-sig? ( https://github.com/${PN}/${PN}/releases/download/v${PV}/${P}-offline_documentation.tar.gz.asc )
-			)"
-	KEYWORDS="~amd64 ~x86 ~amd64-linux ~x86-linux"
-fi
-
-LICENSE="LGPL-2.1+"
-SLOT="0"
-IUSE="
-	adolc arborx assimp arpack cgal cpu_flags_x86_avx cpu_flags_x86_avx512f
-	cpu_flags_x86_sse2 cuda +debug doc +examples ginkgo gmsh +gsl hdf5
-	+lapack metis mpi muparser opencascade p4est petsc scalapack slepc
-	+sparse static-libs sundials symengine trilinos
-"
-
-# TODO: add slepc use flag once slepc is packaged for gentoo-science
-REQUIRED_USE="
-	arborx? ( trilinos )
-	p4est? ( mpi )
-	slepc? ( petsc )
-	trilinos? ( mpi )"
-
-RDEPEND="dev-libs/boost:=
-	app-arch/bzip2
-	sys-libs/zlib
-	dev-cpp/tbb:=
-	arborx? ( sci-libs/arborx[mpi=] )
-	adolc? ( sci-libs/adolc )
-	arpack? ( sci-libs/arpack[mpi=] )
-	assimp? ( media-libs/assimp:= )
-	cuda? ( dev-util/nvidia-cuda-toolkit )
-	ginkgo? ( sci-libs/ginkgo )
-	gmsh? ( sci-libs/gmsh )
-	gsl? ( sci-libs/gsl:= )
-	hdf5? ( sci-libs/hdf5[mpi=] )
-	lapack? ( virtual/lapack )
-	metis? (
-		>=sci-libs/metis-5
-		mpi? ( >=sci-libs/parmetis-4 )
-	)
-	mpi? ( virtual/mpi[cxx] )
-	muparser? ( dev-cpp/muParser )
-	opencascade? ( sci-libs/opencascade:= )
-	p4est? ( sci-libs/p4est[mpi] )
-	petsc? ( sci-mathematics/petsc[mpi=] )
-	scalapack? ( sci-libs/scalapack )
-	slepc? ( sci-mathematics/slepc[mpi=] )
-	sparse? ( sci-libs/umfpack )
-	sundials? ( sci-libs/sundials:= )
-	symengine? ( >=sci-libs/symengine-0.4:= )
-	trilinos? ( sci-libs/trilinos )"
-
-DEPEND="${RDEPEND}
-	virtual/pkgconfig
-	doc? ( app-text/doxygen[dot] dev-lang/perl )"
-
-BDEPEND="
-	verify-sig? ( sec-keys/openpgp-keys-dealii )"
-
-PATCHES=(
-	"${FILESDIR}"/${PN}-9.1.1-no-ld-flags.patch
-)
-
-VERIFY_SIG_OPENPGP_KEY_PATH="/usr/share/openpgp-keys/dealii.asc"
-
-src_configure() {
-	# deal.II needs a custom build type:
-	local CMAKE_BUILD_TYPE=$(usex debug DebugRelease Release)
-
-	local mycmakeargs=(
-		-DDEAL_II_PACKAGE_VERSION="${PV}"
-		-DCMAKE_INSTALL_RPATH_USE_LINK_PATH=OFF
-		-DDEAL_II_ALLOW_AUTODETECTION=OFF
-		-DDEAL_II_ALLOW_BUNDLED=OFF
-		-DDEAL_II_ALLOW_PLATFORM_INTROSPECTION=OFF
-		-DDEAL_II_COMPILE_EXAMPLES=OFF
-		-DDEAL_II_DOCHTML_RELDIR="share/doc/${P}/html"
-		-DDEAL_II_DOCREADME_RELDIR="share/doc/${P}"
-		-DDEAL_II_COMPILE_EXAMPLES=OFF
-		-DDEAL_II_EXAMPLES_RELDIR="share/doc/${P}/examples"
-		-DDEAL_II_LIBRARY_RELDIR="$(get_libdir)"
-		-DDEAL_II_SHARE_RELDIR="share/${PN}"
-		-DDEAL_II_WITH_ZLIB=ON
-		-DDEAL_II_WITH_ADOLC="$(usex adolc)"
-		-DDEAL_II_WITH_ARBORX="$(usex arborx)"
-		-DDEAL_II_WITH_ASSIMP="$(usex assimp)"
-		-DDEAL_II_WITH_ARPACK="$(usex arpack)"
-		-DDEAL_II_WITH_CGAL="$(usex cgal)"
-		-DDEAL_II_WITH_CUDA="$(usex cuda)"
-		-DDEAL_II_WITH_GINKGO="$(usex ginkgo)"
-		-DDEAL_II_COMPONENT_DOCUMENTATION="$(usex doc)"
-		-DDEAL_II_COMPONENT_EXAMPLES="$(usex examples)"
-		-DDEAL_II_WITH_GMSH="$(usex gmsh)"
-		-DDEAL_II_WITH_GSL="$(usex gsl)"
-		-DDEAL_II_WITH_HDF5="$(usex hdf5)"
-		-DDEAL_II_WITH_KOKKOS="$(usex trilinos)"
-		-DDEAL_II_WITH_LAPACK="$(usex lapack)"
-		-DDEAL_II_WITH_METIS="$(usex metis)"
-		-DDEAL_II_WITH_MPI="$(usex mpi)"
-		-DDEAL_II_WITH_MUPARSER="$(usex muparser)"
-		-DDEAL_II_WITH_OPENCASCADE="$(usex opencascade)"
-		-DDEAL_II_WITH_P4EST="$(usex p4est)"
-		-DDEAL_II_WITH_PETSC="$(usex petsc)"
-		-DDEAL_II_WITH_SCALAPACK="$(usex scalapack)"
-		-DDEAL_II_WITH_SLEPC="$(usex slepc)"
-		-DDEAL_II_WITH_SUNDIALS="$(usex sundials)"
-		-DDEAL_II_WITH_SYMENGINE="$(usex symengine)"
-		-DDEAL_II_WITH_UMFPACK="$(usex sparse)"
-		-DBUILD_SHARED_LIBS="$(usex !static-libs)"
-		-DDEAL_II_PREFER_STATIC_LIBS="$(usex static-libs)"
-		-DDEAL_II_WITH_TBB=ON
-		-DDEAL_II_WITH_TASKFLOW=OFF
-		-DDEAL_II_WITH_TRILINOS="$(usex trilinos)"
-	)
-
-	use opencascade && mycmakeargs+=(
-		-DCMAKE_PREFIX_PATH="/usr/$(get_libdir)/opencascade"
-	)
-
-	# Do a little dance for purely cosmetic QA reasons. The build system
-	# does query for the highest instruction set first and skips the other
-	# variables if a "higher" variant is set
-	if use cpu_flags_x86_avx512f; then
-		mycmakeargs+=( -DDEAL_II_HAVE_AVX512=yes )
-		append-cxxflags "-mavx512f"
-	elif use cpu_flags_x86_avx; then
-		mycmakeargs+=( -DDEAL_II_HAVE_AVX=yes )
-		append-cxxflags "-mavx2"
-	elif use cpu_flags_x86_avx; then
-		mycmakeargs+=( -DDEAL_II_HAVE_SSE2=yes )
-		append-cxxflags "-msse2"
-	fi
-
-	# Unconditionally enable strict C++17 standard. This is necessary for
-	# USE=cgal and USE=kokkos and safe to set for all presently supported
-	# compilers
-	append-cxxflags "-std=c++17"
-
-	cmake_src_configure
-}
-
-src_install() {
-	if use doc && [[ ${PV} != *9999* ]]; then
-		# copy missing images to the build directory:
-		cp -r "${WORKDIR}"/doc/doxygen/deal.II/images \
-			"${BUILD_DIR}"/doc/doxygen/deal.II || die
-		# replace links:
-		sed -i \
-			's#"http://www.dealii.org/images/steps/developer/\(step-.*\)"#"images/\1"#g' \
-			"${BUILD_DIR}"/doc/doxygen/deal.II/step_*.html || die "sed failed"
-	fi
-	cmake_src_install
-
-	# decompress the installed example sources:
-	use examples && docompress -x /usr/share/doc/${PF}/examples
-}