sci-libs/coinor-smi: bump to 0.96.1, ported to EAPI 7

Has reworked old workarounds and reviewed deps.

USE=examples removed, now installed unconditionally (small files).
USE=static-libs removed.

Package-Manager: Portage-3.0.15, Repoman-3.0.2
Signed-off-by: Ionen Wolkens <sudinave@gmail.com>
Signed-off-by: Sam James <sam@gentoo.org>

1 files changed, 53 insertions, 0 deletions

diff --git a/sci-libs/coinor-smi/coinor-smi-0.96.1.ebuild b/sci-libs/coinor-smi/coinor-smi-0.96.1.ebuild
new file mode 100644
index 000000000000..e91f6006f743
--- /dev/null
+++ b/sci-libs/coinor-smi/coinor-smi-0.96.1.ebuild
@@ -0,0 +1,53 @@
+# Copyright 1999-2021 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=7
+
+DESCRIPTION="COIN-OR Stochastic modelling interface"
+HOMEPAGE="https://projects.coin-or.org/Smi/"
+SRC_URI="https://github.com/coin-or/Smi/archive/releases/${PV}.tar.gz -> ${P}.tar.gz"
+S="${WORKDIR}/Smi-releases-${PV}/Smi"
+
+LICENSE="CPL-1.0"
+SLOT="0/2"
+KEYWORDS="~amd64 ~x86 ~amd64-linux ~x86-linux"
+IUSE="doc"
+
+RDEPEND="
+	sci-libs/coinor-clp:=
+	sci-libs/coinor-flopcpp:=
+	sci-libs/coinor-osi:=
+	sci-libs/coinor-utils:="
+DEPEND="${RDEPEND}"
+BDEPEND="
+	virtual/pkgconfig
+	doc? ( app-doc/doxygen[dot] )"
+
+src_prepare() {
+	default
+	# Prevent unneeded call to pkg-config that needs ${ED}'s in path.
+	sed -i '/--libs.*addlibs.txt/d' Makefile.in || die
+}
+
+src_configure() {
+	econf $(use_with doc dot)
+}
+
+src_compile() {
+	emake all $(usex doc doxydoc '')
+}
+
+src_test() {
+	# Needed given "make check" is a noop and it skips the working one.
+	emake test
+}
+
+src_install() {
+	default
+	dodoc -r examples flopcpp_examples
+	use doc && dodoc -r doxydoc/html
+
+	# Duplicate or irrelevant files.
+	rm -r "${ED}"/usr/share/coin/doc || die
+	find "${ED}" -name '*.la' -delete || die
+}