sci-libs/ViSP: bump to 3.0.0

Package-Manager: portage-2.2.26
Signed-off-by: Alexis Ballier <aballier@gentoo.org>

3 files changed, 117 insertions, 0 deletions

diff --git a/sci-libs/ViSP/Manifest b/sci-libs/ViSP/Manifest
index ee4b922b24ac..0d946b21997f 100644
--- a/sci-libs/ViSP/Manifest
+++ b/sci-libs/ViSP/Manifest
@@ -1 +1,2 @@
 DIST ViSP-2.10.0.tar.gz 20745399 SHA256 1c8a37cadd0012526be9ceaa182eb21fb0d45aac622a1f0f2d255225e85797aa SHA512 485bad6aea1dddf51c1edd162e22f5f00205947b67b57843207902ea3b97b683828031338282861be495d66cc79bde3a7af09c075aa9c6b783652d5d3bd4f9ef WHIRLPOOL d3d7e29076231fd581346f7de37ef49afed22f48198673d08268b1a298121d8a9bd8a9bc6e34cf2a5655cf45575599b09c5cb56e78961340122ca6f95ee275e3
+DIST visp-3.0.0.tar.gz 22938301 SHA256 cac5c79b00ca9bc2eeaeacffdc6e3c6f88ee101ec16f729ad3058d37092bf05f SHA512 4ba522731ffbbb55082dc9e0cfecb6bd42ad0abff88d95bd7d33f233a9159139ddef032e087a03b261c8ee2d6bc0cf4807819a27fae11ea91ec0482038acecdc WHIRLPOOL ded182caea33af0393e2e545808f03626aaf9a5929a11781953518722a5b8fbeca9d24dafd55d789ab9a71c6005eb0491c80d76285434c61f7d67f9fac9751ed
diff --git a/sci-libs/ViSP/ViSP-3.0.0.ebuild b/sci-libs/ViSP/ViSP-3.0.0.ebuild
new file mode 100644
index 000000000000..0f25727c2d93
--- /dev/null
+++ b/sci-libs/ViSP/ViSP-3.0.0.ebuild
@@ -0,0 +1,103 @@
+# Copyright 1999-2015 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+# $Id$
+
+EAPI=5
+
+inherit cmake-utils
+
+DESCRIPTION="Visual Servoing Platform: visual tracking and visual servoing library"
+HOMEPAGE="http://www.irisa.fr/lagadic/visp/visp.html"
+SRC_URI="http://gforge.inria.fr/frs/download.php/latestfile/475/visp-${PV}.tar.gz"
+
+LICENSE="GPL-2"
+SLOT="0/3"
+KEYWORDS="~amd64 ~arm"
+IUSE="
+	+coin demos +dmtx doc examples ffmpeg gsl ieee1394 jpeg lapack motif ogre
+	ois opencv png qt4 test tutorials usb v4l X xml +zbar zlib
+"
+
+RDEPEND="
+	coin? ( media-libs/coin virtual/opengl )
+	dmtx? ( media-libs/libdmtx )
+	ffmpeg? ( virtual/ffmpeg )
+	gsl? ( sci-libs/gsl )
+	ieee1394? ( media-libs/libdc1394 )
+	jpeg? ( virtual/jpeg:0 )
+	lapack? ( virtual/lapack )
+	!qt4? ( motif? ( media-libs/SoXt ) )
+	ogre? ( dev-games/ogre[ois?] dev-libs/boost:=[threads] )
+	opencv? ( media-libs/opencv qt4? ( media-libs/opencv[-qt5(-)] ) )
+	png? ( media-libs/libpng:0= )
+	qt4? ( media-libs/SoQt dev-qt/qtgui:4 )
+	usb? ( virtual/libusb:1 )
+	v4l? ( media-libs/libv4l )
+	X? ( x11-libs/libX11 )
+	xml? ( dev-libs/libxml2 )
+	zbar? ( media-gfx/zbar )
+	zlib? ( sys-libs/zlib )
+"
+DEPEND="${RDEPEND}
+	doc? ( app-doc/doxygen virtual/latex-base media-gfx/graphviz )
+	virtual/pkgconfig
+	test? ( sci-misc/ViSP-images )
+	v4l? ( virtual/os-headers )"
+RDEPEND="${RDEPEND}
+	demos? ( sci-misc/ViSP-images )"
+REQUIRED_USE="
+	ffmpeg? ( opencv )
+	ois? ( ogre )
+	qt4? ( coin )
+	motif? ( coin )
+"
+
+S="${WORKDIR}/visp-${PV}"
+PATCHES=( "${FILESDIR}/${P}-opencv.patch" )
+
+src_configure() {
+	local mycmakeargs=(
+		"-DBUILD_EXAMPLES=$(usex examples ON OFF)"
+		"-DBUILD_TESTS=$(usex test ON OFF)"
+		"-DBUILD_DEMOS=$(usex demos ON OFF)"
+		"-DBUILD_TUTORIALS=$(usex tutorials ON OFF)"
+		"-DUSE_COIN3D=$(usex coin ON OFF)"
+		"-DUSE_DC1394=$(usex ieee1394 ON OFF)"
+		"-DUSE_DMTX=$(usex dmtx ON OFF)"
+		"-DUSE_FFMPEG=$(usex ffmpeg ON OFF)"
+		"-DUSE_GSL=$(usex gsl ON OFF)"
+		"-DUSE_LAPACK=$(usex lapack ON OFF)"
+		"-DUSE_JPEG=$(usex jpeg ON OFF)"
+		"-DUSE_PNG=$(usex png ON OFF)"
+		"-DUSE_LIBUSB_1=$(usex usb ON OFF)"
+		"-DUSE_OGRE=$(usex ogre ON OFF)"
+		"-DUSE_OIS=$(usex ois ON OFF)"
+		"-DUSE_OPENCV=$(usex opencv ON OFF)"
+		"-DUSE_SOQT=$(usex qt4 ON OFF)"
+		"-DUSE_SOXT=$(usex motif "$(usex qt4 OFF ON)" OFF)"
+		"-DUSE_V4L2=$(usex v4l ON OFF)"
+		"-DUSE_X11=$(usex X ON OFF)"
+		"-DUSE_XML2=$(usex xml ON OFF)"
+		"-DUSE_ZBAR=$(usex zbar ON OFF)"
+		"-DUSE_ZLIB=$(usex zlib ON OFF)"
+		"-DCOIN3D_INCLUDE_DIR=${EPREFIX:-${SYSROOT}}/usr/include/coin"
+		"-DSOQT_INCLUDE_DIR=${EPREFIX:-${SYSROOT}}/usr/include/coin"
+	)
+	cmake-utils_src_configure
+}
+
+src_compile() {
+	cmake-utils_src_compile
+	cd "${BUILD_DIR}"
+	use doc && emake visp_doc
+}
+
+src_install() {
+	cmake-utils_src_install
+	if use tutorials ; then
+		dodoc -r tutorial
+		docompress -x /usr/share/doc/${PF}/tutorial
+	fi
+	cd "${BUILD_DIR}"
+	use doc && dohtml -r doc/html/*
+}
diff --git a/sci-libs/ViSP/files/ViSP-3.0.0-opencv.patch b/sci-libs/ViSP/files/ViSP-3.0.0-opencv.patch
new file mode 100644
index 000000000000..7bd7705e552e
--- /dev/null
+++ b/sci-libs/ViSP/files/ViSP-3.0.0-opencv.patch
@@ -0,0 +1,13 @@
+Index: visp-3.0.0/modules/core/CMakeLists.txt
+===================================================================
+--- visp-3.0.0.orig/modules/core/CMakeLists.txt
++++ visp-3.0.0/modules/core/CMakeLists.txt
+@@ -172,7 +172,7 @@ if(USE_OPENCV)
+     list(APPEND opt_libs ${OpenCV_LIBS})
+   endif()
+   list(APPEND opt_incs ${OpenCV_INCLUDE_DIRS})
+-  #list(APPEND opt_libs ${OpenCV_LIBS})
++  list(APPEND opt_libs ${OpenCV_LIBS})
+   #MESSAGE("OpenCV_INCLUDE_DIRS = ${OpenCV_INCLUDE_DIRS}")
+   #MESSAGE("OpenCV_LIBS = ${OpenCV_LIBS}")
+   #MESSAGE("OpenCV_LIB_DIR = ${OpenCV_LIB_DIR}")