net-wireless/gnome-bluetooth: Bump to 46.2

Signed-off-by: Guillermo Joandet <gjoandet@gmail.com>
Closes: https://github.com/gentoo/gentoo/pull/38094
Signed-off-by: Pacho Ramos <pacho@gentoo.org>

2 files changed, 80 insertions, 0 deletions

diff --git a/net-wireless/gnome-bluetooth/Manifest b/net-wireless/gnome-bluetooth/Manifest
index 9ea6a8fc92ea..5a81518818ce 100644
--- a/net-wireless/gnome-bluetooth/Manifest
+++ b/net-wireless/gnome-bluetooth/Manifest
@@ -1,2 +1,3 @@
 DIST gnome-bluetooth-42.8.tar.xz 304908 BLAKE2B c487e0c278b316ecdcbdd39421389ce95024b06bf0e350d59dcac06d7a7e8b982da12b1088701e479d0b5c64b123899a5351a00c477208946bb1f44f3c8f30a6 SHA512 1c3d1db874b54ebae3cf59e526db8ff71131daea0c994abeefd95b51abf590bbba0baa8314ebbd1d3efe7973021327c7b8257163ed8f0567fe610b4e0c3dba88
 DIST gnome-bluetooth-46.0.tar.xz 306148 BLAKE2B cc2ecb80b69bab74f878eb640f8b65505b0a5e12d4c661bd2491cbb70c4020db7f191e604805df788e3bd45c46de38c8069434a8615874006368e027dd5608b6 SHA512 48ed8aeaa59aba1997991a6ae6113a4d3c9e286aa4e34f3f2611e33582ffa53f9f3f5a81052320292ccb576904d0f3cf8074c0fff6d0f56995266188441e6f7b
+DIST gnome-bluetooth-46.2.tar.xz 306076 BLAKE2B 5696ec06cde737d833f02edd89f265172a3b8c4e3486cbb09b3e2e046ead445e6a3aac23a92223dada9f8a6cadd7969755bed661b3a95161fb3874f545172f38 SHA512 e0745ae67e5c30000ace8161c114caecc1f3b8e99b824b961ed695ba78a088247d797ad3cb284fc7cf91dd7c37b94c5ce0bdc4c1118b9bf059039effeb79313a
diff --git a/net-wireless/gnome-bluetooth/gnome-bluetooth-46.2.ebuild b/net-wireless/gnome-bluetooth/gnome-bluetooth-46.2.ebuild
new file mode 100644
index 000000000000..4194444062ef
--- /dev/null
+++ b/net-wireless/gnome-bluetooth/gnome-bluetooth-46.2.ebuild
@@ -0,0 +1,79 @@
+# Copyright 1999-2024 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+PYTHON_COMPAT=( python3_{10..13} )
+inherit gnome.org gnome2-utils meson python-any-r1 xdg
+
+DESCRIPTION="Bluetooth graphical utilities integrated with GNOME"
+HOMEPAGE="https://gitlab.gnome.org/GNOME/gnome-bluetooth"
+
+LICENSE="GPL-2+ LGPL-2.1+ FDL-1.1+"
+SLOT="3/13" # subslot = libgnome-bluetooth-3 soname version
+IUSE="gtk-doc +introspection sendto test"
+RESTRICT="!test? ( test )"
+KEYWORDS="~amd64 ~arm ~arm64 ~loong ~ppc ~ppc64 ~riscv ~x86"
+
+DEPEND="
+	>=dev-libs/glib-2.44:2
+	>=gui-libs/gtk-4.4:4[introspection?]
+	media-libs/gsound
+	>=gui-libs/libadwaita-1.1:1
+	>=x11-libs/libnotify-0.7.0
+	virtual/libudev:=
+	>=sys-power/upower-0.99.14:=
+	introspection? ( >=dev-libs/gobject-introspection-1.54:= )
+"
+RDEPEND="${DEPEND}
+	acct-group/plugdev
+	virtual/udev
+	>=net-wireless/bluez-5
+	sendto? ( !net-wireless/gnome-bluetooth:2 )
+"
+BDEPEND="
+	${PYTHON_DEPS}
+	dev-libs/libxml2:2
+	dev-util/gdbus-codegen
+	dev-util/glib-utils
+	gtk-doc? ( >=dev-util/gtk-doc-1.9 )
+	virtual/pkgconfig
+	test? (
+		$(python_gen_any_dep '
+			>=dev-python/python-dbusmock-0.26.0[${PYTHON_USEDEP}]
+			dev-python/dbus-python[${PYTHON_USEDEP}]
+		')
+	)
+"
+
+python_check_deps() {
+	if use test; then
+		python_has_version ">=dev-python/python-dbusmock-0.26.0[${PYTHON_USEDEP}]" &&
+		python_has_version "dev-python/dbus-python[${PYTHON_USEDEP}]"
+	fi
+}
+
+pkg_setup() {
+	# Check for python is unconditional
+	python-any-r1_pkg_setup
+}
+
+src_configure() {
+	local emesonargs=(
+		$(meson_use sendto)
+		$(meson_use gtk-doc gtk_doc)
+		$(meson_use introspection)
+	)
+	meson_src_configure
+}
+
+src_test() {
+	# Workaround test failures caused by flatpak being installed that adds to XDG_DATA_DIRS
+	gnome2_environment_reset
+	export XDG_DATA_DIRS="${EPREFIX}"/usr/share
+
+	meson_src_test
+}
+
+pkg_postinst() {
+	xdg_pkg_postinst
+}