net-proxy/mitmproxy: add 9.0.1

Signed-off-by: Matthew Smith <matthew@gentoo.org>

1 files changed, 74 insertions, 0 deletions

diff --git a/net-proxy/mitmproxy/mitmproxy-9.0.1.ebuild b/net-proxy/mitmproxy/mitmproxy-9.0.1.ebuild
new file mode 100644
index 000000000000..1a9ec3e34e78
--- /dev/null
+++ b/net-proxy/mitmproxy/mitmproxy-9.0.1.ebuild
@@ -0,0 +1,74 @@
+# Copyright 1999-2022 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+DISTUTILS_USE_PEP517=setuptools
+PYTHON_COMPAT=( python3_{9,10} )
+PYTHON_REQ_USE="sqlite"
+inherit distutils-r1
+
+DESCRIPTION="An interactive, SSL-capable, man-in-the-middle HTTP proxy"
+HOMEPAGE="https://mitmproxy.org/"
+SRC_URI="https://github.com/mitmproxy/mitmproxy/archive/${PV}.tar.gz -> ${P}.gh.tar.gz"
+
+LICENSE="MIT"
+SLOT="0"
+KEYWORDS="~amd64"
+
+RDEPEND="
+	>=app-arch/brotli-1.0.0[python,${PYTHON_USEDEP}]
+	>=dev-python/asgiref-3.2.10[${PYTHON_USEDEP}]
+	>=dev-python/blinker-1.4[${PYTHON_USEDEP}]
+	>=dev-python/certifi-2015.11.20.1[${PYTHON_USEDEP}]
+	>=dev-python/cryptography-37.0.0[${PYTHON_USEDEP}]
+	>=dev-python/flask-1.1.1[${PYTHON_USEDEP}]
+	>=dev-python/h2-4.1.0[${PYTHON_USEDEP}]
+	>=dev-python/hyperframe-6.0.0[${PYTHON_USEDEP}]
+	>=dev-python/kaitaistruct-0.10[${PYTHON_USEDEP}]
+	>=dev-python/ldap3-2.8[${PYTHON_USEDEP}]
+	>=dev-python/mitmproxy_wireguard-0.1.16[${PYTHON_USEDEP}]
+	>=dev-python/msgpack-1.0.0[${PYTHON_USEDEP}]
+	>=dev-python/passlib-1.6.5[${PYTHON_USEDEP}]
+	>=dev-python/protobuf-python-3.14.0[${PYTHON_USEDEP}]
+	>=dev-python/publicsuffix-2.20190205[${PYTHON_USEDEP}]
+	>=dev-python/pyopenssl-22.1[${PYTHON_USEDEP}]
+	>=dev-python/pyparsing-2.4.2[${PYTHON_USEDEP}]
+	>=dev-python/pyperclip-1.6.0[${PYTHON_USEDEP}]
+	>=dev-python/python-zstandard-0.11.0[${PYTHON_USEDEP}]
+	>=dev-python/ruamel-yaml-0.16[${PYTHON_USEDEP}]
+	>=dev-python/sortedcontainers-2.3.0[${PYTHON_USEDEP}]
+	>=dev-python/tornado-6.1[${PYTHON_USEDEP}]
+	>=dev-python/urwid-2.1.1[${PYTHON_USEDEP}]
+	>=dev-python/wsproto-1.0.0[${PYTHON_USEDEP}]
+"
+
+BDEPEND="
+	test? (
+		>=dev-python/click-7.0[${PYTHON_USEDEP}]
+		>=dev-python/hypothesis-5.8[${PYTHON_USEDEP}]
+		>=dev-python/parver-0.1[${PYTHON_USEDEP}]
+		>=dev-python/pytest-asyncio-0.17.0[${PYTHON_USEDEP}]
+		>=dev-python/requests-2.9.1[${PYTHON_USEDEP}]
+	)
+"
+
+distutils_enable_tests pytest
+
+python_prepare_all() {
+	# loosen dependencies
+	sed -i \
+		-e '/>/s/>.*/",/g' \
+		-e '/python_requires/d' \
+		setup.py || die
+
+	# remove failing test
+	# sed -i 's/test_get_version/_&/g' test/mitmproxy/test_version.py || die
+
+	# seems to hang. other tests ensure that mitmproxy_wireguard module
+	# loads properly.
+	sed -i 's/test_wireguard/_&/g' \
+		test/mitmproxy/proxy/test_mode_servers.py || die
+
+	distutils-r1_python_prepare_all
+}