net-misc/olsrd: add 0.9.8_p20241102

* Switch to USE=gui per QA policy
* Pass -std=gnu17, not going to worry about reporting it upstream at this
  point given how long it's been since the last release.

Bug: https://bugs.gentoo.org/822300
Bug: https://bugs.gentoo.org/895104
Closes: https://bugs.gentoo.org/927456
Signed-off-by: Sam James <sam@gentoo.org>

2 files changed, 128 insertions, 0 deletions

diff --git a/net-misc/olsrd/Manifest b/net-misc/olsrd/Manifest
index 66a3d939e4f6..f50baecf34eb 100644
--- a/net-misc/olsrd/Manifest
+++ b/net-misc/olsrd/Manifest
@@ -1 +1,2 @@
 DIST olsrd-0.9.8_p20210612.tar.gz 14446761 BLAKE2B ef841fcf81ae25acb3c47d70f15e34c614b17c28688e0f718aa45ebabea68844f825a4187bbf5468daa4763c8a2b8c87f5f5a502ce0c5fde1b940f9aa3c6ca5e SHA512 466b762ea1f9ecc4ded3298700d1786b893d87fbcc2e457c75f5adfaaf543e6cea5ab2e63d34814a7c2f65cab895fb19c4cb5a7ec5347b13d0e18703a641126e
+DIST olsrd-0.9.8_p20241102.tar.gz 14463841 BLAKE2B a63302f7102c4e9418d1d3db6d3bbb68e4567a8791c6043f33cf9258a236748b5a36d6a66d6519dfca994115b4c2cd7f236e05a33b309928e3e83788c60aca3d SHA512 f8209e20b358458668412185960b1234fb1e3855c1600b0b0996709443c716554684f07e165d5b061d8fda488dca6aab5fcb2563674de7104cd31e369b0ac03a
diff --git a/net-misc/olsrd/olsrd-0.9.8_p20241102.ebuild b/net-misc/olsrd/olsrd-0.9.8_p20241102.ebuild
new file mode 100644
index 000000000000..f3615b049487
--- /dev/null
+++ b/net-misc/olsrd/olsrd-0.9.8_p20241102.ebuild
@@ -0,0 +1,127 @@
+# Copyright 1999-2024 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+inherit toolchain-funcs
+
+# Snapshot to fix bug #927456 (and before that, bug #735572)
+MY_COMMIT="3653c47b88653be6c5dcf9e8ce3a5efbb69684a4"
+DESCRIPTION="An implementation of the Optimized Link State Routing protocol"
+HOMEPAGE="http://www.olsr.org/"
+SRC_URI="https://github.com/OLSR/olsrd/archive/${MY_COMMIT}.tar.gz -> ${P}.tar.gz"
+#SRC_URI="https://github.com/OLSR/${PN}/archive/v${PV}.tar.gz -> ${P}.tar.gz"
+S="${WORKDIR}/${PN}-${MY_COMMIT}"
+
+LICENSE="BSD LGPL-2.1"
+SLOT="0"
+KEYWORDS="~amd64 ~x86"
+IUSE="gui pud"
+
+RDEPEND="
+	gui? (
+		dev-libs/glib:2
+		x11-libs/gdk-pixbuf:2
+		x11-libs/gtk+:2
+	)
+	pud? ( sci-geosciences/gpsd )
+"
+DEPEND="
+	${RDEPEND}
+	x11-base/xorg-proto
+"
+BDEPEND="
+	app-alternatives/yacc
+	app-alternatives/lex
+	virtual/pkgconfig
+"
+
+PATCHES=(
+	"${FILESDIR}"/${PN}-0.9.0.2-gtk.patch
+)
+
+src_prepare() {
+	default
+
+	# fix parallel make
+	# respect AR
+	# verbose build
+	# fix default prefix, bug #453440
+	sed -i \
+		-e '/@echo "\[/d' \
+		-e 's|$(MAKECMD)|$(MAKE)|g' \
+		-e 's|@$(CC)|$(CC)|g' \
+		-e 's|@ar |$(AR) |g' \
+		-e '/^prefix/s:/usr/local:/usr:' \
+		$( find -name 'Makefile*' ) || die
+
+	# respect LDFLAGS
+	sed -i \
+		-e 's|$(CC)|& $(OLSRD_LDFLAGS)|g' \
+		lib/pud/nmealib/Makefile lib/pud/wireformat/Makefile || die
+}
+
+src_configure() {
+	if ! use pud; then
+		sed -i -e '/^SUBDIRS/ s|pud||g' Makefile || die
+	fi
+}
+
+src_compile() {
+	tc-export PKG_CONFIG
+
+	emake \
+		CC="$(tc-getCC) -std=gnu17" \
+		LIBDIR="/usr/$(get_libdir)/${PN}" \
+		OLSRD_LDFLAGS="${LDFLAGS}" \
+		OS=linux \
+		VERBOSE=1 \
+		build_all
+
+	if use gui; then
+		emake -C gui/linux-gtk LIBDIR="/usr/$(get_libdir)/${PN}" CC="$(tc-getCC) -std=gnu17"
+	fi
+}
+
+src_install() {
+	# See bug #715392 re LDCONFIG
+	emake \
+		DESTDIR="${D}" \
+		DOCDIR_OLSRD="${D}/usr/share/doc/${PF}" \
+		LIBDIR="${D}/usr/$(get_libdir)/${PN}" \
+		OS=linux \
+		STRIP=true \
+		LDCONFIG=true \
+		install_all
+
+	if use gui; then
+		emake -C gui/linux-gtk \
+			DESTDIR="${D}" \
+			LIBDIR="${D}/usr/$(get_libdir)/${PN}" \
+			install
+	fi
+
+	doinitd "${FILESDIR}"/${PN}
+
+	gzip -d \
+		"${ED}"/usr/share/man/man5/olsrd.conf.5.gz \
+		"${ED}"/usr/share/man/man8/olsrd.8.gz \
+		|| die
+
+	dodoc CHANGELOG \
+		valgrind-howto.txt files/olsrd.conf.default.rfc \
+		files/olsrd.conf.default.lq \
+		lib/arprefresh/README_ARPREFRESH \
+		lib/bmf/README_BMF \
+		lib/dot_draw/README_DOT_DRAW \
+		lib/dyn_gw/README_DYN_GW \
+		lib/dyn_gw_plain/README_DYN_GW_PLAIN \
+		lib/httpinfo/README_HTTPINFO \
+		lib/mini/README_MINI \
+		lib/nameservice/README_NAMESERVICE \
+		lib/pgraph/README_PGRAPH \
+		lib/quagga/README_QUAGGA \
+		lib/secure/README_SECURE \
+		lib/txtinfo/README_TXTINFO \
+		lib/watchdog/README_WATCHDOG
+}