net-analyzer/gvm-libs: add 22.7.0

Signed-off-by: Giuseppe Foti <foti.giuseppe@gmail.com>
Closes: https://github.com/gentoo/gentoo/pull/32114
Signed-off-by: Florian Schmaus <flow@gentoo.org>

2 files changed, 114 insertions, 0 deletions

diff --git a/net-analyzer/gvm-libs/Manifest b/net-analyzer/gvm-libs/Manifest
index a0ec15bd17d5..390e121f5d74 100644
--- a/net-analyzer/gvm-libs/Manifest
+++ b/net-analyzer/gvm-libs/Manifest
@@ -1,2 +1,3 @@
 DIST gvm-libs-21.4.4.tar.gz 298551 BLAKE2B 271716d8be2376e2b54218b95069e19d10939c5feda9894220418bf184c4098eeacf61d1faedd49fe3215aa0fbf4a4afcfe2a929ac88450502737eb8af8f8e35 SHA512 6c80820c830cbc2e62865a0823740d857db075f2faa1a1e58af7a8f07e0179e7a78934d7613ec57f144900a5530206d4c07c912a6bbe40ad9d0549f9443bfb12
 DIST gvm-libs-22.6.3.tar.gz 309045 BLAKE2B 9627fbdbb9d7a77542242311bce83e760316aea9f5c7b4c275aada18b6407cda41f5a0e1bd1e7202a16304e11772ddeabb01513ec67b7310d95e6522676fec1a SHA512 7b2db4c7aa2361e6dbaca002755bea00eca333f9edf6da5d3c1cf41c6abac32c60f2721f4f152ea6d6bc0f366bdd6249b0693df711ab35e933cd7e22bf028002
+DIST gvm-libs-22.7.0.tar.gz 309170 BLAKE2B afa3a511707f99764a231c7443b136be811b7bb3b0b30d73665b05457c9f0c158ebf9de15a76d4a31dca891fe59dcc09ecdb75e568c43b896833f73b2f3ce1f5 SHA512 eb0ba10b83c7f3b24323c1ff84b8920820521133e70d6d4492bab875b001efb5a7cc36f0ccb0451e1ec209a6dcc48303fb0dc94c69af179cd3342ac089b6820b
diff --git a/net-analyzer/gvm-libs/gvm-libs-22.7.0.ebuild b/net-analyzer/gvm-libs/gvm-libs-22.7.0.ebuild
new file mode 100644
index 000000000000..860cc4df5b4b
--- /dev/null
+++ b/net-analyzer/gvm-libs/gvm-libs-22.7.0.ebuild
@@ -0,0 +1,113 @@
+# Copyright 1999-2023 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+inherit cmake toolchain-funcs
+
+DESCRIPTION="Greenbone Vulnerability Management (GVM) libraries"
+HOMEPAGE="https://www.greenbone.net https://github.com/greenbone/gvm-libs/"
+SRC_URI="https://github.com/greenbone/gvm-libs/archive/v${PV}.tar.gz -> ${P}.tar.gz"
+
+LICENSE="GPL-2+"
+SLOT="0"
+KEYWORDS="~amd64 ~x86"
+IUSE="doc ldap test radius"
+RESTRICT="!test? ( test )"
+
+DEPEND="
+	acct-user/gvm
+	app-crypt/gpgme:=
+	dev-libs/glib:2
+	dev-libs/hiredis:=
+	dev-libs/libgcrypt:=
+	dev-libs/libgpg-error
+	dev-libs/libxml2
+	dev-perl/UUID
+	net-libs/gnutls:=
+	net-libs/libnet:1.1
+	net-libs/libpcap
+	net-libs/libssh:=
+	sys-apps/util-linux
+	sys-libs/libxcrypt:=
+	sys-libs/zlib
+	dev-libs/paho-mqtt-c:1.3
+	ldap? ( net-nds/openldap:= )
+	radius? ( net-dialup/freeradius-client )
+"
+RDEPEND="${DEPEND}"
+BDEPEND="
+	dev-vcs/git
+	sys-devel/bison
+	sys-devel/flex
+	virtual/pkgconfig
+	doc? (
+		app-doc/doxygen[dot]
+		app-doc/xmltoman
+		app-text/htmldoc
+		dev-perl/CGI
+		dev-perl/SQL-Translator
+	)
+	test? ( dev-libs/cgreen )
+"
+
+src_prepare() {
+	cmake_src_prepare
+	# QA-Fix | Remove -Werror compiler flag | Bug: #909558
+	sed -i -e "s/-Werror//" "${S}"/CMakeLists.txt || die
+	# QA-Fix | Remove doxygen warnings for !CLANG
+	if use doc; then
+		if ! tc-is-clang; then
+		   local f
+		   for f in doc/*.in; do
+			sed -i \
+				-e "s*CLANG_ASSISTED_PARSING = NO*#CLANG_ASSISTED_PARSING = NO*g" \
+				-e "s*CLANG_OPTIONS*#CLANG_OPTIONS*g" \
+				"${f}" || die "couldn't disable CLANG parsing"
+		   done
+		fi
+	fi
+
+	#Remove tests that doesn't work in the network sandbox
+	if use test; then
+		sed -i 's/add_test (networking-test networking-test)/ /g' base/CMakeLists.txt || die
+		sed -i 's/add_test (util-test util-test)/ /g' boreas/CMakeLists.txt || die
+	fi
+}
+
+src_configure() {
+	local mycmakeargs=(
+		"-DLOCALSTATEDIR=${EPREFIX}/var"
+		"-DSYSCONFDIR=${EPREFIX}/etc"
+		"-DGVM_RUN_DIR=${EPREFIX}/var/lib/gvm"
+		"-DBUILD_TESTS=$(usex test)"
+		"-DBUILD_WITH_RADIUS=$(usex radius)"
+		"-DBUILD_WITH_LDAP=$(usex ldap)"
+	)
+	cmake_src_configure
+}
+
+src_compile() {
+	cmake_src_compile
+	if use doc; then
+		cmake_build -C "${BUILD_DIR}" doc
+		cmake_build doc-full -C "${BUILD_DIR}" doc
+	fi
+	cmake_build rebuild_cache
+	if use test; then
+		cmake_build tests
+	fi
+}
+
+src_install() {
+	if use doc; then
+		local HTML_DOCS=( "${BUILD_DIR}"/doc/generated/html/. )
+	fi
+	cmake_src_install
+
+	# Set proper permissions on required files/directories
+	keepdir /var/lib/gvm
+	if ! use prefix; then
+		fowners -R gvm:gvm /var/lib/gvm
+	fi
+}