media-sound/lilypond: bump to 2.21.4 + python3_9

Package-Manager: Portage-3.0.1, Repoman-2.3.23
Signed-off-by: Miroslav Šulc <fordfrog@gentoo.org>

3 files changed, 131 insertions, 1 deletions

diff --git a/media-sound/lilypond/Manifest b/media-sound/lilypond/Manifest
index 40fc65bffd7d..3687cff7423d 100644
--- a/media-sound/lilypond/Manifest
+++ b/media-sound/lilypond/Manifest
@@ -1 +1,2 @@
 DIST lilypond-2.21.1.tar.gz 18135688 BLAKE2B 4a797c325e254b59cb314b28a801198f398efd7a37cac448b79d8161ab7248b0c9ca45ce742b82d0aebb784a98637209c84df74304a9e8c8f744b9f5033e18d2 SHA512 596f6a09d0f9a0c39ca717a9e4e246e03679a6cf40a78491eac9bc3eccf173799c75a0baef491cae8385bf1abda53244fd731695762b6fd841396edb92d0ab75
+DIST lilypond-2.21.4.tar.gz 18011766 BLAKE2B fe9731a170ec6e551bd5e2259cca33e1c69ee5dedccaf39e7026afe3342da8d301f7450450122f4e102915d4469dddb89575b3a75db21e988d526d9b683bcc38 SHA512 29d671d411cf3817e8a62f208bec4c8d74a08c3a54b8856c1474cfa736e2882c5418b52af2675598093fae2b77c2ba4c812aae9164d99c9643ff18271cee6860
diff --git a/media-sound/lilypond/lilypond-2.21.4.ebuild b/media-sound/lilypond/lilypond-2.21.4.ebuild
new file mode 100644
index 000000000000..3aa63a51f186
--- /dev/null
+++ b/media-sound/lilypond/lilypond-2.21.4.ebuild
@@ -0,0 +1,129 @@
+# Copyright 1999-2020 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=7
+PYTHON_COMPAT=( python3_{6,7,8,9} )
+
+inherit elisp-common autotools python-single-r1 toolchain-funcs xdg-utils
+
+if [[ "${PV}" = "9999" ]]; then
+	inherit git-r3
+	EGIT_REPO_URI="https://git.savannah.gnu.org/git/lilypond.git"
+else
+	MAIN_VER=$(ver_cut 1-2)
+	SRC_URI="http://lilypond.org/download/sources/v${MAIN_VER}/${P}.tar.gz"
+	KEYWORDS="~amd64 ~arm ~arm64 ~hppa ~x86"
+fi
+
+DESCRIPTION="GNU Music Typesetter"
+HOMEPAGE="http://lilypond.org/"
+
+LICENSE="GPL-3 FDL-1.3"
+SLOT="0"
+IUSE="debug emacs guile2 profile vim-syntax"
+REQUIRED_USE="${PYTHON_REQUIRED_USE}"
+
+BDEPEND="
+	>=dev-texlive/texlive-metapost-2020
+	>=sys-apps/texinfo-4.11
+	>=sys-devel/bison-2.0
+	sys-devel/flex
+	virtual/pkgconfig
+"
+RDEPEND=">=app-text/ghostscript-gpl-8.15
+	>=dev-scheme/guile-1.8.2:12=[deprecated,regex]
+	media-fonts/tex-gyre
+	media-libs/fontconfig
+	media-libs/freetype:2
+	>=x11-libs/pango-1.12.3
+	emacs? ( >=app-editors/emacs-23.1:* )
+	guile2? ( >=dev-scheme/guile-2.2:12 )
+	!guile2? (
+		>=dev-scheme/guile-1.8.2:12=[deprecated,regex]
+		<dev-scheme/guile-2.0:12
+	)
+	${PYTHON_DEPS}"
+DEPEND="${RDEPEND}
+	app-text/t1utils
+	dev-lang/perl
+	dev-libs/kpathsea
+	media-gfx/fontforge[png,python]
+	sys-devel/gettext"
+
+# Correct output data for tests isn't bundled with releases
+RESTRICT="test"
+
+PATCHES=(
+	"${FILESDIR}"/${PN}-2.21.1-fix-font-size.patch
+)
+
+DOCS=( DEDICATION HACKING README.txt ROADMAP )
+
+src_prepare() {
+	default
+
+	if ! use vim-syntax ; then
+		sed -i 's/vim//' GNUmakefile.in || die
+	fi
+
+	# respect CFLAGS
+	sed -i 's/OPTIMIZE -g/OPTIMIZE/' aclocal.m4 || die
+
+	# remove bundled texinfo file (fixes bug #448560)
+	rm tex/texinfo.tex || die
+
+	eautoreconf
+
+	xdg_environment_reset #586592
+}
+
+src_configure() {
+	# documentation generation currently not supported since it requires a newer
+	# version of texi2html than is currently in the tree
+
+	local myeconfargs=(
+		--with-texgyre-dir=/usr/share/fonts/tex-gyre
+		--disable-documentation
+		--disable-optimising
+		--disable-pipe
+		$(use_enable debug debugging)
+		$(use_enable profile profiling)
+	)
+	export VARTEXFONTS="${T}/fonts"  # https://bugs.gentoo.org/692010
+
+	econf "${myeconfargs[@]}"
+}
+
+src_compile() {
+	default
+
+	if use emacs ; then
+		elisp-compile elisp/lilypond-{font-lock,indent,mode,what-beat}.el \
+			|| die "elisp-compile failed"
+	fi
+}
+
+src_install() {
+	emake DESTDIR="${D}" vimdir=/usr/share/vim/vimfiles install
+
+	# remove elisp files since they are in the wrong directory
+	rm -r "${ED}"/usr/share/emacs || die
+
+	if use emacs ; then
+		elisp-install ${PN} elisp/*.{el,elc} elisp/out/*.el \
+			|| die "elisp-install failed"
+		elisp-site-file-install "${FILESDIR}"/50${PN}-gentoo.el
+	fi
+
+	python_fix_shebang "${ED}"
+
+	einstalldocs
+}
+
+pkg_postinst() {
+	use emacs && elisp-site-regen
+}
+
+pkg_postrm() {
+	use emacs && elisp-site-regen
+}
diff --git a/media-sound/lilypond/lilypond-9999.ebuild b/media-sound/lilypond/lilypond-9999.ebuild
index adc21f971c1d..fc14ef8ed34b 100644
--- a/media-sound/lilypond/lilypond-9999.ebuild
+++ b/media-sound/lilypond/lilypond-9999.ebuild
@@ -2,7 +2,7 @@
 # Distributed under the terms of the GNU General Public License v2
 
 EAPI=7
-PYTHON_COMPAT=( python3_{6,7,8} )
+PYTHON_COMPAT=( python3_{6,7,8,9} )
 
 inherit elisp-common autotools python-single-r1 toolchain-funcs xdg-utils