media-libs/vulkan-loader: Bump to 1.2.154

Package-Manager: Portage-3.0.9, Repoman-3.0.2
Signed-off-by: Nick Sarnie <sarnex@gentoo.org>

3 files changed, 69 insertions, 2 deletions

diff --git a/media-libs/vulkan-loader/Manifest b/media-libs/vulkan-loader/Manifest
index 71fa2ae310d4..a2ec9ac38c31 100644
--- a/media-libs/vulkan-loader/Manifest
+++ b/media-libs/vulkan-loader/Manifest
@@ -1 +1,2 @@
 DIST vulkan-loader-1.2.141.tar.gz 1410381 BLAKE2B a52c384cdda41083705008b0a00f820482d5f7cb16aeb347ebb1b0dfa55e1bc5851e60275728e0d73272a2c4335bbd5efe5aaaed21c0ac9cbd3d5fb76e73cc24 SHA512 251cc617693d651feba887a737ff724631160b172577cd3365d1a93e9c17ee87719d7aa78efa6570ee4f17fa15feb4e39bee1c706f7c12c6f96617348bdd8f26
+DIST vulkan-loader-1.2.154.tar.gz 1417349 BLAKE2B b134932b31325884639e94ef74f7b97c9111554ef904777df9b4e398d927e89bdf2394593ce8e4483e9fda1cd1f299df0841471ac11263580b04bc97786ac973 SHA512 003f16bff7eb24791e458b757d0fee5db9ab68d6e7b56eae623af0c4702c534cc19099c79d2ec2493cd3c30c796f1dff060bc3aaa4057b9215749de65566c157
diff --git a/media-libs/vulkan-loader/vulkan-loader-1.2.154.ebuild b/media-libs/vulkan-loader/vulkan-loader-1.2.154.ebuild
new file mode 100644
index 000000000000..8807c9d94dfb
--- /dev/null
+++ b/media-libs/vulkan-loader/vulkan-loader-1.2.154.ebuild
@@ -0,0 +1,66 @@
+# Copyright 1999-2020 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=7
+
+MY_PN=Vulkan-Loader
+CMAKE_ECLASS="cmake"
+PYTHON_COMPAT=( python3_{6,7,8} )
+inherit flag-o-matic cmake-multilib python-any-r1 toolchain-funcs
+
+if [[ ${PV} == *9999* ]]; then
+	EGIT_REPO_URI="https://github.com/KhronosGroup/${MY_PN}.git"
+	EGIT_SUBMODULES=()
+	inherit git-r3
+else
+	SRC_URI="https://github.com/KhronosGroup/${MY_PN}/archive/v${PV}.tar.gz -> ${P}.tar.gz"
+	KEYWORDS="~amd64 ~arm ~arm64 ~ppc ~ppc64 ~x86"
+	S="${WORKDIR}"/${MY_PN}-${PV}
+fi
+
+DESCRIPTION="Vulkan Installable Client Driver (ICD) Loader"
+HOMEPAGE="https://github.com/KhronosGroup/Vulkan-Loader"
+
+LICENSE="Apache-2.0"
+SLOT="0"
+IUSE="layers wayland X"
+
+BDEPEND=">=dev-util/cmake-3.10.2"
+DEPEND="${PYTHON_DEPS}
+	~dev-util/vulkan-headers-1.2.154
+	wayland? ( dev-libs/wayland:=[${MULTILIB_USEDEP}] )
+	X? (
+		x11-libs/libX11:=[${MULTILIB_USEDEP}]
+		x11-libs/libXrandr:=[${MULTILIB_USEDEP}]
+	)
+"
+PDEPEND="layers? ( media-libs/vulkan-layers:=[${MULTILIB_USEDEP}] )"
+
+multilib_src_configure() {
+	# Integrated clang assembler doesn't work with x86 - Bug #698164
+	if tc-is-clang && [[ ${ABI} == x86 ]]; then
+		append-cflags -fno-integrated-as
+	fi
+
+	local mycmakeargs=(
+		-DCMAKE_SKIP_RPATH=ON
+		-DBUILD_TESTS=OFF
+		-DBUILD_LOADER=ON
+		-DBUILD_WSI_WAYLAND_SUPPORT=$(usex wayland)
+		-DBUILD_WSI_XCB_SUPPORT=$(usex X)
+		-DBUILD_WSI_XLIB_SUPPORT=$(usex X)
+		-DVULKAN_HEADERS_INSTALL_DIR="${ESYSROOT}/usr"
+	)
+	cmake_src_configure
+}
+
+multilib_src_install() {
+	keepdir /etc/vulkan/icd.d
+
+	cmake_src_install
+}
+
+pkg_postinst() {
+	einfo "USE=demos has been dropped as per upstream packaging"
+	einfo "vulkaninfo is now available in the dev-util/vulkan-tools package"
+}
diff --git a/media-libs/vulkan-loader/vulkan-loader-9999.ebuild b/media-libs/vulkan-loader/vulkan-loader-9999.ebuild
index c09d888cf7a6..8807c9d94dfb 100644
--- a/media-libs/vulkan-loader/vulkan-loader-9999.ebuild
+++ b/media-libs/vulkan-loader/vulkan-loader-9999.ebuild
@@ -14,7 +14,7 @@ if [[ ${PV} == *9999* ]]; then
 	inherit git-r3
 else
 	SRC_URI="https://github.com/KhronosGroup/${MY_PN}/archive/v${PV}.tar.gz -> ${P}.tar.gz"
-	KEYWORDS="~amd64 ~ppc64 ~x86"
+	KEYWORDS="~amd64 ~arm ~arm64 ~ppc ~ppc64 ~x86"
 	S="${WORKDIR}"/${MY_PN}-${PV}
 fi
 
@@ -27,7 +27,7 @@ IUSE="layers wayland X"
 
 BDEPEND=">=dev-util/cmake-3.10.2"
 DEPEND="${PYTHON_DEPS}
-	>=dev-util/vulkan-headers-${PV}
+	~dev-util/vulkan-headers-1.2.154
 	wayland? ( dev-libs/wayland:=[${MULTILIB_USEDEP}] )
 	X? (
 		x11-libs/libX11:=[${MULTILIB_USEDEP}]