media-libs/lilv: bump 0.24.6

1) dropped python 2_7 and 3_5, added 3_8
2) updated deps
3) fixed installed bash completion

Closes: https://bugs.gentoo.org/534426
Package-Manager: Portage-2.3.82, Repoman-2.3.20
Signed-off-by: Miroslav Šulc <fordfrog@gentoo.org>

2 files changed, 75 insertions, 0 deletions

diff --git a/media-libs/lilv/Manifest b/media-libs/lilv/Manifest
index 480fbe3b6476..b106b3bee504 100644
--- a/media-libs/lilv/Manifest
+++ b/media-libs/lilv/Manifest
@@ -1 +1,2 @@
 DIST lilv-0.24.4.tar.bz2 252209 BLAKE2B 71142f6a458a0edbb2087ac6eb6323b6ae4c53e45db22a616f00b22f818f507aa724ebf576f09654a98812b8b9a73689720677e64c715fbf7cd49ba26c7ddb11 SHA512 cb909c83dbac36b51a206fe508aec51e52ddf068f9a159d053888594402def8d140aae0d9e1e1866e722396f7ec8dea4b86d4c1b958f56eb3193b78307918a89
+DIST lilv-0.24.6.tar.bz2 541765 BLAKE2B fb3532b1a19c790207b894f88ea7d4f714bef8e9f743ca27f6eca36fe44da6e92bce47931791dfb0096e03f9efdf569b1f3f514debb1538c2727c65f61697627 SHA512 0cf89d7dac97727e744579d3f4f4b330f56cf72f1a30bd03abfd645233aaf04e9bbf2abf460a0e4b963ed40e1ae78ed5f36127553bdab16e3e7dd3e93b70cdad
diff --git a/media-libs/lilv/lilv-0.24.6.ebuild b/media-libs/lilv/lilv-0.24.6.ebuild
new file mode 100644
index 000000000000..1189d6b58278
--- /dev/null
+++ b/media-libs/lilv/lilv-0.24.6.ebuild
@@ -0,0 +1,74 @@
+# Copyright 1999-2019 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=6
+
+PYTHON_COMPAT=( python3_{6,7,8} )
+PYTHON_REQ_USE='threads(+)'
+
+inherit python-any-r1 waf-utils bash-completion-r1 multilib-build multilib-minimal
+
+DESCRIPTION="Library to make the use of LV2 plugins as simple as possible for applications"
+HOMEPAGE="http://drobilla.net/software/lilv/"
+SRC_URI="http://download.drobilla.net/${P}.tar.bz2"
+
+LICENSE="ISC"
+SLOT="0"
+KEYWORDS="~alpha ~amd64 ~arm ~arm64 ~hppa ~ia64 ~ppc ~ppc64 ~sparc ~x86"
+IUSE="doc +dyn-manifest static-libs test"
+RESTRICT="!test? ( test )"
+
+RDEPEND="
+	>=dev-libs/serd-0.30.0-r1[${MULTILIB_USEDEP}]
+	>=dev-libs/sord-0.16.0-r1[${MULTILIB_USEDEP}]
+	media-libs/libsndfile
+	>=media-libs/lv2-1.16.0[${MULTILIB_USEDEP}]
+	media-libs/sratom[${MULTILIB_USEDEP}]
+"
+DEPEND="
+	${RDEPEND}
+	${PYTHON_DEPS}
+	virtual/pkgconfig[${MULTILIB_USEDEP}]
+	doc? ( app-doc/doxygen )
+	test? ( dev-python/unittest2 )
+"
+
+PATCHES=( "${FILESDIR}/includedir.patch" )
+
+src_prepare() {
+	default
+	sed -i -e 's/^.*run_ldconfig/#\0/' wscript || die
+	multilib_copy_sources
+}
+
+multilib_src_configure() {
+	waf-utils_src_configure \
+		--docdir="${EPREFIX}"/usr/share/doc/${PF} \
+		--no-bash-completion \
+		$(multilib_native_usex doc --docs "") \
+		$(usex test --test "") \
+		$(usex static-libs --static "") \
+		$(usex dyn-manifest --dyn-manifest "")
+}
+
+multilib_src_compile() {
+	./waf build || die
+}
+
+multilib_src_test() {
+	./waf test || die
+}
+
+multilib_src_install() {
+	waf-utils_src_install
+}
+
+multilib_src_install_all() {
+	sed -i "/lv2jack/d" utils/lilv.bash_completion
+	newbashcomp utils/lilv.bash_completion lv2info
+
+	dodir /etc/env.d
+	echo "LV2_PATH=${EPREFIX}/usr/$(get_libdir)/lv2" > "${ED}/etc/env.d/60lv2"
+
+	python_optimize
+}