media-libs/libshout: bump to 2.4.5

Closes: https://bugs.gentoo.org/762664
Package-Manager: Portage-3.0.12, Repoman-3.0.2
Signed-off-by: Miroslav Šulc <fordfrog@gentoo.org>

1 files changed, 52 insertions, 0 deletions

diff --git a/media-libs/libshout/libshout-2.4.5.ebuild b/media-libs/libshout/libshout-2.4.5.ebuild
new file mode 100644
index 000000000000..76d212702972
--- /dev/null
+++ b/media-libs/libshout/libshout-2.4.5.ebuild
@@ -0,0 +1,52 @@
+# Copyright 1999-2020 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=7
+
+inherit autotools multilib-minimal
+
+DESCRIPTION="library for connecting and sending data to icecast servers"
+HOMEPAGE="https://www.icecast.org/"
+SRC_URI="http://downloads.xiph.org/releases/${PN}/${P}.tar.gz"
+
+LICENSE="LGPL-2"
+SLOT="0"
+KEYWORDS="~alpha ~amd64 ~arm ~arm64 ~hppa ~ia64 ~ppc ~ppc64 ~sparc ~x86"
+IUSE="libressl speex static-libs theora"
+
+RDEPEND="
+	>=media-libs/libogg-1.3.0[${MULTILIB_USEDEP}]
+	>=media-libs/libvorbis-1.3.3-r1[${MULTILIB_USEDEP}]
+	!libressl? ( dev-libs/openssl:0= )
+	libressl? ( dev-libs/libressl:0= )
+	speex? ( media-libs/speex[${MULTILIB_USEDEP}] )
+	theora? ( media-libs/libtheora[${MULTILIB_USEDEP}] )
+"
+DEPEND="${RDEPEND}
+	virtual/pkgconfig
+"
+
+MULTILIB_WRAPPED_HEADERS=(
+	/usr/include/shout/shout.h
+)
+
+src_prepare() {
+	default
+	# Fix docdir
+	sed '/^docdir/s@$(PACKAGE)@$(PF)@' -i Makefile.am || die
+	eautoreconf
+	multilib_copy_sources
+}
+
+multilib_src_configure() {
+	local myeconfargs=(
+		$(use_enable speex)
+		$(use_enable static-libs static)
+		$(use_enable theora)
+	)
+	ECONF_SOURCE="${S}" econf "${myeconfargs[@]}"
+}
+
+multilib_src_install_all() {
+	find "${ED}" -name '*.la' -delete || die
+}