media-gfx/cura: add 4.13.0

Signed-off-by: Matthew Smith <matthew@gentoo.org>

2 files changed, 87 insertions, 0 deletions

diff --git a/media-gfx/cura/Manifest b/media-gfx/cura/Manifest
index 66fb25368e66..7ed2fd162fb3 100644
--- a/media-gfx/cura/Manifest
+++ b/media-gfx/cura/Manifest
@@ -1,2 +1,3 @@
 DIST cura-4.12.1.tar.gz 50021408 BLAKE2B 114bbe0cc022e33125486228db2eeaeacd9f4abeac8e65f3ed70231e05f4429062ce1cd49e1649959beb827b7a2d245f61c106529a18bd0cebbd0e8b9b8f883f SHA512 397048e1ed93d2e3ec326a3b0564db2b6ee2b239843346e2dd44470b11b5aea86f3f519534270789e020261c87a0100bf3bba39ddbd3a1d8be0e38e68fd7e0c0
+DIST cura-4.13.0.tar.gz 42339276 BLAKE2B 05e747b8e84ecf64bdc1ad7662eae7b5e8a739b7c1bbafdd3ae081e790dafbcd98209eb90f45996e93115ea8b7a38764be957091dd358c502e7aa71cb61fe6c7 SHA512 46f13cde12735d64dad2c533c7688612ebc1c2c8b78d71ced8cfd7d7abd80a53c09105bb16f64ae92cddf345fe44f83800d4448007fe5c2938c652f58354747b
 DIST cura-4.9.1.tar.gz 47870392 BLAKE2B 2471c8461f73ad2343f4c3315994c5f63781ae1e49cb4699cd66e7e77c25a93916931fbaa6598c4144707dbc7778c902dad3a25839c0523aaf51ed39aacd2463 SHA512 436b8e33514de67d6d680fe59ab9599a75a86caa7e63fbcd05297b12a435483ec0c9ca90557fe23f25590a24e533294915fc18a665fd5cdb77fcc3a05a9076bf
diff --git a/media-gfx/cura/cura-4.13.0.ebuild b/media-gfx/cura/cura-4.13.0.ebuild
new file mode 100644
index 000000000000..805c67fdd48c
--- /dev/null
+++ b/media-gfx/cura/cura-4.13.0.ebuild
@@ -0,0 +1,86 @@
+# Copyright 1999-2022 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+PYTHON_COMPAT=( python3_{8..10} )
+
+inherit cmake desktop python-single-r1 xdg
+
+# Never got tagged as 4.13 proper.
+PYNEST2D_PV=4.13_beta
+
+DESCRIPTION="A 3D model slicing application for 3D printing"
+HOMEPAGE="https://github.com/Ultimaker/Cura"
+SRC_URI="https://github.com/Ultimaker/${PN}/archive/${PV}.tar.gz -> ${P}.tar.gz"
+
+LICENSE="LGPL-3"
+SLOT="0"
+KEYWORDS="~amd64 ~arm64 ~x86"
+IUSE="debug test +usb zeroconf"
+REQUIRED_USE="${PYTHON_REQUIRED_USE}"
+
+RESTRICT="!test? ( test )"
+
+BDEPEND="${PYTHON_DEPS}
+	sys-devel/gettext
+	$(python_gen_cond_dep '
+		test? ( dev-python/pytest[${PYTHON_USEDEP}] )
+	')
+"
+RDEPEND="${PYTHON_DEPS}
+	~dev-libs/libarcus-${PV}:=[python,${PYTHON_SINGLE_USEDEP}]
+	~dev-libs/libcharon-${PV}[${PYTHON_SINGLE_USEDEP}]
+	~dev-libs/libsavitar-${PV}:=[python,${PYTHON_SINGLE_USEDEP}]
+	~dev-python/pynest2d-${PYNEST2D_PV}[${PYTHON_SINGLE_USEDEP}]
+	~dev-python/uranium-${PV}[${PYTHON_SINGLE_USEDEP}]
+	~media-gfx/curaengine-${PV}
+	~media-gfx/fdm-materials-${PV}
+	dev-qt/qtquickcontrols[widgets]
+	$(python_gen_cond_dep '
+			dev-python/importlib_metadata[${PYTHON_USEDEP}]
+			dev-python/keyring[${PYTHON_USEDEP}]
+			dev-python/mypy[${PYTHON_USEDEP}]
+			dev-python/numpy[${PYTHON_USEDEP}]
+			dev-python/PyQt5[-debug,${PYTHON_USEDEP}]
+			dev-python/PyQt5-sip[${PYTHON_USEDEP}]
+			dev-python/requests[${PYTHON_USEDEP}]
+			dev-python/sentry-sdk[${PYTHON_USEDEP}]
+			dev-python/trimesh[${PYTHON_USEDEP}]
+			sci-libs/shapely[${PYTHON_USEDEP}]
+			usb? ( dev-python/pyserial[${PYTHON_USEDEP}] )
+			zeroconf? ( dev-python/zeroconf[${PYTHON_USEDEP}] )
+	')"
+DEPEND="${RDEPEND}"
+
+PATCHES=(
+	"${FILESDIR}"/${PN}-4.12.1-code-style-test.patch
+)
+
+DOCS=( README.md )
+S="${WORKDIR}"/Cura-${PV}
+
+src_prepare() {
+	sed -i -e "s:lib\${LIB_SUFFIX}/python\${Python3_VERSION_MAJOR}.\${Python3_VERSION_MINOR}/site-packages:$(python_get_sitedir):g" CMakeLists.txt || die
+
+	# Remove failing test.  Bug #693172.
+	rm -r plugins/VersionUpgrade/VersionUpgrade44to45/tests || die
+
+	cmake_src_prepare
+}
+
+src_configure() {
+	local mycmakeargs=(
+		-DCURA_BUILDTYPE="ebuild"
+		-DCURA_VERSION=${PV}
+		-DCURA_DEBUGMODE=$(usex debug)
+	)
+	cmake_src_configure
+}
+
+src_install() {
+	cmake_src_install
+	doicon icons/*.png
+	python_fix_shebang "${D}/usr/bin/cura"
+	python_optimize "${D}${get_libdir}"
+}